Auto scroll watchlist in Amibroker - (Moved)

[LearningEW]

Hi,

I want AutoIt to scroll through the specified watchlist having stock names in it continuously in technical analysis software Amibroker.    

A utility to auto scroll the charts in the watchlist of Amibroker say every 10-15sec (stopping at each chart for 2sec) so that no need to manually go through each chart. Have no idea about coding so request your help make this utility.

 

[Melba23]

Moved to the appropriate forum.

Moderation Team

[LearningEW]

Pls help here.

[Luke94]

I'm not familiar with AmiBroker but I'll try and point you in the right direction.

Are you trying to cycle through those tabs marked in red?

[LearningEW]

Im trying to auto scroll even in background through the stocks highlighted in blue. This watchlist may have say 100 or 2000 stocks.

 

[Luke94]

If you're not familiar with it - check out the AutoIt Window Information Tool.

Post back the Control Information for all of the controls you can find in the area you've highlighted.

Edit: Just post screenshots of the AutoIt Window Information Tool (Control tab) for each control.

Edited June 29, 2021 by Luke94

[LearningEW]

Auto.docx

 

Have attached 2 screenshots. Hope this is OK.

 

[Luke94]

Did you use the Finder Tool on the actual list? I would assume it's a ListView. (SysListView32)

Those screenshots are of the column headers.

Use the Finder Tool on some text within the list - Try the scrollbars as well.

You can paste the screenshot directly into your reply, rather than uploading as a document.

[LearningEW]

[LearningEW]

 

On scroll bar

 

 

 

 

 

on next stock  in watchlist

 

[Luke94]

I'm not able to test this but give it a try:

#include <GuiListView.au3>

Global $g_hWnd
Global $g_hListView
Global $g_iCount
Global $g_iIndex

$g_hWnd = WinGetHandle('AmiBroker') ; Get AmiBroker window handle
If IsHWnd($g_hWnd) = 1 Then ; Check the window handle is valid
    If WinActive($g_hWnd) = 0 Then ; Check if AmiBroker is NOT active
        WinActivate($g_hWnd) ; If it's NOT active, activate it
        WinWaitActive($g_hWnd, '', 5) ; Wait for the handle to become active
    EndIf
    While 1 ; Loop forever
        $g_hListView = ControlGetHandle($g_hWnd, '', '[CLASS:SysListView32; INSTANCE:5]') ; Get the ListView handle
        $g_iCount = (_GUICtrlListView_GetItemCount($g_hListView) - 1) ; Get the number of items in the ListView
        $g_iIndex = 0
        Do
            _GUICtrlListView_EnsureVisible($g_hListView, $g_iIndex) ; Scrolls the ListView to the given index - which we're increasing by one below
            $g_iIndex += 1
            Sleep(2000) ; Wait 2000ms (2 seconds)
        Until $g_iIndex > $g_iCount ; Loop until we've reached the end of the ListView
        _GUICtrlListView_EnsureVisible($g_hListView, 0) ; Once we've reached the end of the ListView above, move back to the top of the ListView
        Sleep(15000) ; Wait 15000ms (15 seconds) - once we've waited, the While loop will restart
    WEnd
EndIf

I assume the two screenshots you've sent are different ListViews on different tabs? In that case, the above will only work (if it does) on the currently selected tab. If it does work, we can look into changing the tab periodically. Any errors, post them back. ☺️

[LearningEW]

Thanks. I can see the scroll bar moving, but its not selecting(next stock/chart) and scrolling the stocks. 

Edited June 29, 2021 by LearningEW

[Luke94]

How do you select next stock/chart? Do you click the item in the ListView?

[LearningEW]

yes.....they have to be clicked. 

[Luke94]

Try this - it should double click each item.

#include <GuiListView.au3>

Global $g_hWnd
Global $g_hListView
Global $g_iCount
Global $g_iIndex

