Switching an array to add an item

[mike2003]

I have a set of items in a file. I read line by line. Depending on the content, the data goes into arrays. How can I switch arrays conveniently? Something more like a reference to a variable from C ++. For example.

Dim $a[0], $b[0]

$t = FileReadLine

if $t = aaaa then arr = $a

if $t = bbbb then arr = $b

_ArrayAdd(arr, $t)

Is something like this possible?

[Melba23]

mike2003,

i would do something like this:

Global $a[0], $b[0]

$hFile = FileOpen($sFile)

While 1 

    $t = FileReadLine($hFile)
    
    Switch $t
        Case -1 ; EOF
            ExitLoop
        Case "aaaa"
            _ArrayAdd($a, $t)
        Case "bbbb"
            _ArrayAdd($b, $t)
    EndSwitch

WEnd

FileClose($hFile)

M23

P.S. Click here to see how to post code.

Edited June 19, 2021 by Melba23
Typo

[jchd]

Yes but not pretty:

Local $a[0], $b[0], $arr

$t = FileReadLine

If $t = "aaaa" Then $arr = "a"
If $t = "bbbb" Then $arr = "b"

_ArrayAdd(Eval($arr), $t)

 

[mike2003]

1 hour ago, jchd said:

_ArrayAdd(Eval($arr), $t)

This is very similar to what I need. But it doesn't work.

error: _ArrayAdd() called with Const or expression on ByRef-param(s).

Quote

Eval Return the value of the variable defined by a string.

Not a pointer to an array address.

Edited June 19, 2021 by mike2003

[mike2003]

1 hour ago, Melba23 said:

do something like this

Not in my case. I have a more complex data structure.

Marker1
data11111
data2222
data333

Marker2
new data11111
new data2222
new data333
new data44

Marker3
...

[Subz]

You would need to use something like StringInStr for example:

#include <Array.au3>
Global $a[0], $b[0]
Global $sFile = @ScriptDir & "\Example.txt"
Global $hFile = FileOpen($sFile)
While 1
    $t = FileReadLine($hFile)
        If @error Then ExitLoop
    If StringInStr($t, "data1") Then
        _ArrayAdd($a, $t)
    ElseIf StringInStr($t, "data2") Then
        _ArrayAdd($b, $t)
    EndIf
WEnd
FileClose($hFile)
_ArrayDisplay($a)
_ArrayDisplay($b)

 

[mike2003]

18 minutes ago, Subz said:

StringInStr

But my data does not contain labels ('data1' & ' data2'), only "Marker" in the header. And that means all this will be lost. I just need to switch the target array.

Edited June 19, 2021 by mike2003

[Subz]

Your posts are little confusing, in your original post you mentioned, aaaaa or bbbbb (which Melba23 referenced) you then said it wouldn't work because the data structure was different (which I was referencing).  You need to clarify what you're after or modify the examples we posted to fit your needs.

[JockoDundee]

#include <Array.au3>


Global $garr[2], $arr, $s[0], $t

$garr[0]=$s
$garr[1]=$s

$t=FileReadLine("file.txt")

If $t="aaaa" Then $arr=0
If $t="bbbb" Then $arr=1

_ArrayAdd($garr[$arr], $t)

_ArrayDisplay($garr[$arr])

 

[JockoDundee]

Modification, if you like your $a and $b stuff:

#include <Array.au3>

Global $garr[2], $arr, $s[0], $t
Enum $a, $b

$garr[$a]=$s
$garr[$b]=$s

$t=FileReadLine("file.txt")

If $t="aaaa" Then $arr=$a
If $t="bbbb" Then $arr=$b

_ArrayAdd($garr[$arr], $t)

 

[jchd]

3 hours ago, mike2003 said:

This is very similar to what I need. But it doesn't work.

error: _ArrayAdd() called with Const or expression on ByRef-param(s).

You're very right. I made the mistake to post quickly, seconds before leaving my home, and didn't engage brain when typing.

Edited June 19, 2021 by jchd

[mikell]

A more convenient (and efficient) way could be to use StringRegExp to directly build the arrays instead of populate them progressively
Concept :

$txt = FileRead

; define requirements and build the patterns
$pattern_a = ...
$pattern_b = ...

; then use regex with flag $STR_REGEXPARRAYGLOBALMATCH
; to return the 2 arrays
$a = StringRegExp($txt, $pattern_a, 3)
$b = StringRegExp($txt, $pattern_b, 3)

 

[mike2003]

Sorry, but either it doesn't work or I don't understand. Here is some primitive long code that I want to reduce and optimize. It has more lines and is very awkward.

$sFileRead = FileReadLine($hFileOpen)
ElseIf ($sFileRead = "mark1") Then
    $ArrMode = 1
ElseIf ($sFileRead = "mark2") Then
    $ArrMode = 2
ElseIf ($sFileRead = "mark3) Then
    $ArrMode = 3
EndIf

Switch $ArrMode
    Case 1
        _ArrayAdd($Arr1, $sFileRead)
    Case 2
        _ArrayAdd($Arr2, $sFileRead)
    Case 3
        _ArrayAdd($Arr3, $sFileRead)
EndSwitch

 

Edited June 20, 2021 by mike2003

[Subz]

Maybe something like:

#include <Array.au3>
Global $Arr1[0], $Arr2[0], $Arr3[0]
Global $sFile = @ScriptDir & "\Example.txt"
Global $hFileOpen = FileOpen($sFile)
While 1
    $sFileRead = FileReadLine($hFileOpen)
        If @error Then ExitLoop
    If (StringStripWS($sFileRead,8) = "mark1") Then
        $ArrMode = 1
    ElseIf (StringStripWS($sFileRead,8) = "mark2") Then
        $ArrMode = 2
    ElseIf (StringStripWS($sFileRead,8) = "mark3") Then
        $ArrMode = 3
    ElseIf (StringStripWS($sFileRead,8) = "") Then
        ContinueLoop
    EndIf
    Switch $ArrMode
        Case 1
            _ArrayAdd($Arr1, $sFileRead)
        Case 2
            _ArrayAdd($Arr2, $sFileRead)
        Case 3
            _ArrayAdd($Arr3, $sFileRead)
    EndSwitch
WEnd
_ArrayDisplay($Arr1)
_ArrayDisplay($Arr2)
_ArrayDisplay($Arr3)

 

[mikell]

@Subz  
The requirements are confusing. For the fun...

#include <Array.au3>

$sFile = FileRead(@ScriptDir & "\Example.txt")
$a1 = _getArray("Marker1")
$a2 = _getArray("Marker2")
$a3 = _getArray("Marker3")
_ArrayDisplay($a1)
_ArrayDisplay($a2)
_ArrayDisplay($a3)

Func _getArray($header)
    ; including the header
    Local $s = StringRegExpReplace($sFile, '(?ms).*?(' & $header & '.*?)(?=\R{2}|\z).*', "$1")
    ; excluding the header
    ;Local $s = StringRegExpReplace($sFile, '(?ms).*?' & $header & '\R(.*?)(?=\R{2}|\z).*', "$1")
    Return StringRegExp($s, '\N+', 3)
EndFunc

 

[JockoDundee]

2 hours ago, mike2003 said:

It has more lines and is very awkward.

My solution has no Switch and no multiple ArrayAdds.

It only has conditionals to evaluate the marker, which I believe are necessary.

What more were you looking to abstract?