_ArraySearch "bug" ? - (Moved)

[TommyDDR]

Hi,

It's not possible to search only in the first entry of an array with _ArraySearch.

Indeed :

; Bounds checking
    If $bRow Then
        If UBound($aArray, $UBOUND_DIMENSIONS) = 1 Then Return SetError(5, 0, -1)
        If $iEnd < 1 Or $iEnd > $iDim_2 Then $iEnd = $iDim_2
        If $iStart < 0 Then $iStart = 0
        If $iStart > $iEnd Then Return SetError(4, 0, -1)
    Else
        If $iEnd < 1 Or $iEnd > $iDim_1 Then $iEnd = $iDim_1
        If $iStart < 0 Then $iStart = 0
        If $iStart > $iEnd Then Return SetError(4, 0, -1)
    EndIf

If $iEnd = 0, then _ArraySearch process the entire array.

 

I think the default value should be -1 and not 0 fot $iEnd

[Jos]

Moved to the appropriate forum.

Moderation Team

[jchd]

I'm afraid it's too late to fix due to the number of real-world scripts already relying on this convention, admitedly weird.

OTOH, "searching" a given single row in an array amounts to directly comparing "searched" column(s) of row index N with search value(s). That's true whatever the searched row index is, 0 or not. So this point is rather moot.

[TommyDDR]

Here is an exemple where the problem can happen :

#include <Array.au3>

Global $topPoints = [["Jos", 1000], ["jchd", 900], ["TommyDDR", 800]]
Global $playerToFind = "TommyDDR"

For $i = 3 To 1 Step -1
    Local $top = isTopPoints($playerToFind, $i-1) ? " is in TOP " : " is not in TOP "
    ConsoleWrite($playerToFind & $top & $i & @CRLF)
Next

Func isTopPoints($player, $nbMax)
    Return _ArraySearch($topPoints, $player, 0, $nbMax) >= 0
EndFunc

Result will be :

TommyDDR is in TOP 3
TommyDDR is not in TOP 2
TommyDDR is in TOP 1

Instead of :

TommyDDR is in TOP 3
TommyDDR is not in TOP 2
TommyDDR is not in TOP 1

Does it really break many script ?

I think many of us don't send any parameter when all array have to be processed, si if it's changed internally to -1, we can't see the difference.

But i know that changing such a basic function after a long period of use can be touchy.

[Luke94]

I guess how it is now is correct? You would never search a singular item because you wouldn't need to search it.

You wouldn't search among the rock. You'd just check to see if the rock was what you was looking for?

#include <Array.au3>

Global $topPoints = [["Jos", 1000], ["jchd", 900], ["TommyDDR", 800]]
Global $playerToFind = "TommyDDR"

For $i = 3 To 1 Step -1
    Local $top = isTopPoints($playerToFind, $i-1) ? " is in TOP " : " is not in TOP "
    ConsoleWrite($playerToFind & $top & $i & @CRLF)
Next

Func isTopPoints($player, $nbMax)
    If $nbMax = 0 Then
        Return ($topPoints[0][0] = $player)
    Else
        Return _ArraySearch($topPoints, $player, 0, $nbMax) >= 0
    EndIf
EndFunc

 

[jchd]

1 hour ago, TommyDDR said:

Does it really break many script ?

I think many of us don't send any parameter when all array have to be processed, si if it's changed internally to -1, we can't see the difference.

Yes, actually many scripts IMVHO: just because there are useful parameters passed after $iEnd, like case sensivity, comparison method (text vs. numeric), subitems (2D arrays) and the like. Without a way to omit intermediate parameters like in _ArraySearch($a, $sSearch, 5, , , 3) I see the issue as difficult to solve.

The only proper way to solve the problem would be to propose _ArraySearchEx() with smarter defaults.

Edited December 15, 2021 by jchd

[ad777]

this better code if you want to use it:

#include <Array.au3>

Global $topPoints = [["Jos", 1000], ["jchd", 900], ["TommyDDR", 800]]
Global $playerToFind = "TommyDDR"
For $i = 0 To UBound($topPoints)-1 Step 1
    if $topPoints[$i][0] = $playerToFind  Then
       ConsoleWrite($playerToFind & " is in TOP " &$i &@CRLF)
    Else
          ConsoleWrite($playerToFind & " is not in TOP " &$i&@CRLF)
       EndIf
Next