What is timerdiff() doing?

[Lecdev]

does anyone know what exactly TimerDiff() is doing with the integer returned by TimerInit() in order to get milliseconds?

 

Just trying to find out if i can use the integer timerinit() returns in a slightly different way to the norm because it will save me a great deal of effort.

 

( hoping to save the integer in a db and query rows where the difference in current time integer is > x where x = whatever the integer needs to be to = y hours )

 

 

[jchd]

See by yourself there is only little difference in behavior of the two timer functions. They both basically deal with QueryPerformanceCounter.

Note that TimerInit returns a double and the built-in functions are unsurprisingly way faster (~20x)  than the UDF.

#include <Timers.au3>

Local $t1 = TimerInit()
Local $t2 = _Timer_Init()
ConsoleWrite($t1 & @TAB & VarGetType($t1) & @LF)
ConsoleWrite($t2 & @TAB & VarGetType($t2) & @LF)

Sleep(1000)

$t1 = TimerDiff($t1)
$t2 = _Timer_Diff($t2)
ConsoleWrite($t1 & @TAB & VarGetType($t1) & @LF)
ConsoleWrite($t2 & @TAB & VarGetType($t2) & @LF)

Local $total
For $i = 1 To 10000
    $t1 = TimerInit()
    $total += TimerDiff($t1)
Next
ConsoleWrite('Average TimerInit + TimerDiff invokation time = ' & $total & @LF)
$total = 0
For $i = 1 To 10000
    $t1 = _Timer_Init()
    $total += _Timer_Diff($t1)
Next
ConsoleWrite('Average _Timer_Init + _Timer_Diff invokation time = ' & $total & @LF)

To convert to usable precise relative (unsynchronized to UTC) time you'll have to use __Timer_QueryPerformanceCounter and  __Timer_QueryPerformanceFrequency (see those internal function in Timers.au3).

The int64 you'll get are perfect candidates for use in a DB but can't be used as primary key as the counter is reset at reboot. To get a UTC-synchronized high-res timestamp in 100ns increments from January 1, 1601 use GetSystemTimePreciseAsFileTime WinAPI call. Its result is guaranteed in sync with UTC and monotonically increasing in 100ns increments.

[BrewManNH]

Just an FYI, from the help file.

Quote

Remarks

The return value from TimerInit() should be treated as an opaque handle and should only be used to pass to TimerDiff(). Any other usage of the return value is a potential error.

 

[TurionAltec]

To expand on @jchd's post, TimerInit returns QueryPerformanceCounter. TimerDiff returns the difference of QueryPerformanceCounter (relative to QueryPerformanceCounter value captured by TimerInit), divided by QueryPerformanceFrequency, which will depend on CPU speed. If you call TimerDiff with no reference, it will give time since boot.

See this previous post of mine

 

Looking at this contrived example, the builtin TimerDiff and TimerInit functions are very performant, although you could calculate the QueryPerformanceCounter you want to see in the future ahead of time, to know if a certain amount of time has passed, and be more performant. Though these are incredibly contrived, as the loops don't do any useful work. 

 

expandcollapse popup

#include <Timers.au3>

$dLoopLength=10000000

$hTimer=TimerInit()
For $i=1 to $dLoopLength
    $fDummytime=0
Next
$fDummytime=TimerDiff($hTimer)
ConsoleWrite("Empty For loop: "& $fDummytime&@CRLF)

$hTimer=TimerInit()
For $i=1 to $dLoopLength
    $fDummytime=TimerDiff($hTimer)
Next
ConsoleWrite("Builtin TimerDiff: "& $fDummytime&@CRLF)

$hTimer=TimerInit()
$fFreq= __Timer_QueryPerformanceFrequency()/1000
For $i=1 to $dLoopLength
    $fDummytime=(TimerInit()-$hTimer)/$fFreq
Next
ConsoleWrite("Hybrid TimerDiff: "& $fDummytime&@CRLF)

$dLoopLength=$dLoopLength/100

$hTimer=_Timer_Init()
For $i=1 to $dLoopLength
    $fDummytime=_Timer_Diff($hTimer)
Next
ConsoleWrite("UDF TimerDiff: "& $fDummytime*100&@CRLF)

$i=1
$hTimer=TimerInit()
Do
$i+=1
Until TimerDiff($hTimer) > 2000
ConsoleWrite("Builtin Timerdiff:"&$i&" loops"&@CRLF)

$i=1
$hTimer=TimerInit()
$fFreq= __Timer_QueryPerformanceFrequency()
$hTagetend=Int(TimerInit())+(2*$fFreq)
Do
$i+=1
Until TimerInit() > $hTagetend
ConsoleWrite("Hybrid Timerdiff:"&$i&" loops"&@CRLF)

Empty For loop: 1327.85372380903
Builtin TimerDiff: 3809.99572739426
Hybrid TimerDiff: 4339.62816893478
UDF TimerDiff: 151207.223724135
Builtin Timerdiff:3647645 loops
Hybrid Timerdiff:5246004 loops

 

[BrewManNH]

Quote

 7 years ago by Valik

If you use the return value from TimerInit() for anything other than an opaque handle to be passed to TimerDiff() then you are asking for trouble. Therefore the type is irrelevant. Ticket closed.

 

 

[jchd]

Fine. Then it's enough to DllCall the relevant (already-mentionned) Windows primitives which return an unambiguous Int64.