RegExpReplace -- Remove whitespace Before lines of text

[2Toes]

Hello all 

For the past week or so, I've been learning & messing around with Regular Expressions.

Despite the amount that I've learned throughout this time, I seem to be having an issue with what would seem to be a simple task..

I'm trying to remove gaps of Whitespace that sit in Front of text, as well as empty lines between lines of text.

Here's the expression that I've come up with thus far:

(?is)(?<=^)\s*(?=\w)*

The logic that I'm shooting for is:

Grab 0 or More Whitespaces - between [HAT] and the 1st word Character - and do that 0 or More times.

 

Here's a simple sample code I put together:

$text = "   This is Line 1" & @CRLF & _
"           " & @CRLF & _
"                   " & @CRLF & _
"               This is Line 4  " & @CRLF & _
"                           " & @CRLF & _
"       " & @CRLF & _
"                                                                           This is Line 7" & @CRLF & _
"                                   " & @CRLF & _
"               " & @CRLF & _
"           This is Line 10                 " & @CRLF & _
"   " & @CRLF & _
"                   " & @CRLF & _
"                                       This is Line 13"


$text = StringRegExpReplace($text, "(?is)(?<=^)\s*(?=\w)*", "")

ConsoleWrite($text)

 

After running the code, the gap of Whitespace in front of "This is Line 1" gets removed..

But all other gaps of whitespace remain in place.

 

Does anyone have any ideas on what might be the issue here?

 

Any tips or hints would be greatly appreciated 

[iamtheky]

remove the leading spaces, and then any two whitespaces (or more) in a row replace with a single LF?

$text = "   This is Line 1" & @CRLF & _
"           " & @CRLF & _
"                   " & @CRLF & _
"               This is Line 4  " & @CRLF & _
"                           " & @CRLF & _
"       " & @CRLF & _
"                                                                           This is Line 7" & @CRLF & _
"                                   " & @CRLF & _
"               " & @CRLF & _
"           This is Line 10                 " & @CRLF & _
"   " & @CRLF & _
"                   " & @CRLF & _
"                                       This is Line 13"

$text= StringRegExpReplace(StringStripWS($text , 1) , "(\s\s+)" , @LF)

ConsoleWrite($text)

 

Edited September 3, 2018 by iamtheky

[2Toes]

@iamtheky

In order to achieve what I was looking for, I just had to change @LF to @CRLF. 

But aside from that, that's exactly what I was looking for!

Thanks for the quick reply & help on that. Very much appreciated my friend! 

[jchd]

Try that as well:

$text = "   This is Line 1" & @CRLF & _
"           " & @CRLF & _
"                   " & @CRLF & _
"               This is Line 4  " & @CRLF & _
"                           " & @CRLF & _
"       " & @CRLF & _
"                                                                           This is Line 7" & @CRLF & _
"                                   " & @CRLF & _
"               " & @CRLF & _
"           This is Line 10                 " & @CRLF & _
"   " & @CRLF & _
"                   " & @CRLF & _
"                                       This is Line 13"

$text = StringRegExpReplace($text, "(?m)^\R|^\s+(?=\S)", "")
ConsoleWrite($text & @LF)

 

[2Toes]

Hey @jchd

 

Thanks for jumping in with that. You have a couple things in there that I hadn't learned yet -- (?m) and \R

So, if I'm understanding that correctly..

(?m) switched on MultiLine.

Then, it matches any Empty lines .. ^\R

OR

it matches any whitespace that's between [HAT] and anything that's NOT a whitespace .. (?=\S)

And then of course replaces them with ""

 

Very interesting. Thanks again for that. Much appreciated!! 

[jchd]

Good reading.

For a full, strict and correct explanation of a PCRE-compatible regex in verbose plain English you can use http://regex101.com/ which also offers a useful step-by-step debugging feature.

Sidenote: AutoIt PCRE implementation sets \R to match LF or CR or CRLF. That can be changed at runtime (see help).

[Simpel]

With the regex search string „(?m)^\R|^\s+(?=\S)|\h*$“ you can delete all horizontal whitespaces between the last word in line and the line end.

Simpel