[SOLVED] _ArrayDelete example not working?

[JackER4565]

Hi all, I have a question about the example in _arrayDelete.

If I run it on the spot with the example file it doesn't delete the row 3 of the array: (image 1)

 

#include <Array.au3>

Local $aArray[5] = [0, 1, 2, 3, 4]

_ArrayDisplay($aArray, "Original")
_ArrayDelete($aArray, 2)
_ArrayDisplay($aArray, "Element 2 deleted")

Local $aArray_Base[25][4]
For $i = 0 To 24
    For $j = 0 To 3
        $aArray_Base[$i][$j] = $i & "-" & $j
    Next
Next

; Single row
$aArray = $aArray_Base
_ArrayDisplay($aArray, "BEFORE deletion")
_ArrayDelete($aArray, 7)
_ArrayDisplay($aArray, "SINGLE ROW deleted")

; Range string
$aArray = $aArray_Base
Local $sRange = "0;11-15;24"
_ArrayDisplay($aArray, "BEFORE deletion")
_ArrayDelete($aArray, $sRange)
ConsoleWrite(" " & @error & @CRLF)
_ArrayDisplay($aArray, "RANGE STRING deleted")

; 1D array
$aArray = $aArray_Base
Local $aDel[4] = [3, 5, 11, 13]
_ArrayDisplay($aArray, "BEFORE deletion")
_ArrayDelete($aArray, $aDel)
_ArrayDisplay($aArray, "RANGE ARRAY deleted")

It should delete the rows number 3, 5, 11 and 13 but the 3rd doesn't get deleted.

Additionaly I've tryied modify the example and it works even worst. The error returns 0. (image 2)

 

Thanks in advance!

Edited March 31, 2021 by JackER4565
Solved

[FrancescoDiMuro]

25 minutes ago, JackER4565 said:

It should delete the rows number 3, 5, 11 and 13 but the 3rd doesn't get deleted.

When using the $vRange as a 1D array, you have to specify the number of elements to delete in the 0th element of your $vRange array, as stated in the Help file:

$vRange can also be a 1D array listing all rows to be deleted with the count in the [0] element.

Cheers

Edited March 31, 2021 by FrancescoDiMuro

[JackER4565]

1 minute ago, FrancescoDiMuro said:

When using the $vRange as a 1D array, you have to specify the number of elements to delete in the 0th element of your $vRange array, as stated in the Help file:

$vRange can also be a 1D array listing all rows to be deleted with the count in the [0] element.

Cheers

Do'h thanks so much!!