$g_hWnd = WinGetHandle('AmiBroker') ; Get AmiBroker window handle
If IsHWnd($g_hWnd) = 1 Then ; Check the window handle is valid
    If WinActive($g_hWnd) = 0 Then ; Check if AmiBroker is NOT active
        WinActivate($g_hWnd) ; If it's NOT active, activate it
        WinWaitActive($g_hWnd, '', 5) ; Wait for the handle to become active
    EndIf
    While 1 ; Loop forever
        $g_hListView = ControlGetHandle($g_hWnd, '', '[CLASS:SysListView32; INSTANCE:5]') ; Get the ListView handle
        $g_iCount = (_GUICtrlListView_GetItemCount($g_hListView) - 1) ; Get the number of items in the ListView
        $g_iIndex = 0
        Do
            _GUICtrlListView_EnsureVisible($g_hListView, $g_iIndex) ; Scrolls the ListView to the given index - which we're increasing by one below
            _GUICtrlListView_ClickItem($g_hListView, $g_iIndex, 'Left', False, 2, 0) ; Double click the ListView Item
            $g_iIndex += 1
            Sleep(2000) ; Wait 2000ms (2 seconds)
        Until $g_iIndex > $g_iCount ; Loop until we've reached the end of the ListView
        _GUICtrlListView_EnsureVisible($g_hListView, 0) ; Once we've reached the end of the ListView above, move back to the top of the ListView
        Sleep(15000) ; Wait 15000ms (15 seconds) - once we've waited, the While loop will restart
    WEnd
EndIf

 

[LearningEW]

Thanks. Its working fine when Amibroker is in front but when i open another window say chrome and Amibroker is in background then it scrolls but doesn't click the stock.  

Is it possible to click/select the charts/stock even when Amibroker is in background.

 

[Luke94]

7 minutes ago, LearningEW said:

Thanks. Its working fine when Amibroker is in front but when i open another window say chrome and Amibroker is in background then it scrolls but doesn't click the stock.  

Is it possible to click/select the charts/stock even when Amibroker is in background.

 

Not that I'm aware of. Someone else may be able to help with that though.

[LearningEW]

Many thanks Luke. 

Will use this and give feedback tomorrow. Thanks again.

 

[LearningEW]

Luke,

One query....this script is using mouse click function to select the stock. Can this also be done by using arrow key function, as next stock can be selected by arrow keys also. Asking as this might then work in background.

 

 

[Luke94]

#include <GuiListView.au3>

Global $g_hWnd
Global $g_hListView
Global $g_iCount
Global $g_iIndex

$g_hWnd = WinGetHandle('AmiBroker') ; Get AmiBroker window handle
If IsHWnd($g_hWnd) = 1 Then ; Check the window handle is valid
    If WinActive($g_hWnd) = 0 Then ; Check if AmiBroker is NOT active
        WinActivate($g_hWnd) ; If it's NOT active, activate it
        WinWaitActive($g_hWnd, '', 5) ; Wait for the handle to become active
    EndIf
    While 1 ; Loop forever
        $g_hListView = ControlGetHandle($g_hWnd, '', '[CLASS:SysListView32; INSTANCE:5]') ; Get the ListView handle
        $g_iCount = (_GUICtrlListView_GetItemCount($g_hListView) - 1) ; Get the number of items in the ListView
        $g_iIndex = 0
        Do
            _GUICtrlListView_EnsureVisible($g_hListView, $g_iIndex) ; Scrolls the ListView to the given index - which we're increasing by one below
            ; _GUICtrlListView_ClickItem($g_hListView, $g_iIndex, 'Left', False, 2, 0) ; Double click the ListView Item
            _GUICtrlListView_SetItemSelected($g_hListView, $g_iIndex)
            $g_iIndex += 1
            Sleep(2000) ; Wait 2000ms (2 seconds)
        Until $g_iIndex > $g_iCount ; Loop until we've reached the end of the ListView
        _GUICtrlListView_EnsureVisible($g_hListView, 0) ; Once we've reached the end of the ListView above, move back to the top of the ListView
        Sleep(15000) ; Wait 15000ms (15 seconds) - once we've waited, the While loop will restart
    WEnd
EndIf

See if this works in the background first.