StringRegEx Extract five-digit number

[Felicitas]

Hello again,

i´m a little bit in trouble trying to extract the five-digit number from a string

i have an array like this:

 

array                                                     arraynew

row1   112 56985 1 589 6                 56985

row2   15896 25 25 3636                  15896

row3   6 6 8956 56895 4                   56895

....

Does someone have an good idea?

 

Thank you for your help.

 

 

[Melba23]

Felicitas:

Try this:

#include <Array.au3>

Global $aArray[] = ["112 56985 1 589 6", "15896 25 25 3636", "6 6 8956 56895 4"]

Global $aNewArray[UBound($aArray)]

For $i = 0 To UBound($aArray) - 1
    ; Get array of all 5 digit numbers in element
    $aRet = StringRegExp($aArray[$i], "\d{5}", 3)
    ; Add returned string to the new array
    $aNewArray[$i] = $aRet[0]
Next

_ArrayDisplay($aNewArray, "", Default, 8)

I leave error-checking to you - and no doubt a real guru will be along soon to do the whole thing in one line!

M23

[mikell]

5 hours ago, Melba23 said:

do the whole thing in one line

No way to do a one-liner using StringRegExp directly on an array 
The only one I can think of is this

#include <Array.au3>

Global $aArray[] = ["112 56985 1 589 6", "15896 25 25 3636", "6 6 8956 56895 4"]

Global $aNewArray = StringRegExp(_ArrayToString($aArray), "\d{5}", 3)
_ArrayDisplay($aNewArray, "", Default, 8)

 

[Felicitas]

thank you so much, it works perfectly...

is there an option to get an array with the empty rows?

for example:

row1   112 56985 1 589 6                 56985

row2   15 4 123 23 623 8                  "Null"                           

row3   6 6 8956 56895 41                 56895

row4                                                    "Null"

row5 15557 15 1 1 1556                  15557

 

thank you for your help :)

 

[Melba23]

Felicitas,

Quote

is there an option to get an array with the empty rows?

Of course:

#include <Array.au3>

Global $aArray[] = ["12 56985 1 589 6", "15 4 123 23 623 8", "6 6 8956 56895 41", "", "15557 15 1 1 1556"]

Global $aNewArray[UBound($aArray)]

For $i = 0 To UBound($aArray) - 1
    ; Get array of all 5 digit numbers in element
    $aRet = StringRegExp($aArray[$i], "\d{5}", 3)
    If Not @error Then
        ; Add returned string to the new array
        $aNewArray[$i] = $aRet[0]
    Else
        ; Or place "Null"
        $aNewArray[$i] = "Null"
    EndIf
Next

_ArrayDisplay($aNewArray, "", Default, 8)

M23

[mikell]

For the fun challenge

#include <Array.au3>

Global $aArray[] = ["12 56985 1 589 6", "15 4 123 23 623 8", "6 6 8956 56895 41", "", "15557 15 1 1 1556"]

$aNewArray = StringSplit(StringRegExpReplace(_ArrayToString($aArray), "\b(\h+|\d{1,4})\b", ""), "|", 3)
_ArrayDisplay($aNewArray, "", Default, 8)

 

[markyrocks]

for funzies... Idk why the non capturing group wasn't working. then i looked at the documentation to see it was actually in there then came back and it was working.... weird like im being spied on....

#include <Array.au3>

Global $aArray[] = ["112 56985 1 589 6", "15896 25 25 3636","", "6 6 8956 56895 4"]

for $i in $aArray
$ticket = StringRegExp($i, "^(?:.*\W*)(\d{5})(?:.*)$|(^$)", 1)
if IsArray($ticket) Then _ArrayDisplay($ticket)
Next

 

[Felicitas]

Thank you so much. I will try the solutions asap. I love this forum. Very kind helpers everywhere 😘