Jump to content

Game Bot - Builder


Valuater
 Share

Recommended Posts

Ver 1.0.3 August 12, 2008

Works Great...

Posted Image

heres an ini i built with it..

(pace it in scriptDir\Games\CurveBall.ini

CureveBall.ini

[Colors]
   1=0xDFFFD7
   2=0xE5FFE0
   3=0xE0FFD8
   4=0xE4FFDE
   5=0xEBFFE7
   6=0xEFFFEC
   7=0xD4FFCA
   8=0xABFF96
   9=0xC6FFB8
   10=0xF2FFEF
   [Settings]
   Run=1
   Launcher=http://www.albinoblacksheep.com/flash/curveball.php
   Left=312
   Top=331
   Right=708
   Bottom=593
   Vary=50
   Wait=1
   Skip=10
   CWait=0

and the GameBot - Builder

#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#include <File.au3>

Dim $ver = "1.0.3"
Dim $pos = "", $CHex = "", $Cpos = "", $Count = 0, $data[11], $Label_[11], $Run, $Launcher, $cwait = 0
Dim $pause, $left = 0, $right = @DesktopWidth, $top = 0, $bottom = @DesktopHeight, $wait = 1000, $Vary = 5, $Skip = 5
Dim $Gloc = @ScriptDir & "\Games\", $Ginfo

Opt("PixelCoordMode", 0)    ;1=absolute, 0=relative, 2=client
Opt("MouseCoordMode", 0)    ;1=absolute, 0=relative, 2=client

HotKeySet("{ESC}", "Terminate")

$Gamebot = GUICreate("GameBot - Builder      by, QTasc     v" & $ver, 392, 402, -1, -1, -1, $WS_EX_ACCEPTFILES)
$Group_1 = GUICtrlCreateGroup("Game Select", 10, 10, 370, 60)
$Combo_2 = GUICtrlCreateCombo("New Game", 20, 34, 110, 21)
$Button_3 = GUICtrlCreateButton("Select Game", 150, 30, 100, 30)
Set_Game_List()
$Button_4 = GUICtrlCreateButton("Delete Game", 270, 30, 100, 30)
$Group_5 = GUICtrlCreateGroup("Game Launch", 10, 80, 370, 80)
$Radio_6 = GUICtrlCreateRadio("Run URL", 30, 100, 80, 20)
$Radio_7 = GUICtrlCreateRadio("Run Game exe", 110, 100, 100, 20)
$Input_8 = GUICtrlCreateInput("Type or Drag & Drop  -  URL or Game exe/link", 20, 130, 340, 20, -1, $WS_EX_ACCEPTFILES)
GUICtrlSetState(-1, $GUI_DROPACCEPTED)
GUICtrlSetState(-1, $GUI_DISABLE)
$Radio_9 = GUICtrlCreateRadio("Dont Launch Anything", 230, 100, 130, 20)
GUICtrlSetState(-1, $GUI_CHECKED)
$Group_10 = GUICtrlCreateGroup("Pixel Search Area", 10, 170, 370, 100)
$Label_11 = GUICtrlCreateLabel("Left              Top              Right            Bottom        Varience      Skip", 20, 190, 350, 20)
$Input_12 = GUICtrlCreateInput($left, 20, 210, 40, 20)
$Input_13 = GUICtrlCreateInput($top, 80, 210, 40, 20)
$Input_14 = GUICtrlCreateInput($right, 140, 210, 40, 20)
$Label_16 = GUICtrlCreateLabel("Color Wait", 20, 243, 50, 20)
$Input_19 = GUICtrlCreateInput($cwait, 80, 240, 40, 20)
$Input_15 = GUICtrlCreateInput($bottom, 200, 210, 40, 20)
$Label_16 = GUICtrlCreateLabel("Search Wait", 135, 243, 60, 20)
$Input_17 = GUICtrlCreateInput($Vary, 260, 210, 40, 20)
$Input_18 = GUICtrlCreateInput($wait, 200, 240, 40, 20)
$Group_19 = GUICtrlCreateGroup("Colors to Search  -  10 Max", 10, 280, 370, 70)
$Input_20 = GUICtrlCreateInput($Skip, 320, 210, 40, 20)
$Label_[1] = GUICtrlCreateLabel("1", 20, 300, 50, 20)
$Label_[2] = GUICtrlCreateLabel("2", 70, 300, 50, 20)
$Label_[3] = GUICtrlCreateLabel("3", 120, 300, 50, 20)
$Label_[4] = GUICtrlCreateLabel("4", 170, 300, 50, 20)
$Label_[5] = GUICtrlCreateLabel("5", 220, 300, 50, 20)
$Label_[6] = GUICtrlCreateLabel("6", 20, 320, 50, 20)
$Label_[7] = GUICtrlCreateLabel("7", 70, 320, 50, 20)
$Label_[8] = GUICtrlCreateLabel("8", 120, 320, 50, 20)
$Label_[9] = GUICtrlCreateLabel("9", 170, 320, 50, 20)
$Label_[10] = GUICtrlCreateLabel("10", 220, 320, 50, 20)
$Button_29 = GUICtrlCreateButton("Get Area", 280, 240, 90, 25)
$Button_30 = GUICtrlCreateButton("Get Colors", 280, 290, 90, 25)
$Button_31 = GUICtrlCreateButton("Clear All", 280, 320, 90, 25)
$Button_32 = GUICtrlCreateButton("Save Game Info", 10, 360, 110, 30)
$Button_33 = GUICtrlCreateButton("Run GameBot", 140, 360, 110, 30)
$Button_34 = GUICtrlCreateButton("Exit GameBot", 270, 360, 110, 30)

GUISetState()
While 1
     $msg = GUIGetMsg()
     Select
         Case $msg = $GUI_EVENT_CLOSE Or $msg = $Button_34
             ExitLoop
         Case $msg = $Button_3
             $Ginfo = GUICtrlRead($Combo_2)
             If $Ginfo = "" Then
    ; nada
             ElseIf $Ginfo = "New Game" Then
                 Set_new_game()
             Else
                 Set_game()
             EndIf
         Case $msg = $Button_4
             $Ginfo = GUICtrlRead($Combo_2)
             If $Ginfo = "New Game" Or $Ginfo = "" Then
    ; nada
             Else
                 FileDelete($Gloc & $Ginfo & ".ini")
                 Set_Game_List()
             EndIf
         Case $msg = $Radio_6
             GUICtrlSetState($Radio_7, $GUI_UNCHECKED)
             GUICtrlSetState($Radio_9, $GUI_UNCHECKED)
             GUICtrlSetState($Input_8, $GUI_ENABLE)
             GUICtrlSetState($Radio_6, $GUI_CHECKED)
             GUICtrlSetState($Input_8, $GUI_DROPACCEPTED)
         Case $msg = $Radio_7
             GUICtrlSetState($Radio_6, $GUI_UNCHECKED)
             GUICtrlSetState($Radio_9, $GUI_UNCHECKED)
             GUICtrlSetState($Input_8, $GUI_ENABLE)
             GUICtrlSetState($Radio_7, $GUI_CHECKED)
             GUICtrlSetState($Input_8, $GUI_DROPACCEPTED)
         Case $msg = $Radio_9
             GUICtrlSetState($Radio_6, $GUI_UNCHECKED)
             GUICtrlSetState($Radio_7, $GUI_UNCHECKED)
             GUICtrlSetState($Input_8, $GUI_DISABLE)
             GUICtrlSetState($Radio_9, $GUI_CHECKED)
         Case $msg = $Button_29
             Get_Area()
         Case $msg = $Button_30
             Get_Colors()
         Case $msg = $Button_31
             Clear_Colors()
         Case $msg = $Button_32
             Save_Game()
         Case $msg = $Button_33
             Set_Run()
         Case Else
;;;
     EndSelect
WEnd
Exit

; --------------------- Functions -----------------------

Func Set_new_game()
     If FileExists($Gloc & $Ginfo & ".ini") Then
         MsgBox(262208, "Sorry!", "That File Already Exists!      " & @CRLF & $Gloc & $Ginfo & ".ini   ", 5)
         Return
     EndIf
     $NewG = InputBox("New GameBot", "Please type in a New Game Name ", "", "", 200, 120)
     If $NewG = "" Then Return
     DirCreate($Gloc)
     FileWrite($Gloc & $NewG & ".ini", "")
     GUICtrlSetState($Radio_9, $GUI_CHECKED)
     GUICtrlSetState($Radio_7, $GUI_UNCHECKED)
     GUICtrlSetState($Radio_6, $GUI_UNCHECKED)
     GUICtrlSetData($Input_8, "Type or Drag & Drop  -  URL or Game exe/link")
     GUICtrlSetState($Input_8, $GUI_DISABLE)
     GUICtrlSetData($Input_12, 1)
     GUICtrlSetData($Input_13, 1)
     GUICtrlSetData($Input_14, @DesktopWidth)
     GUICtrlSetData($Input_15, @DesktopHeight)
     GUICtrlSetData($Input_17, 5)
     GUICtrlSetData($Input_18, 1000)
     GUICtrlSetData($Input_19, 1000)
     GUICtrlSetData($Input_20, 5)
     Set_Game_List()
EndFunc;==>Set_new_game

Func Set_Game_List()
     $FileList = _FileListToArray ($Gloc)
     If (Not IsArray($FileList)) Or (@error = 1) Then
         MsgBox(262208, "Sorry!", "No Files\Folders Found in." & @CRLF & $Gloc & "   ", 5)
         Return
     EndIf
     GUICtrlSetData($Combo_2, "")
     For $x = 1 To $FileList[0]
         GUICtrlSetData($Combo_2, StringTrimRight($FileList[$x], 4) & "|", 1)
     Next
     GUICtrlSetData($Combo_2, "New Game")
EndFunc;==>Set_Game_List

Func Set_game()
     If Not FileExists($Gloc & $Ginfo & ".ini") Then
         MsgBox(262208, "Sorry!", "That File Does Not Exist!      " & @CRLF & $Gloc & $Ginfo & ".ini   " & @CRLF & 'Please choose "New Game" to Create a New GameBot   ', 5)
         Return
     EndIf
     $Run = IniRead($Gloc & $Ginfo & ".ini", "Settings", "Run", "0")
     If $Run = 0 Then
         GUICtrlSetState($Radio_9, $GUI_CHECKED)
         GUICtrlSetState($Radio_7, $GUI_UNCHECKED)
         GUICtrlSetState($Radio_6, $GUI_UNCHECKED)
         GUICtrlSetData($Input_8, "No Launch")
         GUICtrlSetState($Input_8, $GUI_DISABLE)
         $Launcher = ""
     ElseIf $Run = 1 Then
         GUICtrlSetState($Radio_7, $GUI_UNCHECKED)
         GUICtrlSetState($Radio_9, $GUI_UNCHECKED)
         $Launcher = IniRead($Gloc & $Ginfo & ".ini", "Settings", "Launcher", "Not Found")
         GUICtrlSetState($Input_8, $GUI_ENABLE)
         GUICtrlSetData($Input_8, $Launcher)
         GUICtrlSetState($Radio_6, $GUI_CHECKED)
     ElseIf $Run = 2 Then
         GUICtrlSetState($Radio_6, $GUI_UNCHECKED)
         GUICtrlSetState($Radio_9, $GUI_UNCHECKED)
         $Launcher = IniRead($Gloc & $Ginfo & ".ini", "Settings", "Launcher", "Not Found")
         GUICtrlSetState($Input_8, $GUI_ENABLE)
         GUICtrlSetData($Input_8, $Launcher)
         GUICtrlSetState($Radio_7, $GUI_CHECKED)
     EndIf
; pixel search
     $left = IniRead($Gloc & $Ginfo & ".ini", "Settings", "Left", "None")
     GUICtrlSetData($Input_12, $left)
     $top = IniRead($Gloc & $Ginfo & ".ini", "Settings", "Top", "None")
     GUICtrlSetData($Input_13, $top)
     $right = IniRead($Gloc & $Ginfo & ".ini", "Settings", "Right", "None")
     GUICtrlSetData($Input_14, $right)
     $bottom = IniRead($Gloc & $Ginfo & ".ini", "Settings", "Bottom", "None")
     GUICtrlSetData($Input_15, $bottom)
     $Vary = IniRead($Gloc & $Ginfo & ".ini", "Settings", "Vary", "5")
     GUICtrlSetData($Input_17, $Vary)
     $cwait = IniRead($Gloc & $Ginfo & ".ini", "Settings", "CWait", "0")
     GUICtrlSetData($Input_19, $cwait)
     $wait = IniRead($Gloc & $Ginfo & ".ini", "Settings", "Wait", "1000")
     GUICtrlSetData($Input_18, $wait)
     $Skip = IniRead($Gloc & $Ginfo & ".ini", "Settings", "Skip", "5")
     GUICtrlSetData($Input_20, $Skip)
; colors
     If IniRead($Gloc & $Ginfo & ".ini", "Colors", "1", "") = "" Then
         MsgBox(262208, "Sorry!", "No Colors were Found!      ", 5)
         Return
     EndIf
     $Colors = IniReadSection($Gloc & $Ginfo & ".ini", "Colors")
     For $i = 0 To $Colors[0][0]
         $data[$i] = IniRead($Gloc & $Ginfo & ".ini", "Colors", $i, "")
;GUICtrlSetData($Label_[$i], $data[$i])
         GUICtrlSetBkColor($Label_[$i], $data[$i])
         If $i >= 10 Then ExitLoop
     Next
    
EndFunc;==>Set_game

Func Get_Colors()
     $Ginfo = GUICtrlRead($Combo_2)
     If $Ginfo = "New Game" Or $Ginfo = "" Then
         MsgBox(262208, "Sorry!", "Please Select a Game Name First   ", 5)
         Return
     EndIf
     If GUICtrlRead($Button_30) = "Get Colors" Then
         HotKeySet("{F9}", "set_color")
         ToolTip('Press "F9" to Get the Color under the Mouse, Click "Done" when Finished', 0, 0)
         GUICtrlSetData($Button_30, "Done")
         Return
     Else
         HotKeySet("{F9}")
         ToolTip('')
         GUICtrlSetData($Button_30, "Get Colors")
         MsgBox(262208, "Saved!", "The Colors have been Saved to " & @CRLF & $Gloc & $Ginfo & ".ini" & "   ", 5)
         $Count = 0
     EndIf
EndFunc;==>Get_Colors

Func set_color()
     $Ginfo = GUICtrlRead($Combo_2)
     $pos = MouseGetPos()
     $CHex = Hex(PixelGetColor($pos[0], $pos[1]), 6)
     $Count = $Count + 1
     If $Count > 10 Then
         MsgBox(262208, "Sorry!", "Colors pre-selected is Full!      ", 5)
         Return
     Else
         IniWrite($Gloc & $Ginfo & ".ini", "Colors", $Count, "0x" & $CHex)
         GUICtrlSetBkColor($Label_[$Count], "0x" & $CHex)
     EndIf
EndFunc;==>set_color

Func Clear_Colors()
     For $x = 1 To 10
         GUICtrlSetBkColor($Label_[$x], 0xECE9D8)
     Next
     $Count = 0
EndFunc;==>Clear_Colors

Func Get_Area()
     $Ginfo = GUICtrlRead($Combo_2)
     If $Ginfo = "New Game" Or $Ginfo = "" Then
         MsgBox(262208, "Sorry!", "Please Select a Game Name First   ", 5)
         Return
     EndIf
     $Count = 0
     If GUICtrlRead($Button_29) = "Get Area" Then
         HotKeySet("{F9}", "set_Area")
         ToolTip('Press "F9" to Get the Area under the Mouse Left-Top-Right-Bottom, Click "Done" when Finished', 0, 0)
         GUICtrlSetData($Button_29, "Done")
         Return
     Else
         HotKeySet("{F9}")
         ToolTip('')
         GUICtrlSetData($Button_29, "Get Area")
         $Count = 0
     EndIf
EndFunc;==>Get_Area

Func set_Area()
     $Count = $Count + 1
     $Mpos = MouseGetPos()
     If $Count = 1 Then GUICtrlSetData($Input_12, $Mpos[0])
     If $Count = 2 Then GUICtrlSetData($Input_13, $Mpos[1])
     If $Count = 3 Then GUICtrlSetData($Input_14, $Mpos[0])
     If $Count = 4 Then GUICtrlSetData($Input_15, $Mpos[1])
     If $Count >= 4 Then $Count = 0
EndFunc;==>set_Area

Func Save_Game()
     $Ginfo = GUICtrlRead($Combo_2)
     If $Ginfo = "New Game" Or $Ginfo = "" Then
         MsgBox(262208, "Sorry!", "Please Select a Game Name First   ", 5)
         Return
     EndIf
     If Not FileExists($Gloc & $Ginfo & ".ini") Then
         MsgBox(262208, "Sorry!", "That File Does Not Exist!      " & @CRLF & $Gloc & $Ginfo & ".ini   " & @CRLF & 'Please choose "New Game" to Create a New GameBot   ', 5)
         Return
     EndIf
     $Run = "L"
     If BitAND(GUICtrlRead($Radio_9), $GUI_CHECKED) = $GUI_CHECKED Then
         $Run = 0
         $Launcher = "No Launch"
     ElseIf BitAND(GUICtrlRead($Radio_7), $GUI_CHECKED) = $GUI_CHECKED Then
         $Run = 2
         $Launcher = GUICtrlRead($Input_8)
     ElseIf BitAND(GUICtrlRead($Radio_6), $GUI_CHECKED) = $GUI_CHECKED Then
         $Run = 1
         $Launcher = GUICtrlRead($Input_8)
     EndIf
     If $Run = "L" Or $Launcher = "" Then
         MsgBox(262208, "Sorry!", "Run Select Error   ", 5)
         MsgBox(0, $Run, $Launcher)
         Return
     EndIf
     $left = GUICtrlRead($Input_12)
     $top = GUICtrlRead($Input_13)
     $right = GUICtrlRead($Input_14)
     $bottom = GUICtrlRead($Input_15)
     $Vary = GUICtrlRead($Input_17)
     $wait = GUICtrlRead($Input_18)
     $cwait = GUICtrlRead($Input_19)
     $Skip = GUICtrlRead($Input_20)
     If $Run = 0 Then
         IniWrite($Gloc & $Ginfo & ".ini", "Settings", "Run", $Run)
         IniWrite($Gloc & $Ginfo & ".ini", "Settings", "Launcher", "No Launch")
     Else
         IniWrite($Gloc & $Ginfo & ".ini", "Settings", "Run", $Run)
         IniWrite($Gloc & $Ginfo & ".ini", "Settings", "Launcher", $Launcher)
     EndIf
     IniWrite($Gloc & $Ginfo & ".ini", "Settings", "Left", $left)
     IniWrite($Gloc & $Ginfo & ".ini", "Settings", "Top", $top)
     IniWrite($Gloc & $Ginfo & ".ini", "Settings", "Right", $right)
     IniWrite($Gloc & $Ginfo & ".ini", "Settings", "Bottom", $bottom)
     IniWrite($Gloc & $Ginfo & ".ini", "Settings", "Vary", $Vary)
     IniWrite($Gloc & $Ginfo & ".ini", "Settings", "CWait", $cwait)
     IniWrite($Gloc & $Ginfo & ".ini", "Settings", "Wait", $wait)
     IniWrite($Gloc & $Ginfo & ".ini", "Settings", "Skip", $Skip)
     MsgBox(262208, "Done!", "File appears to be written Correctly!   ", 5)
EndFunc;==>Save_Game

Func Set_Run()
     $Ginfo = GUICtrlRead($Combo_2)
     If $Ginfo = "New Game" Or $Ginfo = "" Then
         MsgBox(262208, "Sorry!", "Please Select a Game Name First   ", 5)
         Return
     EndIf
     If Not FileExists($Gloc & $Ginfo & ".ini") Then
         MsgBox(262208, "Sorry!", "That File Does Not Exist!      " & @CRLF & $Gloc & $Ginfo & ".ini   " & @CRLF & 'Please choose "New Game" to Create a New GameBot   ', 5)
         Return
     EndIf
     If IniRead($Gloc & $Ginfo & ".ini", "Colors", "1", "") = "" Then
         MsgBox(262208, "Sorry!", "No Colors were Found!      ", 5)
         Return
     EndIf
     If $Run = 1 Then
         Run(@ComSpec & " /c Start " & $Launcher, "", @SW_HIDE)
     ElseIf $Run = 2 Then
         $Launched = FileGetShortName($Launcher)
         Run(@ComSpec & " /c Start " & $Launched, "", @SW_HIDE)
     EndIf
     GUISetState(@SW_MINIMIZE, $Gamebot)
     ToolTip('Press F9 to Start Game', 0, 0)
     _ReduceMemory()
     HotKeySet("{F9}", "_start")
EndFunc;==>Set_Run

Func _start()
     $Colors = IniReadSection($Gloc & $Ginfo & ".ini", "Colors")
     For $i = 0 To $Colors[0][0]
         $data[$i] = IniRead($Gloc & $Ginfo & ".ini", "Colors", $i, "")
         If $i >= 10 Then ExitLoop
     Next
     $pause = Not $pause
     While $pause
         ToolTip('GameBot is "Running"..   Press F9 to Quit', 0, 0)
         $t = 0
         Do
             $t = $t + 1
             If $t > 10 Then ExitLoop
             Sleep($cwait)
             $Cpos = PixelSearch($left, $top, $right, $bottom, $data[$t], $Vary, $Skip)
         Until Not @error
         If $t > 10 Then ContinueLoop
         MouseClick("left", $Cpos[0], $Cpos[1], 1, 0)
;MouseMove($left, $top)
         Sleep($wait)
     WEnd
     ToolTip('')
     GUISetState(@SW_RESTORE, $Gamebot)
     HotKeySet("{F9}")
EndFunc;==>_start

Func _ReduceMemory()
     Local $ai_Return = DllCall("psapi.dll", 'int', 'EmptyWorkingSet', 'long', -1)
     Return $ai_Return[0]
EndFunc;==>_ReduceMemory

Func Terminate()
     Exit
EndFunc;==>Terminate

Enjoy!!!

Valuater

8)

