For the longest time, I've been trying to come up with an Apply() method similar to Pythons .map(). Closest I've come...

[bailey1274]

expandcollapse popup

#include <Array.au3>
LocalFunction()

Func LocalFunction()

    ; Goal is to have one function act on all of these
    Local $Var1 = '     Trim Me 1     '
    Local $Var2 = '   Trim Me 2    '
    Local $Var3 = '       Trim Me 3  '

    ; Function/Params of what you want to apply to a list/set of vars
    Local $FuncArr[2] = [StringStripWS, 3]
    ; Var names next to vars. If we could byRef these somehow to avoid the For loop after the Apply then it would be great 
    Local $VarArr[6] = [$Var1, 'Var1', $Var2, 'Var2', $Var3, 'Var3'] 

    ; Apply our function to our list of variables
    Apply($FuncArr, $VarArr)
    
    ; Reassign our updated array back to our original variables
    Local $val
    For $var=0 to UBound($VarArr)-1
        If Mod($var, 2) = 0 Then    ; Grab the updated values
            $Val = $VarArr[$var]
            ContinueLoop
        EndIf
        Assign($VarArr[$var], $Val) ; Assign value to correct name
    Next

    MsgBox(0,'Var1',  '['&$Var1&']')
    MsgBox(0,'Var2',  '['&$Var2&']')
    MsgBox(0,'Var3',  '['&$Var3&']')

EndFunc

Func Apply($aFunc, byRef $arr)
    For $var=0 to UBound($arr)-1
        If Mod($var, 2) <> 0 Then ContinueLoop ; Avoid the variable name strings
        $arr[$var] = Call($aFunc[0], $arr[$var], $aFunc[1])
    Next
EndFunc

So heres the code, it gets close to what I want although does anyone have any ideas how to avoid the For Loop after the apply function? If there is a way to create an array with references back to the variables themselves instead of just passing the values, this wouldn't be so ugly. The goal is to just be able to call one function on a large set of variables without having to reassign them individually. This does work but, imo, its pretty ugly and would only be worth it for a very large set of variables since the implementation of this pattern is at minimum like 10 lines. 

[jchd]

Seems to me you're making your life difficult:

LocalFunction()

Func LocalFunction()
    ; Goal is to have one function act on all of these
    Local $aVars = ['     Trim Me 1     ', '   Trim Me 2    ', '       Trim Me 3  ']

    ; Function/Params of what you want to apply to a list/set of vars
    Local $aFunction = [StringStripWS, 3]

    ; Apply function to array elements
    For $i = 0 to UBound($aVars) - 1
        $aVars[$i] = $aFunction[0]($aVars[$i], $aFunction[1])
    Next

    _ArrayDisplay($aVars)
EndFunc

 

[bailey1274]

The goal is to have a callable function that can be used and updates variables, not arrays of values. I think with the limitations of autoit, it may not be possible. It could be achieved using all global variables but that's something I don't want to do. The only way to have a callable function that updates the original local variables in the function would to be using byRefs but also having an arbitrary number of params. This can't be done since optional byRefs aren't supported which is why I put the values into an array with the corresponding names next to them to use after the array has been cleaned and then assign back to original vars. I was just hoping someone had a not so intuitive way that I'm not seeing how to do it.

[jchd]

Python map() doesn't directly do what you want either: you still have to convert the resulting map object(s) to something else AND initial (caller's side) arguments aren't changed either.

I agree, AutoIt isn't a functional language at all.

[bailey1274]

But python can at least unpack things in one line, The verbosenss of a rather simple task the issue I am trying to handle here. 

[Melba23]

bailey1274,

You can reduce the "reassign" loop quite considerably:

; Reassign our updated array back to our original variables
For $var = 0 to UBound($VarArr) - 1 Step 2
    Assign($VarArr[$var + 1], $VarArr[$var]) ; Assign value to correct name
Next

Not quite a single line - but rather more concise than your initial effort.

M23