Advice mode from mouse position

[Asaf_Ank]

How can I get from mouse position the button advice mode  if exist?

 

[Jos]

Welcome, but I have no idea what you are asking. Could you try to explain what you are trying to do again?

[Asaf_Ank]

Is it possible to get the information about "Advanced mode"  from mouse location x,y ?

 

[Nine]

Yes :

expandcollapse popup

#include <Constants.au3>
#include <WindowsConstants.au3>
#include <StructureConstants.au3>
#include <WinAPISysWin.au3>
#include <APISysConstants.au3>

Opt("MustDeclareVars", 1)

HotKeySet("{ESC}", _Exit)

Example()

Func Example()
  Local $hWnd, $tPoint = DllStructCreate($tagPOINT)
  Local $hTarget, $sClass, $sClassList, $iInstance, $hCtrl
  While 1
    $tPoint.X = MouseGetPos(0)
    $tPoint.Y = MouseGetPos(1)
    $hTarget = _WinAPI_WindowFromPoint($tPoint)
    $sClass = _WinAPI_GetClassName($hTarget)
    $hWnd = _WinAPI_GetAncestor($hTarget, $GA_ROOT)
    ConsoleWrite($hWnd & "/" & $hTarget & "/" & $sClass)
    If $hWnd <> $hTarget And $sClass <> "" Then
      $sClassList = WinGetClassList($hWnd)
      StringReplace($sClassList, $sClass, $sClass)
      $iInstance = @extended
      ConsoleWrite("(" & $iInstance & ") ")
      For $i = 1 To $iInstance
        $hCtrl = ControlGetHandle($hWnd, "", $sClass & $i)
        If $hCtrl = $hTarget Then
          ConsoleWrite(" [CLASS:" & $sClass & "; INSTANCE:" & $i & "]")
          ExitLoop
        EndIf
      Next
    EndIf
    ConsoleWrite(@CRLF)
    Sleep(500)
  WEnd
EndFunc   ;==>Example

Func _Exit()
  Exit
EndFunc   ;==>_Exit

 

[Nine]

Let me review my previous post.  After playing with it, I noticed that it was not able to detect disabled controls.  So here a new version :

expandcollapse popup

#include <Constants.au3>
#include <WindowsConstants.au3>
#include <StructureConstants.au3>
#include <WinAPISysWin.au3>
#include <APISysConstants.au3>
#include <WinAPIConv.au3>

Opt("MustDeclareVars", 1)

HotKeySet("{ESC}", _Exit)

Example()

Func Example()
  Local $hWnd, $tPoint = DllStructCreate($tagPOINT)
  Local $hTarget, $sClass, $sClassList, $iInstance, $hCtrl
  While 1
    $tPoint.X = MouseGetPos(0)
    $tPoint.Y = MouseGetPos(1)
    $hTarget = _WinAPI_WindowFromPoint($tPoint)
    $hWnd = _WinAPI_GetAncestor($hTarget, $GA_ROOT)
    If $hTarget = $hWnd Then
      _WinAPI_ScreenToClient($hWnd, $tPoint)
      $hTarget = _WinAPI_ChildWindowFromPointEx ($hWnd, $tPOINT)
    EndIf
    $sClass = _WinAPI_GetClassName($hTarget)
    ConsoleWrite ($hWnd & "/" & $hTarget & "/" & $sClass)
    If $hWnd <> $hTarget And $sClass <> "" Then
      $sClassList = WinGetClassList($hWnd)
      StringReplace($sClassList, $sClass, $sClass)
      $iInstance = @extended
      ConsoleWrite ("(" & $iInstance & ") ")
      For $i = 1 To $iInstance
        $hCtrl = ControlGetHandle($hWnd, "", $sClass & $i)
        If $hCtrl = $hTarget Then
          ConsoleWrite (" [CLASS:"  & $sClass & "; INSTANCE:" & $i & "]")
          ExitLoop
        EndIf
      Next
    EndIf
    ConsoleWrite (@CRLF)
    Sleep(500)
  WEnd
EndFunc   ;==>Example

Func _Exit()
  Exit
EndFunc   ;==>_Exit

I could have modified the previous post, but I thought you would prefer a new snippet so you can compare and study the changes made.

[Asaf_Ank]

Is it possible to do it in C#?

 

 

[Nine]

Just now, Asaf_Ank said:

Is it possible to do it in C#?

Meh ?  It is an AutoIt forum here not a C# !

But to answer your question : yes.

[Asaf_Ank]

Yes.. In AutoIt DLL import to C#.

I asking that is because some of the functions you used do not exist in the DLL.

AutoItX3.Assembly.xml

AutoItX3.Assembly.dll

Edited March 22, 2021 by Asaf_Ank

[Nine]

I see.  But most of the functions are WinAPI which are available in C#.