[Solved] Why is my listview in inverted order?

[qwert]

From a post a couple of years ago:

Quote

GUICtrlCreateListViewItem places newly created ListViewItems right below the older ones.

This is the result I want. But no matter which "add item" statement I use, the result always displays in descending (not ascending) order.

;
;       Array and Listview Test
;
#include <GuiListView.au3>
#include <Array.au3>

Local $aArray[4]
$aArray[0] = "Jasper"
$aArray[1] = "Beethoven"
$aArray[2] = "Pinky"
$aArray[3] = "Fidget"

_ArrayDisplay($aArray)

_ArraySort($aArray)
_ArrayDisplay($aArray)

GUICreate("Array and ListView Test", 300, 300)
GUISetFont(12)
$idListview = GUICtrlCreateListView("", 20, 20, 250, 220, 50)
_GUICtrlListView_SetExtendedListViewStyle($idListview, BitOR($LVS_EX_FULLROWSELECT, $LVS_EX_CHECKBOXES))

For $i = 0 To UBound($aArray) - 1 Step 1
MsgBox(0, "Next", $aArray[$i])
GUICtrlCreateListViewItem($aArray[$i], $idListview)
Next

GUISetState(@SW_SHOW)

While 1
    Switch GUIGetMSG()
        Case -3 ; $GUI_EVENT_CLOSE
            GUIDelete()
            Exit
    EndSwitch
WEnd

Thanks in advance for any help.

Edited October 28, 2018 by qwert

[Melba23]

qwert,

Your parameters for the  GUICtrlCreateListView call are wrong - you are setting a style of 50 which is probably the cause of the problem. This works for me:

#include <GuiListView.au3>
#include <Array.au3>

Local $aArray[4]
$aArray[0] = "Jasper"
$aArray[1] = "Beethoven"
$aArray[2] = "Pinky"
$aArray[3] = "Fidget"

_ArrayDisplay($aArray)
_ArraySort($aArray)
_ArrayDisplay($aArray)

GUICreate("Array and ListView Test", 300, 300)
GUISetFont(12)
$idListview = GUICtrlCreateListView(" ", 20, 20, 250, 250) ; You need at least one pixel for a column...
_GUICtrlListView_SetColumnWidth($idListview, 0, 230)       ; ...which you can expand like this
_GUICtrlListView_SetExtendedListViewStyle($idListview, BitOR($LVS_EX_FULLROWSELECT, $LVS_EX_CHECKBOXES))

For $i = 0 To UBound($aArray) - 1 Step 1
    MsgBox(0, "Next", $aArray[$i])
    GUICtrlCreateListViewItem($aArray[$i], $idListview)
Next

GUISetState(@SW_SHOW)

While 1
    Switch GUIGetMsg()
        Case -3 ; $GUI_EVENT_CLOSE
            GUIDelete()
            Exit
    EndSwitch
WEnd

M23

[qwert]

Melba23, thanks. Indeed, that resolves the order.

I don't rightly know where I got the 50 from ... but I seem to remember it had something to do with "no header".

Do proper Listviews always have headers? This (but not inverted) is the result I'm after:

[qwert]

Well, it looks like $LVS_NOCOLUMNHEADER gives the result I'm after.  I had never investigated List View versus Report View (which the documentation indicates is the default).

Thanks for helping out with this.