Checking for multiple Windows in "If Winexists" and closing that specific window if detected

[monkycheez]

I have a current implementation where I'm searching for numerous windows existing, and if they exist I'd like to close that particular window.  Ideally I'd like to keep it within one block, rather than have multiple "if exist then" in a row.

Example:  

If  _
           WinExists("WindowA", "") Or _
           WinExists("WindowB", "") Or _
           WinExists("WindowC", "") Or _
           Then
        Send("{ESC}")

In this example, I'd like to replace the "Send("{ESC}")" to a "WinClose" (or even WinKill).

 

Is there a way to grab which Window was triggered into a variable of some sort so it could be plugged into the WinClose?

[AdamUL]

You could do something like this with a select.  

Global $sWinA = "WindowA"
Global $sWinB = "WindowB"
Global $sWinC = "WindowC"
Global $sWinClose = ""

Select
    Case WinExists($sWinA)
        $sWinClose = $sWinA
    Case WinExists($sWinB)
        $sWinClose = $sWinB
    Case WinExists($sWinC)
        $sWinClose = $sWinC
EndSelect
If $sWinClose <> "" Then WinClose($sWinClose)

 

Adam

 

[FrancescoDiMuro]

@monkycheez

What about an array of windows?

Global $arrWindows[3] = ["Window1", "Window2", "WindowN"]

For $i = 0 To UBound($arrWindows) - 1 Step 1
    If WinExists($arrWindows[$i]) Then WinClose($arrWindows[$i])
Next

[monkycheez]

@FrancescoDiMuro

That's a pretty elegant solution.

I should probably clarify that this Window "check" is nested in a While loop that will continuously run and is also looking for other (unrelated) windows to perform other (unrelated) actions.

How would the "For $i..." steps work while nested in a loop?  Step right thru as if it were individual "If..." checks?

[AdamUL]

For an even simpler use with arrays use For In, since you are only reading the array.  You can use it in loops as well.  

Global $aWindows[3] = ["WindowA", "WindowB", "WindowC"]

For $sWindow In $aWindows
    If WinExists($sWindow) Then WinClose($sWindow)
Next

 

Adam

[monkycheez]

Thank you @adamUL

[monkycheez]

Thank you @adamUL and @FrancescoDiMuro

The Arrays worked as I expected and is a much more elegant solution than having 10 different "if WinExists Then..." blocks.  

[jchd]

Much better:

If WinExists("[REGEXPTITLE:(?i)(.*SciTE.*|.*Internet Explorer.*)]") Then
    ...
EndIf

https://www.autoitscript.com/autoit3/docs/intro/windowsadvanced.htm