Function call with ByRef

[HurleyShanabarger]

Hi,

there is something that I do not understand. I wanted to address the index in an array by increasing the index variable using a function call with ByRef. But the result seems strange to me:

expandcollapse popup

#Region Includes
    #include <Array.au3>
#EndRegion Includes

#Region Main
    _Main_1()
    _Main_2()

    Func _Main_1()
        Local $aArr[4]
        Local $iInx = -1

        $aArr[_Increase($iInx)] = "Index " & $iInx     ; $iInx should be 0 in array, and index in ArrayDisplay should be 0
        $aArr[_Increase($iInx)] = "Index " & $iInx     ; $iInx should be 0 in array, and index in ArrayDisplay should be 0
        _ArrayDisplay($aArr)
    EndFunc   ;==>_Main_1

    Func _Main_2()
        Local $aArr[4]
        Local $iInx = -1, $iInx_Return

        $iInx_Return = _Increase($iInx)     ; Increase value from -1
        ConsoleWrite($iInx_Return & @TAB & $iInx & @CRLF)     ; Both values should be equal
        $aArr[$iInx] = "Index " & $iInx

        $iInx_Return = _Increase($iInx)
        ConsoleWrite($iInx_Return & @TAB & $iInx & @CRLF)     ; Both values should be equal
        $aArr[$iInx] = "Index " & $iInx
        _ArrayDisplay($aArr)
    EndFunc   ;==>_Main_2
#EndRegion Main

#Region Functions
    Func _Increase(ByRef $iInt)
        $iInt += 1
        Return $iInt
    EndFunc   ;==>_Increase
#EndRegion Functions

Can someone explain what I am missing?

[Aelc]

If you want to increase an array you should take a look on Dim/Redim 

you have to declare them again to resize it

Edited December 14, 2020 by Aelc

[Jos]

It mostly helps when you also tell us what the problem is or the part you don't find logical ....or you want us to guess?.  

Edited December 14, 2020 by Jos

[HurleyShanabarger]

Sure thing 😉

I don't want to resize the array, but increase the index pointer. When I do it like that:

$aArr[_Increase($iInx)] = "Index " & $iInx

The functional _Increase gets called twice if you look at the debug output:

#Region Includes
    #include <Array.au3>
#EndRegion Includes

#Region Main
    _Main_1()

    Func _Main_1()
        Local $aArr[4]
        Local $iInx = -1

        ConsoleWrite($iInx & @CRLF) ; Should be -1
        $aArr[_Increase($iInx)] = "Index " & $iInx     ; $iInx should be 0 in array, and index in ArrayDisplay should be 0
        ConsoleWrite($iInx & @CRLF); Should be 0, but is 1
    EndFunc   ;==>_Main_1

#EndRegion Main

#Region Functions
    Func _Increase(ByRef $iInt, $iLine = @ScriptLineNumber)
        Local Static $S_iCall = -1
        $S_iCall += 1
        ConsoleWrite("Call no. " & $S_iCall & " with value " & $iInt & " from line " & $iLine & @CRLF)
        $iInt += 1
        Return $iInt
    EndFunc   ;==>_Increase
#EndRegion Functions

So I am wondering why the function _Increase gets called twice.

[Jos]

mmm ... guess it is too late for me to understand why this is happening,but this simple version sums up the issue: The second liune calls the Func 2 times in stead of one time:

Local $iInx = -1
dim $aArr[4]

ConsoleWrite($iInx & @CRLF) ; is -1
_Increase($iInx)            ; calls the func 1 time
ConsoleWrite($iInx & @CRLF) ; is 0
$aArr[_Increase($iInx)] = 1 ; calls the func 2 times
ConsoleWrite($iInx & @CRLF) ; Should be 1, but is 2

Func _Increase(ByRef $iInt, $iLine = @ScriptLineNumber)
     ConsoleWrite("value=" & $iInt & " from line " & $iLine & @CRLF)
    $iInt += 1
    Return $iInt
EndFunc   ;==>_Increase

Change the Dim $aArr[4] to  1, run it and 2 and run it and wonder about the result.... I am going to sleep on it. 

Jos

[HurleyShanabarger]

Thank you, for presenting the issue in a better way and have a good night and some dreams free from AutoIt.

[Aelc]

Ahh i see...

It doesn't look like it's a ByRef bug... It also happens with a global variable. or did i miss something?

Global $iint = -1
Dim $aArr[4]

ConsoleWrite($iint & @CRLF) ; is -1
_Increase()            ; calls the func 1 time
ConsoleWrite($iint & @CRLF) ; is 0
$aArr[_Increase()] = 1 ; calls the func 2 times
ConsoleWrite($iint & @CRLF) ; Should be 1, but is 2

