how to take control of the active window with an open Excel book?

[Tick]

Hello dear friends!

The stock application I work with generates reports in the form of Excel files that it opens on the screen. I would like to automatically receive some information from them, and then close these particular windows. But I can't figure out how to work with this window using Autoit tools? For example, when I try to close this particular window, all Excel windows are closed. Or just this process - but several at once.

Quote

while True
WinWaitActive("_CurrentDay_","", 0);жду окна
;Send ( "!{F4}")

WinClose("_CurrentDay_")

sleep(5000)

WEnd

 

I tried to iterate over all Excel processes and all open books to select the ones I needed and close them. But this procedure often gives an error.

Quote

$nCount = 0
While True
    Local $obj = ObjGet("", "Excel.Application", $nCount + 1)
    If @error Then ExitLoop
     
    
     $books=$obj.Application.Workbooks.Count
     MsgBox(4096, "",$books&" books")
     for $i=1 to $books
        $obj.DisplayAlerts = False

        MsgBox(4096, "",$obj.application.workbooks($i).name)
        $obj.application.workbooks($i).close

        If @error Then ExitLoop
          sleep(500)
     Next

     
    $nCount += 1
WEnd

What am I doing wrong?

I would be grateful for your advice.

[Subz]

Have a look at the _Excel functions in the help file, try _Excel_BookAttach then _Excel_BookClose to close the workbook.

[Tick]

2 hours ago, Subz said:

Have a look at the _Excel functions in the help file, try _Excel_BookAttach then _Excel_BookClose to close the workbook.

Subz thanks for the answer! i tried to use your advice. unfortunately, I didn't succeed. Doesn't return values from the cell.

#include <Array.au3>
#include <Excel.au3>
#include <MsgBoxConstants.au3>
Opt("WinTitleMatchMode", 2)

while True
WinWaitActive("_CurrentDay","", 0)
$Active=WinGetHandle("_CurrentDay")
$oExcel = _Excel_open()
$oWorkbook = _Excel_Bookattach($Active)
$read=_Excel_Rangeread($oWorkbook,Default,"A1")
MsgBox(0,0,$read)

_Excel_BookClose($oWorkbook)
sleep(5000)
WEnd

Maybe I got it wrong somewhere?

[Tick]

and does not close the excel 

[Tick]

#include <Array.au3>
#include <Excel.au3>
#include <MsgBoxConstants.au3>
Opt("WinTitleMatchMode", 2)

while True
WinWaitActive("_CurrentDay","", 0)
$Active=WinGetTitle("_CurrentDay")
$oExcel = _Excel_open()
$oWorkbook = _Excel_Bookattach($Active,"Title")
$read=_Excel_Rangeread($oWorkbook,Default,"A1")
MsgBox(0,0,$read)

_Excel_BookClose($oWorkbook)
sleep(5000)
WEnd

fixed obvious bugs. that doesn't work either. Doesn't return a value or close the workbook. Does not give errors. only one book is open.

[Tick]

I think I get it. I needed to exclude _Excel_open - then everything works.

while True
WinWaitActive("_CurrentDay","", 0)
$Active=WinGetTitle("_CurrentDay")
$oWorkbook = _Excel_Bookattach($Active,"Title")

$read=_Excel_Rangeread($oWorkbook,Default,"A1")
MsgBox(0,0,$read)

_Excel_BookClose($oWorkbook, False)
sleep(5000)
WEnd

 

[water]

I suggest to add some error checking:

#include <Excel.au3>
While True
    WinWaitActive("_CurrentDay", "", 0)
    $sWindowTitle = WinGetTitle("_CurrentDay")
    $oWorkbook = _Excel_BookAttach($sWindowTitle, "Title")
    If @error = 0 Then
        $sRangeRead = _Excel_RangeRead($oWorkbook, Default, "A1")
        MsgBox(0, 0, $sRangeRead)
        _Excel_BookClose($oWorkbook, False)
    EndIf
    Sleep(5000)
WEnd