StringRegExp - Verbatim sequence

[HurleyShanabarger]

If I want to prevent metacharacter having an effect on the regular expression, I can use \Q ... \E, where ... is the pattern. The search-pattern is entered by the user and the script actually adds some stuff before \Q and after \E. When the user is inserting \E in his pattern, it of course breaks the overall pattern. What would be the right approach to "escape", if the user enters \E?

 

Dim $sText_1 = "C:\Test (example)\Everything"
Dim $sUserPattern_1 = "Test (example)\Every"
ConsoleWrite(StringRegExp($sText_1, "^.+?\Q" & $sUserPattern_1 & "\E.+?$") & @TAB & "This fails, as user inserts >>\E<<" & @CRLF)

Dim $sText_2 = "C:\Test (example)\Fallout"
Dim $sUserPattern_2 = "Test (example)\Fall"
ConsoleWrite(StringRegExp($sText_2, "^.+?\Q" & $sUserPattern_2 & "\E.+?$") & @TAB & "No problem here" & @CRLF)

 

Edited February 21, 2021 by HurleyShanabarger

[MrCreatoR]

The best solution is to escape specials chars:

Dim $sText_1 = "C:\Test (example)\Everything"
Dim $sUserPattern_1 = "Test (example)\Every"
ConsoleWrite(StringRegExp($sText_1, "^.+?" & _StringRegExpEscapeChars($sUserPattern_1) & ".+?$") & @TAB & "No problem here" & @CRLF)

Dim $sText_2 = "C:\Test (example)\Fallout"
Dim $sUserPattern_2 = "Test (example)\Fall"
ConsoleWrite(StringRegExp($sText_2, "^.+?" & _StringRegExpEscapeChars($sUserPattern_2) & ".+?$") & @TAB & "No problem here" & @CRLF)

Func _StringRegExpEscapeChars($sString, $sChars = '')
    If StringStripWS($sChars, 8) = '' Then
        $sChars = '\]\[<>\^\\.+*?$(){}=!|:'
    EndIf
    
    Return StringRegExpReplace($sString, '([' & $sChars & '])', '\\\1')
EndFunc

 

[mikell]

@MrCreatoR

May I suggest to remove the $sChars param 

Dim $sText_1 = "C:\Test (example)\Everything"
Dim $sUserPattern_1 = "Test (example)\Every"

$p = _StringRegExpEscapeChars($sUserPattern_1, "\")
ConsoleWrite($p & @CRLF)
ConsoleWrite(StringRegExp($sText_1, "^.+?" & $p & ".+?$") & @CRLF)

Func _StringRegExpEscapeChars($sString, $sChars = '')
    If StringStripWS($sChars, 8) = '' Then
        $sChars = '\]\[<>\^\\.+*?$(){}=!|:'
    EndIf
    Return StringRegExpReplace($sString, '([' & $sChars & '])', '\\\1')
EndFunc

 

[MrCreatoR]

3 hours ago, mikell said:

May I suggest to remove the $sChars param

Why? You are using it wrong, this param is to specify particular chars to escape...

$p = _StringRegExpEscapeChars($sUserPattern_1, "\\\(\)")

 

Edited February 21, 2021 by MrCreatoR

[AspirinJunkie]

If you want to keep your \Q...\E construct, you can also solve it like this:

Dim $sText_1 = "C:\Test (example)\\\Everything"
Dim $sUserPattern_1 = "Test (example)\\\Every"
ConsoleWrite(StringRegExp($sText_1, "^.+?\Q" & StringRegExpReplace($sUserPattern_1, '\\E', '\\E\\\\E\\Q') & "\E.+?$") & @TAB & "This fails nothing more" & @CRLF)

Dim $sText_2 = "C:\Test (example)\Eallout"
Dim $sUserPattern_2 = "Test (example)\Eall"
ConsoleWrite(StringRegExp($sText_2, "^.+?" & _RegExEscape($sUserPattern_2) & ".+?$") & @TAB & "No problem here" & @CRLF)

; same wrapped in a function
Func _RegExEscape($sString)
    Return "\Q" & StringRegExpReplace($sString, '\\E', '\\E\\\\E\\Q') & "\E"
EndFunc

Also a escape function is a lot more easier with this approach.

Edited February 22, 2021 by AspirinJunkie

[mikell]

9 hours ago, MrCreatoR said:

Why?

1/ because it is not convenient. I know that I used it wrong but to be really handy such a param should be used like this...
More, to make it work all the specials chars in the string must be first located by the user then mentioned and escaped in the param, so the function is not useful any more

Dim $sText_1 = "C:\Test (example)\Everything"
Dim $sUserPattern_1 = "Test \(example\)\\Every"
ConsoleWrite(StringRegExp($sText_1, "^.+?" & $sUserPattern_1 & ".+?$") & @CRLF)

2/ because it is useless. The regex engine is powerful enough to find and treat all the specials chars by itself - and btw the user saves time

Dim $sText_1 = "C:\Test (example)\Everything"
Dim $sUserPattern_1 = "Test (example)\Every"

$p = _StringRegExpEscapeChars($sUserPattern_1)
ConsoleWrite($p & @CRLF)
ConsoleWrite(StringRegExp($sText_1, "^.+?" & $p & ".+?$") & @CRLF)

Func _StringRegExpEscapeChars($sString)
    Local $sChars = '\]\[<>\^\\.+*?$(){}=!|:'
    Return StringRegExpReplace($sString, '([' & $sChars & '])', '\\\1')
EndFunc

 

[MrCreatoR]

47 minutes ago, mikell said:

to make it work all the specials chars in the string must be first located by the user then mentioned and escaped in the param

The idea is to allow to escape not all chars.

47 minutes ago, mikell said:

it is useless

I disagree (in this case yes, but sometimes no).

[HurleyShanabarger]

I never cam back to you guys and just remembered as I run into the same issue.

Thanks a lot, it solves my issue just perfectly!