How to know which EDIT GUICTRL is active?

[September]

I have two tabs, which are TAB_1 and TAB_2, there are two EDIT controls, one in TAB_1, another in TAB_2, respectively.

My question is, how to know which EDIT control is active?---I mean, to know which one is in front?

I tried GUICtrlGetState, but two EDIT controls return 80, I also tried GUICtrlRead($tab), but nothing return.

[Luke94]

You could use ControlCommand to check if the Edit is visible?

If ControlCommand($hGUI, '', ControlGetHandle($hGUI, '', $Edit_1), 'IsVisible') = 1 Then
    ConsoleWrite('Edit_1 is visible' & @CRLF)
ElseIf ControlCommand($hGUI, '', ControlGetHandle($hGUI, '', $Edit_2), 'IsVisible') = 1 Then
    ConsoleWrite('Edit_2 is visible' & @CRLF)
EndIf

If you're wanting to know which tab is selected, you could use _GUICtrlTab_GetCurSel.

#include <GuiTab.au3>

Local $iCurSel = _GUICtrlTab_GetCurSel($Tab_1)

 

[OJBakker]

Try with 

ControlGetFocus

 

[September]

29 minutes ago, Luke94 said:

You could use ControlCommand to check if the Edit is visible?

If ControlCommand($hGUI, '', ControlGetHandle($hGUI, '', $Edit_1), 'IsVisible') = 1 Then
    ConsoleWrite('Edit_1 is visible' & @CRLF)
ElseIf ControlCommand($hGUI, '', ControlGetHandle($hGUI, '', $Edit_2), 'IsVisible') = 1 Then
    ConsoleWrite('Edit_2 is visible' & @CRLF)
EndIf

If you're wanting to know which tab is selected, you could use _GUICtrlTab_GetCurSel.

#include <GuiTab.au3>

Local $iCurSel = _GUICtrlTab_GetCurSel($Tab_1)

 

Great, that's what I need, thanks.

[Nine]

5 hours ago, September said:

I also tried GUICtrlRead($tab), but nothing return.

I highly doubt that.  See example :

#include <GUIConstantsEx.au3>

Example()

Func Example()
    GUICreate("Test")
    Local $tab = GUICtrlCreateTab(10, 10, 400, 400)

    GUICtrlCreateTabItem("tab0")
    GUICtrlCreateEdit("ed1", 20, 40, 250, 250)

    GUICtrlCreateTabItem("tab1")
    GUICtrlCreateEdit("ed2", 20, 40, 250, 250)

    GUICtrlCreateTabItem("")
    GUISetState()

    While 1
        If GUIGetMsg() = $GUI_EVENT_CLOSE Then ExitLoop
        ConsoleWrite(GUICtrlRead($tab) & @CRLF)
    WEnd
EndFunc   ;==>Example