How can I create compatible regex patterns for each language?

[youtuber]

cmd systeminfo output separately for each language so I want to make my mold compatible for all
cmd systeminfo output
 

in English

Original Install Date:     5/26/2020, 12:02:21 AM

in Spanish

Fecha de instalación original :     5/26/2020, 12:02:21 AM

in Russian

Дата установки : 5.26.2020, 12:02:21

 

Local $iPID = Run('systeminfo', '', @SW_HIDE, 2)
If @error Or Not $iPID Then Exit
Local $sStdOut = ""

Do
    Sleep(10)
    $sStdOut &= StdoutRead($iPID)
Until @error

$regex = StringRegExp($sStdOut, "Date:|original:|установки:\h(\d{2}.\d{2}.\d{4})\W(?=[^,])\s\d{2}|(\d{2}\\d{2}\\d{4})\W(?=[^,])\s\d{2}", 3)

If IsArray($regex) Then
    For $Y = 0 To UBound($regex) - 1
    ConsoleWrite($regex[$Y] & @CRLF)
    Next
EndIf

 

 

[FrancescoDiMuro]

@youtuber

Maybe, an easier solution would be to split the systeminfo output with @CRLF and grab the line where the information you are looking for appears, since it should always return the same number of lines in the same order

EDIT:

Or you can use these tricks to get a list of Properties with standard names:

https://ss64.com/nt/systeminfo.html

https://community.idera.com/database-tools/powershell/powertips/b/tips/posts/get-computerinfo-vs-systeminfo-exe-part-1

Edited April 28, 2021 by FrancescoDiMuro

[jchd]

I sincerely doubt that spanish and russian systems show 12-hour times since their locale use a 24-hour clock. Also their date locale is dd/mm/yyyy, just like yours and mine (you're both French IIRC).

[FrancescoDiMuro]

@jchd
I'm italian
By the way, using something like this should work as long as the number of information obtained by systeminfo are the same and in the same order:

#include <String.au3>

Test()

Func Test()

    Local $intPID, _
          $strSTDOutRead, _
          $arrSTDOutRead, _
          $strOriginalInstallationDate


    $intPID = Run('systeminfo', '', @SW_HIDE, 2)
    If @error Then Return ConsoleWrite("Run ERR: " & @error & @CRLF)

    While 1
        $strSTDOutRead &= StdoutRead($intPID)
        If @error Then ExitLoop
    WEnd

    ; ConsoleWrite($strSTDOutRead & @CRLF)

    $arrSTDOutRead = StringSplit($strSTDOutRead, @CRLF, $STR_ENTIRESPLIT)

    ; _ArrayDisplay($arrSTDOutRead)

    $strOriginalInstallationDate = StringRegExp($arrSTDOutRead[11], "[^:]+:\h*(.+)", $STR_REGEXPARRAYMATCH)[0]

    ConsoleWrite("$strOriginalInstallationDate = " & $strOriginalInstallationDate & @CRLF)

EndFunc

Result:

$strOriginalInstallationDate = 10/12/2019, 11:06:12

Then, the Powershell solution would be nice to use as well, isn't it?

Edited April 28, 2021 by FrancescoDiMuro

[youtuber]

Seems to work better 

https://www.autoitscript.com/wiki/Snippets_(_Windows_OS_)#InstallDate.28.29

I fixed it like this works fine for me

ConsoleWrite(_InstallDate() & @CRLF)

Func _InstallDate()
    Local $oWMIService = ObjGet("winmgmts:{impersonationLevel = impersonate}!\\" & "." & "\root\cimv2")
    Local $oColFiles = $oWMIService.ExecQuery("Select * From Win32_OperatingSystem")
    If IsObj($oColFiles) Then
        For $oObjectFile In $oColFiles
            Return StringRegExpReplace($oObjectFile.InstallDate, "\A(\d{4})(\d{2})(\d{2})(\d{2})(\d{2})(\d{2})(?:.*)", "$1")
        Next
    EndIf
    Return SetError(1, 0, 0)
EndFunc   ;==>_InstallDate

 

Edited April 28, 2021 by youtuber