NC wrapper problem

[Rob99]

hi fellows , I have a program that receives tcp strings, with netcat I can send the string I want, so I would like to create a wrapper for netcat, but I can't go on practically opens the cmd but it stays there waiting for the command that never arrives

$path="C:\Users\Rob99\Documents\PROGRAMMAZIONE\AUTOIT\GUI_NJ_MT4"
$iPID = RunWait(@ComSpec & " /c "&$path&"\nc64.exe -c  127.0.0.1 23457", $path, @SW_MAXIMIZE, BitOR($STDERR_CHILD, $STDOUT_CHILD))
StdinWrite($iPID, "HI" & @CRLF)

thanks to all those who want to help me

[Musashi]

Have you tried Run  instead of RunWait ?

[Rob99]

yes  but  appear one second cmd  and close it

[mLipok]

1 hour ago, Rob99 said:

nc64.exe

What program is that?

 

[FrancescoDiMuro]

1 minute ago, mLipok said:

What program is that?

https://github.com/int0x33/nc.exe

[JockoDundee]

14 minutes ago, Rob99 said:

yes  but  appear one second cmd  and close it

Well, you definitely want Run, not RunWait, since RunWait will give you the exit code, not a handle to Stdio.  The way you have the code right now, even if you were to change it to Run would still just close if your program is not still running.

Did you try it in a loop with Run?

Do you need the netcat to be bidirectional? 

[mLipok]

@Rob99

check this:

 

[Nine]

There is a number of ways to interact with DOS console.  In your case, I believe you should enter in a convo mode.  Here how you would do it :

expandcollapse popup

;#AutoIt3Wrapper_Change2CUI=y
#include <WinAPIConv.au3>
#include <Constants.au3>

Opt("MustDeclareVars", 1)

Const $sPath = "C:\Users\Rob99\Documents\PROGRAMMAZIONE\AUTOIT\GUI_NJ_MT4"

Local $iPID = Run(@ComSpec, "", @SW_SHOW, $STDIN_CHILD+$STDERR_MERGED)
ProcessWait($iPID)
MsgBox ($MB_SYSTEMMODAL,"",ReadStream ($iPID))

StdinWrite ($iPID, "cd " & $sPath & @CRLF)
MsgBox ($MB_SYSTEMMODAL,"",ReadStream ($iPID))

StdinWrite ($iPID, "nc64.exe -c  127.0.0.1 23457" & @CRLF)
MsgBox ($MB_SYSTEMMODAL,"",ReadStream ($iPID))

Local $sRep
While True
  $sRep = InputBox("Convo with DOS console", "Enter DOS command :", "", "", 500)
  If @error Then ExitLoop
  StdinWrite ($iPID, $sRep & @CRLF)
  MsgBox ($MB_SYSTEMMODAL,"", ReadStream($iPID))
WEnd

Func ReadStream ($iPID, $iDelay = 300)
  Local $vData, $sStream
  Do
    Sleep ($iDelay)
    $vData = StdoutRead($iPID)
    If @error Then
      StdioClose($iPID)
      ProcessClose($iPID)
      Exit ConsoleWrite("[ERROR] reading child Stream" & @CRLF)
    EndIf
    ; ConsoleWrite($vData & @CRLF)
    $sStream &= $vData
  Until $vData = ""
  Return _WinAPI_OemToChar ($sStream)
EndFunc

I hard coded the first 2 commands, so you understand how this snippet is working...Enjoy !

Edited January 19, 2021 by Nine
corrected a small bug

[Rob99]

@Nine   thanks so muchhhh, I would never have gotten there thanks now the studio and if I have any doubts I ask,

 

thanks at all

[Rob99]

HI @Nine 

1. I'm trying to run the script, but I think it doesn't work yet let me explain:
when I launch the script and he tries to connect to my "server" the program returns the HELLO of my server when it asks me to send a command I give the command but nothing happen.

2. can you explain to me why  you use  this  (or if you have some wiki for study thanks)    Local $ iPID = Run (@ComSpec, "", @SW_SHOW, $ STDIN_CHILD + $ STDERR_MERGED) and not  this form   To run DOS (console) commands, try Run(@ComSpec & " /c " & 'commandName', "", @SW_HIDE)    ; don't forget " " before "/c"

thanks again

 

[Nine]

1.  I do not know why because you did not give anything to work with.  I am using this method for many purposes and it is working fine to send multiple commands one after the other.

2. I use this form of communication with the DOS console as it is a persistent (convo) approach, instead of launching multiple cmd.exe repeatedly. Also remember that the form of Run(@comspec & " /c someapps.exe") is not always required.  You can run most exe with Run("someapps.exe") directly without the need of cmd.exe.

But use whatever form you feel confortable with. As long as it working...

[Rob99]

@Nine sorry your code  work the problem been in my server now work thanks so much

[Nine]

  Glad you found a solution.