Func _Increase()
    $iInt += 1
    ConsoleWrite("value=" & $iInt & @CRLF)
    Return $iInt
EndFunc   ;==>_Increase

 

Edited December 15, 2020 by Aelc

[pseakins]

I ran your code and could see the problem but thought I would have breakfast before posting a response. On return I see there are several replies. Nonetheless, here is my response;

Now retired, but when working for an AntiVirus company I used AutoIt to develop certain in house tools. I was often frustrated when stuff didn't work that should have worked. It is a wonderful tool but has some idiosyncrasies.

Anyway, I eventually learned that you are playing with fire trying to include functions within expressions. I learned to break my complex expressions down into a series of simplified line by line steps.

The issue here has something to do with AutoIt rules of precedence in evaluating the expression. For some reason, which I am not going to bother to research, your function is being evaluated twice leading to the double increment.

Simplify your code. Don't try anything fancy like placing functions within an expression, particularly as you have done, within the [] referencing an array element.

Also when passing your variable to the function, "byref", any operation within the function acts directly on the variable. There is no point returning the variable with a "Return $iInt" statement as this is redundant.

This works;

Func _Main_1()
  Local $aArr[4]
  Local $iInx = -1
  _Increase($iInx)
  $aArr[$iInx] = "Index " & $iInx           ; $iInx should be 0 in array, and index in ArrayDisplay should be 0
  _Increase($iInx)
  $aArr[$iInx] = "Index " & $iInx           ; $iInx should be 0 in array, and index in ArrayDisplay should be 0
  _ArrayDisplay($aArr)
EndFunc   ;==>_Main_1

 

Edited December 15, 2020 by pseakins
intro

[Nine]

It is not global nor byref bug, it is an array bug.  Calling a function inside an array assignment calls it twice :

#include <Array.au3>

Local $aArr[4]

$aArr[_Call()] = 1 ; calls the func 2 times
_ArrayDisplay($aArr)

Func _Call()
    ConsoleWrite("called" & @CRLF)
EndFunc

Applies also to 2D arrays...

Edited December 15, 2020 by Nine

[Jos]

5 hours ago, Nine said:

It is not global nor byref bug, it is an array bug.  Calling a function inside an array assignment calls it twice :

Correct ...  nothing to do with byref of global  and all could have known when they would have done what I stated!  

  

10 hours ago, Jos said:

Change the Dim $aArr[4] to  1, run it and 2 and run it and wonder about the result.... I am going to sleep on it. 

 

Edited December 15, 2020 by Jos

[Jos]

This issue seems to be resolved in the current Alpha version, so guess it was already known and worked on..

Edited December 15, 2020 by Jos

[HurleyShanabarger]

#include <Array.au3>

Local $aArr[4] = ["x", "y", "z", "a"]
Local $sVal = $aArr[_Call()]
ConsoleWrite($sVal & @CRLF)

Func _Call()
    ConsoleWrite("called" & @CRLF)
EndFunc

Seems only to be called twice, when the value of the array is changed.

 

@Jos, good to know. Is there clue, when a new version will be available?

Edited December 15, 2020 by HurleyShanabarger

[Nine]

15 minutes ago, HurleyShanabarger said:

Seems only to be called twice, when the value of the array is changed.

And it is not call twice either on declaration :

#include <Array.au3>

Local $aArr[_Call()+1] = [0]
Local $sVal = $aArr[_Call()]
ConsoleWrite($sVal & @CRLF)

$aArr[_Call()] = 1 ; calls the func 2 times
_ArrayDisplay($aArr)

Func _Call()
    ConsoleWrite("called" & @CRLF)
EndFunc

 

[mLipok]

1 hour ago, HurleyShanabarger said:

@Jos, good to know. Is there clue, when a new version will be available?

Take a look on:
https://www.autoitscript.com/trac/autoit/timeline

there is many fixes and changes made by @jpm already sent to @Jon but you must to know that all we here (including @Jon ) we are volunteers.

It will be available when @Jon find spare time to validate the code and release version.

Please do not ask further question like "When ...."

 

[Jos]

6 hours ago, HurleyShanabarger said:

@Jos, good to know. Is there clue, when a new version will be available?

No and do not bet it will be anytime soon, so just use a workaround for the moment by separating them :

_Increase($iInx) 
$aArr[iInx] = 1

 

5 hours ago, mLipok said:

It will be available when @Jon find spare time to validate the code and release version.

Let's make sure we do not create any expectations here and for now assume it isn't there.
I merely made the statement to indicate that there is no need to submit a bug report as it has been worked on.

Jos

Edited December 15, 2020 by Jos

[Nine]

Map seems immune to this bug :

Local $map[]
$map[_Call()] = "Test"

Func _Call()
    ConsoleWrite("called" & @CRLF)
EndFunc