_Excel_RangeFind in a specific sheet

[kawumm3000]

Hi,
as the title says, I want to use _Excel_RangeFind in a specific sheet. How can I choose the sheet here?

Thx

[Nine]

The third param specify the range.  Something like this :

#include <Excel.au3>

Local $oExcel = _Excel_Open()
Local $oWorkbook = _Excel_BookOpen($oExcel, @MyDocumentsDir & "\Test.xls")

Local $aResult = _Excel_RangeFind($oWorkbook, "Test", $oWorkbook.sheets(2).usedRange)
If @error Then Exit MsgBox($MB_SYSTEMMODAL, "RangeFind Error", @error & "/" & @extended)
_ArrayDisplay($aResult)

 

[FrancescoDiMuro]

@kawumm3000
You could use Worksheets collection to search in a specific sheet:

#include <Array.au3>
#include <Excel.au3>

Test()

Func Test()

    Local $strFileName = @ScriptDir & "\Test.xlsx", _
          $objExcel, _
          $objWorkbook, _
          $arrResult


    $objExcel = _Excel_Open()
    If @error Then Return ConsoleWrite("_Excel_Open ERR: " & @error & @CRLF)

    $objWorkbook = _Excel_BookOpen($objExcel, $strFileName)
    If @error Then Return ConsoleWrite("_Excel_BookOpen ERR: " & @error & @CRLF)

    ; Use $objWorkbook.Worksheets(SheetNumber).UsedRange or $objWorkbook.Worksheets(SheetName).UsedRange
    $arrResult = _Excel_RangeFind($objWorkbook, "TextToFind", $objWorkbook.Worksheets(1).UsedRange)
    If @error Then Return ConsoleWrite("_Excel_RangeFind ERR: " & @error & @CRLF)

    If UBound($arrResult) > 0 Then _ArrayDisplay($arrResult)

    _Excel_BookClose($objWorkbook)
    _Excel_Close($objExcel)

EndFunc

@Nine 

Edited March 12, 2021 by FrancescoDiMuro

[Nine]

Great minds think alike