Simple mouse down and up script

[MarkLeung]

Hello. I'm trying to write a script that changes F1 to left click down, and then release when F1 is pressed again. This is what I have, and it doesn't work.

Dim $MouseDown

Func LMouseDown()
   $MouseDown = 0
If $MouseDown = 0 Then
   MouseDown("left")
   $MouseDown = 1
Else
   MouseUp("left")
   $MouseDown = 0
   EndIf
EndFunc

Any help is appreciated!

[ad777]

#include <Misc.au3>
Dim $MouseDown
Local $hDLL = DllOpen("user32.dll")
While 1
   LMouseDown()
   Sleep(100)
   WEnd
Func LMouseDown()
if _IsPressed("70",$hDLL) Then;;;if F1 key press
  if  $MouseDown = 1 Then
   MouseUp("left")
   $MouseDown = 0
     EndIf
   Sleep(100);;Sleep 100 for break it
EndIf
if _IsPressed("70",$hDLL) Then
     if  $MouseDown = 0 Then
  MouseDown("left")
   $MouseDown = 1
     EndIf
   Sleep(100);;Sleep 100 for  break it
EndIf
EndFunc

 

Edited January 1, 2022 by ad777

[Jos]

@ad777, You forgot again to Tidy your code  

... but more importantly, this is not a very efficient script opening the DLL constantly...  so not a script I would recommend to use as is.  

[ad777]

Jos oh i did fix the code 

Edited January 1, 2022 by ad777

[Jos]

That code is still messy,...  so why aren't you simply using Tidy.exe from SciTE (Ctrl+T) when you have the full version installed? 

Secondly:  I think the script is still flawed in several ways...  

1. The script will be constantly sending Mouse UP&DOWNs when you keep the F1 pressed.... is that wanted?
2. The F1 is still send as normal F1 to the system as well ....  is that what is wanted?

This is how I would do it when 2 is still desired:

#include <Misc.au3>
Global $MouseDown = False
Global $hDLL = DllOpen("user32.dll")
While 1
    LMouseDown()
    Sleep(10)
WEnd
Func LMouseDown()
    ; F1 key press
    If _IsPressed("70", $hDLL) Then
        MouseDown("left")
        ConsoleWrite("+ Mouse down." & @CRLF)
        While _IsPressed("70", $hDLL)
            sleep(10)
        WEnd
        MouseUp("left")
        ConsoleWrite("+ Mouse Up." & @CRLF)
    EndIf
EndFunc   ;==>LMouseDown

@MarkLeung, Why do you want to change the behavior of the F1 like this anyways? 

 

 

Edited January 1, 2022 by Jos

[MarkLeung]

15 hours ago, Jos said:

That code is still messy,...  so why aren't you simply using Tidy.exe from SciTE (Ctrl+T) when you have the full version installed? 

Secondly:  I think the script is still flawed in several ways...  

1. The script will be constantly sending Mouse UP&DOWNs when you keep the F1 pressed.... is that wanted?
2. The F1 is still send as normal F1 to the system as well ....  is that what is wanted?

This is how I would do it when 2 is still desired:

#include <Misc.au3>
Global $MouseDown = False
Global $hDLL = DllOpen("user32.dll")
While 1
    LMouseDown()
    Sleep(10)
WEnd
Func LMouseDown()
    ; F1 key press
    If _IsPressed("70", $hDLL) Then
        MouseDown("left")
        ConsoleWrite("+ Mouse down." & @CRLF)
        While _IsPressed("70", $hDLL)
            sleep(10)
        WEnd
        MouseUp("left")
        ConsoleWrite("+ Mouse Up." & @CRLF)
    EndIf
EndFunc   ;==>LMouseDown

@MarkLeung, Why do you want to change the behavior of the F1 like this anyways? 

 

 

Because I've recently become disabled and can't click very well with the mouse. I need a way to perform drag and drop accurately because my work demands it.

I want to replace F1 entirely as I rarely use it. Regarding the dlls, can you guarantee that I have them?

Thanks so much.

[Jos]

12 minutes ago, MarkLeung said:

Regarding the dlls, can you guarantee that I have them?

Did you try?  

[MarkLeung]

8 minutes ago, Jos said:

Did you try?  

Hehe, just did.

If I press F1 again it doesn't mouseup. Instead it resets the cycle.

[Jos]

Run the Script from SciTE and tell me what you see in the OutputPane when you do this....  (but as stated before ....the F1 will be performed as well.)

EDIT: You could also check out the Helpfile for HotkeySet() and look at the example as that is pretty close to what you want too!
 

Edited January 2, 2022 by Jos

[Nine]

If I was a teacher (like good old time), I would give a 10% to @ad777 in his homework for not understanding the basic principle of indentation.  But gladly I am not, and I am pretty sure he would still not understand the principle.

[junkew]

Windows has this dragging with keys build in with mousekeys. Maybe that helps also

https://www.computerhope.com/issues/ch000542.htm

https://support.microsoft.com/en-us/windows/use-mouse-keys-to-move-the-mouse-pointer-9e0c72c8-b882-7918-8e7b-391fd62adf33

 

[Deye]

* Click to select the start of the drag and a second click to finish it. 
* Double click to select and highlight a word .etc

  Here's a way to start you off:

expandcollapse popup

#include <Misc.au3>
Global $hDLL = DllOpen("user32.dll")

HotKeySet("{F1} ", "HotKeyPressed")
HotKeySet("{ESC}", "Close") ; Set ESC as a hotkey to exit the script.

While 1
    Sleep(100)
WEnd

Func __dragStartStop()
    While _IsPressed("70", $hDLL)
        Sleep(10)
    WEnd
    If _IsPressed("01", $hDLL) Then
        MouseUp("left")
    Else
        MouseDown("left")
    EndIf
EndFunc   ;==>__IsPressed

Func HotKeyPressed()
    Local Static $hTimer = "881808965525"
    Local $fDiff = TimerDiff($hTimer)
    If Int($fDiff) > 200 Then
        __dragStartStop()
        $hTimer = TimerInit()
        Return
    EndIf
    ;double click determined
    $hTimer = TimerInit()
    MouseClick("left", Default, Default, 1)
EndFunc   ;==>HotKeyPressed

Func Close()
    MouseUp("left")
    Exit
EndFunc   ;==>Close

 

Edited January 4, 2022 by Deye

[Deye]

No edit button for me ?   

edit : ok got  it .. a little rusty ..

Edited January 4, 2022 by Deye

[Luke94]

Global $g_bMouseDown = False

HotKeySet('{ESC}', '_Exit')
HotKeySet('{F1}', '_ToggleMouseDown')

While 1
    If $g_bMouseDown Then
        MouseDown('Left')
        While $g_bMouseDown
            Sleep(10)
        WEnd
        MouseUp('Left')
    EndIf
    Sleep(10)
WEnd

Func _Exit()
    Exit
EndFunc

Func _ToggleMouseDown()
    $g_bMouseDown = Not $g_bMouseDown
EndFunc