Catch function keys only when script has focus, otherwise do not handle ?

[Myicq]

I have a small script that works using function keys (not related to gaming or keylogging).  I set the keys using something like

Opt ('GUIoneventmode', 1)
HotKeySet("{F4}", "_functionF4")

This is all good. But at times I wish to have my script open, and use other software on same machine. These other software may use function keys as well.

Problem is that AutoIT has "captured" the function key, and thereby, the function key won't do anything in the other program.

 

My question is: what is best approach to "not handle" the hotkeys when autoIT script is not focused ? And pass on keypress to the other software ?

I could of course add a timer/ event to check for focus and set /unset hotkeys, but I think there should be a simpler way ?

 

[Melba23]

Myicq,

Look at GUISetAccelerators in the Help file - that could well be what you are looking for.

M23

[Nine]

There is multiple ways to skin this particular cat (proverbial expression on AutoIt forum ).  Here one of them - clean - simple :

#include <GUIConstants.au3>

Example()

Func Example()
    GUICreate("Test", 225, 80)

    Local $idF4 = GUICtrlCreateDummy()
    Local $idF5 = GUICtrlCreateDummy()
    Local $idExit = GUICtrlCreateButton("Exit", 150, 50, 65, 25)

    Local $aAccelKeys[2][2] = [["{F4}", $idF4], ["{F5}", $idF5]]
    GUISetAccelerators($aAccelKeys)

    GUISetState(@SW_SHOW) ; Display the GUI.

    While 1
        Switch GUIGetMsg()
            Case $GUI_EVENT_CLOSE, $idExit
                ExitLoop
            Case $idF4
                ConsoleWrite("F4 was pressed" & @CRLF)
            Case $idF5
                ConsoleWrite("F5 was pressed" & @CRLF)
        EndSwitch
    WEnd
EndFunc   ;==>Example