How to check, that a string contains capital letters or a number or a special letter?

[DannyJ]

I am writing a program that checks, that a string is okay for a password.

I need to chechk that the string contains at least a number a capital letter and a special charachter?

Here is my example code:

$Input = InputBox(64,"Type password","")
If GUICtrlRead($Input) == "" Or $Input .... CHECK Then
    MsgBox(0,"password","password not okay")
Else
    MsgBox(0,"okay","password okay")
EndIf

 

[Nine]

Maybe this ?

$Input = InputBox("Title","Type password","")
If @error Then Exit
If StringRegExp($Input, "[A-Z]") And StringRegExp($Input, "[0-9]") And StringRegExp($Input,"[!/$%?&*+=]") Then
    MsgBox(0,"password","password is OK")
Else
    MsgBox(0,"okay","password not okay")
EndIf

Or even this better :

$Input = InputBox("Title","Type password","")
If @error Then Exit
If StringRegExp($Input, "(?=.*[A-Z])(?=.*[0-9])(?=.*[!/$%?&*+=])") Then
    MsgBox(0,"password","password is OK")
Else
    MsgBox(0,"okay","password not okay")
EndIf

 

Edited June 29, 2021 by Nine

[DannyJ]

Thank you very much @Nine

[JockoDundee]

8 hours ago, DannyJ said:

I need to chechk that the string contains at least a number a capital letter and a special charachter?

So a password could contain just UPPERCASE letters, a number and a special char?

[spudw2k]

Per the requirements listed, yes.  As a good security practice, a minimum length is also advised; for example, 8 characters.

*built from @Nine's example

$Input = InputBox("Title","Type password","")
If @error Then Exit
If StringRegExp($Input, "(?=^.{8,}$)(?=.*[A-Z])(?=.*[0-9])(?=.*[[:punct:]])") Then
    MsgBox(0,"password","password is OK")
Else
    MsgBox(0,"okay","password not okay")
EndIf

 

[jchd]

FYI you can also use the Unicode Character Properties supported by the regex engine. See help.

[JockoDundee]

4 hours ago, spudw2k said:

Per the requirements listed, yes.

Interesting.  

Yet an ALL-CAPS password can be guessed by brute force just as quickly as an all-lower case password.

And since I doubt that the omission of the requirement of mixed case is at the request of the user community, perhaps it’s just an oversight…

 

[spudw2k]

I agree, password complexity (strong passwords) can (and should) be adequate to thwart brute-forcing as much as reasonable.