Accessing PathCleanupSpec with AutoIT

[Graesholt]

Hey guys,

I hope I'm posting this in the correct place.

 

I am trying to access PathCleanupSpec in AutoIT, much in the way these things are called in the WinAPIShPath.au3 file. It's not working out.

Here is some code...

Local $Badstring = 'jo|h*nj/oh<n:jo>h?n"j|oh/njo*h>nj:oh"n|j*ohnj/o?hnj|o:h?njohn'

Local $Goodstring = 'Placeholder'

_WinAPI_PathCleanupSpec($Badstring, $Goodstring)

MsgBox(0, 'john!', $Goodstring)

Exit

Func _WinAPI_PathCleanupSpec($sInFilePath, $sOutFilePath)
    MsgBox(0, 'john!', $sInFilePath & ' ' & $sOutFilePath) ; DEBUG

    Local $aRet = DllCall('shlobj_core.dll', 'int', 'PathCleanupSpec', 'wstr', $sInFilePath, 'wstr', $sOutFilePath)                         

    MsgBox(0, 'john!', $sInFilePath & ' ' & $sOutFilePath) ; DEBUG

    Return $sOutFilePath
EndFunc   ;==>_WinAPI_PathCleanupSpec

I tried some stuff, but I feel like I might be out of my depth.

Does anyone have any wisdom to share?

 

Is it even possible? (because I'll take no for an answer in that regard...)

Thank you for your time!

[jchd]

There are many errors in your code.

First you don't follow the API specifications: read again https://docs.microsoft.com/en-us/windows/win32/api/shlobj_core/nf-shlobj_core-pathcleanupspec

The first argument is a fully qualified valid path.  The second argument is a filename to be cleaned; this string is "cleaned" on-place.

The dll to use is shell32.dll as specified in the function description.

You need to retrieve the changed file name from the array returned by DllCall.

Working code:

Local $sPath = 'D:\Placeholder\subdir'
Local $sFile = 'jo|h*nj/oh<n:jo>h?n"j|oh/njo*h>nj:oh"n|j*ohnj/o?hnj|o:h?njohn'

Local $sFixedFile = _WinAPI_PathCleanupSpec($sPath, $sFile)
ConsoleWrite($sPath & '\' & $sFixedFile)

Func _WinAPI_PathCleanupSpec($sPathName, $sFileName)
    Local $aRet = DllCall('shell32.dll', 'int', 'PathCleanupSpec', 'wstr', $sPathName, 'wstr', $sFileName)
    Return $aRet[2]
EndFunc   ;==>_WinAPI_PathCleanupSpec

 

[water]

Welcome to AutoIt and the forum!

As far as I understand DLLCall you should

• check for errors after the call (@error <> 0)
• get the result of the function returned in an array

This is described in the help file.

BTW: "It's not working out." doesn't help much. Describe what you expect and what you get as a result (wrong string, error code etc.)

[Graesholt]

Fair critisism.

In this small example, what I want to happen is have a string returned without any special characters (This string would be "johnjohnjohnjohnjohnjohnjohnjohnjohnjohn").

This is not working out, by it not seeming to change the string at all.

Sorry for leaving this out.

 

I will do my best to attempt to apply your advice...

[jchd]

Did you at least run my code?

Another way to achieve the same thing PathCleanupSpec() does (except the 8.3 part, but who uses old-FAT now?):

Local $sPath = 'D:\Placeholder\subdir'
Local $sFile = 'jo|h*nj/oh<n:jo>h?n"j|oh/njo*h>nj:oh"n|j*ohnj/o?hnj|o:h?n\john'

Local $sFixedFile = StringRegExpReplace(StringReplace($sFile, '/', '-'), '[\\:*?"<>|]', '')
ConsoleWrite($sPath & '\' & $sFixedFile & @LF)

Local $sFixedFile = _WinAPI_PathCleanupSpec($sPath, $sFile)
ConsoleWrite($sPath & '\' & $sFixedFile & @LF)

Func _WinAPI_PathCleanupSpec($sPathName, $sFileName)
    Local $aRet = DllCall('shell32.dll', 'int', 'PathCleanupSpec', 'wstr', $sPathName, 'wstr', $sFileName)
    Return $aRet[2]
EndFunc   ;==>_WinAPI_PathCleanupSpec

If you insist on removing forward slashes instead of replacing them by a dash, then simply use this:

Local $sPath = 'D:\Placeholder\subdir'
Local $sFile = 'jo|h*nj/oh<n:jo>h?n"j|oh/njo*h>nj:oh"n|j*ohnj/o?hnj|o:h?n\john'

Local $sFixedFile = StringRegExpReplace($sFile, '[\\/:*?"<>|]', '')
ConsoleWrite($sPath & '\' & $sFixedFile & @LF)

 

Edited June 22, 2020 by jchd
Forgot the 8.3 case

[Melba23]

Graesholt,

The path returned from the DLL call is :

Quote

johnj-ohnjohnjoh-njohnjohnjohnj-ohnjohnjohn+

all the remaining characters are legal in a Windows filename, so the call is doing exactly what you ask it to do.

if you want to get rid of all non-alphabetic characters then you need a RegEx like this:

Local $sFile = 'jo|h*nj/oh<n:jo>h?n"j|oh/njo*h>nj:oh"n|j*ohnj/o?hnj|o:h?njohn'
Local $sCleaned = StringRegExpReplace($sFile, "[^[:alpha:]]", "")
ConsoleWrite($sCleaned & @CRLF)

But no doubt a RegEx guru will be along soon to tell me there is a better way - as usual!

M23

Edit: Or even before I get around to posting! 

Edited June 22, 2020 by Melba23

[jchd]

To be honest, the real truth is a bit more involved.  Windows is Unicode-aware and supports a very large number of characters in filenames (I'm restricting to FAT32 and NTFS here, of course).

[:alpha:] isn't enough as it wouldn't allow the dot(s) of extension(s) as well as many other commonly used characters like - or _ and many others.

Yet not all symbols are valid in filenames.

FileWrite("e=mc².123€.©®.⅜+⅝=1.‟†‡”.ℙℚℝℤℕ.47Ω.txt", "Eureka") works fine but not all symbols do.

Ideally one would also need to filter out many Unicode control characters and possibly more things.

 

[Graesholt]

jchd, I don't know what happened, the error was probably on my end, but I didn't see your first response when I responded myself (thus I only intended to respond to water).

My sincere apologies.
 

But oh my holy stars, thanks a bunch, man!

You really broke this one down to a level I could follow.

Thank you so much for your time, everyone, and have a GREAT day!

[jchd]

No worry.  Glad it works for you.