Edited by Valuater

NEWHeader1.png

Link to comment
Share on other sites

  • Moderators

nice , but for noobies , if you want to make a bot , use au3 not an script of au3 to make a bot , thats a bot maker in a botmaker..

@jaenster, will you please stop bashing other peoples programs, can you tell me something that you have contributed that is worth a damn? (And I don't mean other peoples source code either from the hacked decompiler that any lame brain could use)

@Val, I'm sure alot of folks (Especially noobs) will benefit.

Common sense plays a role in the basics of understanding AutoIt... If you're lacking in that, do us all a favor, and step away from the computer.

Link to comment
Share on other sites

I don't quite get it, would this would with counter strike even? Can someone please explain the colors and the top, left, right, bottom???

Thank you

[center]AutoIT + Finger Print Reader/Scanner = COOL STUFF -> Check Out Topic![/center][center][font=Arial Black]Check out ConsultingJoe.com[/font][/center][center]My Scripts~~~~~~~~~~~~~~Web Protocol Managing - Simple WiFi Scanner - AutoTunes - Remote PC Control V2 - Audio SpectrascopePie Chart UDF - At&t's TTS - Custom Progress Bar - Windows Media Player Embed[/center]

Link to comment
Share on other sites

  • Moderators

Top = X Coord Top Left of the beginning area to search

Left = Y Coord Top Left of the beginning area to search

Right = X Coord Bottom Right of End of Area to search

Bottom = Y Coord Bottom Right of End of Area to search

So you have 2 points of access, the beginning x and y coord, and the ending x and y coord of an area to search.

Common sense plays a role in the basics of understanding AutoIt... If you're lacking in that, do us all a favor, and step away from the computer.

Link to comment
Share on other sites

Top = X Coord Top Left of the beginning area to search

Left = Y Coord Top Left of the beginning area to search

Right = X Coord Bottom Right of End of Area to search

Bottom = Y Coord Bottom Right of End of Area to search

So you have 2 points of access, the beginning x and y coord, and the ending x and y coord of an area to search.

WOW, that thing is great. But its kinda glitchy but i haven't tried the other options, major props. it would only work on little games right, I'm sure for something like CS you could get it to help to be an aim bot right?

again nice job

[center]AutoIT + Finger Print Reader/Scanner = COOL STUFF -> Check Out Topic![/center][center][font=Arial Black]Check out ConsultingJoe.com[/font][/center][center]My Scripts~~~~~~~~~~~~~~Web Protocol Managing - Simple WiFi Scanner - AutoTunes - Remote PC Control V2 - Audio SpectrascopePie Chart UDF - At&t's TTS - Custom Progress Bar - Windows Media Player Embed[/center]

Link to comment
Share on other sites

C:\Documents and Settings\Owner2\My Documents\GameBot.au3(24,38) : WARNING: $GUI_DROPACCEPTED: possibly used before declaration.
GUICtrlSetState(-1, $GUI_DROPACCEPTED)
~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~^
C:\Documents and Settings\Owner2\My Documents\GameBot.au3(24,38) : ERROR: $GUI_DROPACCEPTED: undeclared global variable.
GUICtrlSetState(-1, $GUI_DROPACCEPTED)
~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~^
C:\Documents and Settings\Owner2\My Documents\GameBot.au3(142,40) : ERROR: _FileListToArray(): undefined function.
    $FileList = _FileListToArray ($Gloc)
~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~^
C:\Documents and Settings\Owner2\My Documents\GameBot.au3 - 2 error(s), 1 warning(s)

I'm getting this error, and it won't launch. (I know, I"m new :o)

This is happening when I compile it myself (that's the error from SciTE editor that pops up when I click run)

This is from the bottom window (below the acctual code window) after I press "continue anyways":

>"C:\Program Files\AutoIt3\SciTE\CompileAU3\CompileAU3.exe" /run /beta /ErrorStdOut /in "C:\Documents and Settings\Owner2\My Documents\GameBot.au3" /autoit3dir "C:\Program Files\AutoIt3\beta" /UserParams 
>Running AU3Check   C:\Program Files\AutoIt3\SciTE\Defs\Unstable\Au3Check\au3check.dat
C:\Documents and Settings\Owner2\My Documents\GameBot.au3(24,38) : WARNING: $GUI_DROPACCEPTED: possibly used before declaration.
GUICtrlSetState(-1, $GUI_DROPACCEPTED)
~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~^
C:\Documents and Settings\Owner2\My Documents\GameBot.au3(24,38) : ERROR: $GUI_DROPACCEPTED: undeclared global variable.
GUICtrlSetState(-1, $GUI_DROPACCEPTED)
~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~^
C:\Documents and Settings\Owner2\My Documents\GameBot.au3(142,40) : ERROR: _FileListToArray(): undefined function.
    $FileList = _FileListToArray ($Gloc)
~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~^
C:\Documents and Settings\Owner2\My Documents\GameBot.au3 - 2 error(s), 1 warning(s)
>AU3Check Ended with Error(s).
>Running: (3.1.1.0):C:\Program Files\AutoIt3\autoit3.exe "C:\Documents and Settings\Owner2\My Documents\GameBot.au3"    
C:\Documents and Settings\Owner2\My Documents\GameBot.au3 (142) : ==> Unknown function name.: 
$FileList = _FileListToArray ($Gloc) 
$FileList = ^ ERROR
>AutoIT3.exe ended.
>Exit code: 0   Time: 193.929

any idea what's goin on?

Link to comment
Share on other sites

Judging by the errors, I'd say the #include lines are missing (I was going to say it's a production vs beta issue, but I ran it fine with production and didn't have any errors). Make sure you have the #include lines at the top, and then make sure that the files are in your AutoIt installation directory. If you didn't install it (used .zip version instead of .exe), use the full path to the includes.

Link to comment
Share on other sites

  • 2 weeks later...

When I try to run it(From my desktop\GameBot Builder\Gamebot builder.au3) I get this error message:

Line 155 (File "C:\Documents and Settings\MyUser\Desktop\GameBot Builder\Gamebot Builder.au3"):

$FileList = _FileListToArray ($Gloc)

$FileList = ^ERROR

Error: Unknown function name

Link to comment
Share on other sites

I need a simple script to check the color of the mouse. If its a certain color, to perform an action. Not under the mouse ( I can do that) but if the mouse itself turns a color to perform an action.

can I do that with the GameBot builder ?

Link to comment
Share on other sites

  • 2 months later...

Wow! Great script!

AutoIt if more than a hobby. Is a way of life!http://www.autoitscript.com/forum/index.php?showtopic=26002 -my first projecthttp://www.autoitscript.com/forum/index.php?showtopic=26103 -my second project
Link to comment
Share on other sites

  • 2 weeks later...
  • 4 weeks later...

Hi Valuater,

I am trying to use your GetColor script that you wrote to get the color value beneath the cursor in a game. Everwhere that I try to get the color in the game I am coming up with a 'Black' value. If I try and use your script to get the color inside of a web browser it works flawlessly. I am assuming the problem that I am having is that AutoIT's GetColor function is having a problem reading the color values of this particular game. Is this a DirectX/OpenGL issue? Is there an alternative method that I can use or am I SOL? Thanks in advance for your help.

Black Widow

Link to comment
Share on other sites

Guest
This topic is now closed to further replies.
 Share

  • Recently Browsing   0 members

    • No registered users viewing this page.
×
×
  • Create New...