Gotta start somewhere.

[Cadman]

First yes I have the betta yes I use SciTE for editing.

Ok so I created a form with a bunch of buttons.

Sample: GuiCtrlCreateButton("regedit", 373, 330, 90, 20) and as a standalone

script i can make it run.

Run("regedit.exe") Now my questions.

A / When I click the button "regedit' what kind of code is required to run,start regedit.exe?The script without form works fine.

B / I am looking to make a popup appear for confirmation.IE:Run bla bla bla?ok/cancel

C / I can make a script to run a .VBS file but again can't figure out the on click or do or function.

D / When I place a picture acoss the form the buttons are still vissible but don't click.Send picture to back? how?

I guess a button that runs something other than a msg would be a nice place to start with autoit3 no?

All or any help to let the fun begin would be most appreciated.

Humble beginnings.

P.s most of the sample scipts provided show error.

Error parsing,Error unknown function,unresolved etc... Hard to learn that way.

[Valuater]

show us your script... then we can help you better

use this to post it

[ code ] ; no spaces

; post your code

[ /code ] ; no spaces

8)

Edited March 5, 2006 by Valuater

[CyberSlug]

There are two approaches. I usually use the first method; however, the second way is better structured for complex GUIs and is similar to other programming languages.

The code for a confirmation box would be the same, but I just put it in the second example.

When a picture overlaps with a button, you need to disable the picture:

#include <GuiConstants.au3>
$myPic = GuiCtrlCreatePic("something.jpg", 10, 10)
GUICtrlSetState(-1, $GUI_DISABLE)
Just so you know, -1 in the above line referes to the most recently created control.  I could have also said GUICtrlSetState($myPic, $GUI_DISABLE)

Answers to question A:

#include <GuiConstants.au3>
GuiCreate("Example One")

$Button1 = GuiCtrlCreateButton("Launch Regedit", 100, 100, 200, 30)

GuiSetState()
While 1
    $msg = GuiGetMsg()
    
    Select
        Case $msg = $GUI_EVENT_CLOSE
            Exit
        Case $msg = $Button1
            Run("regedit.exe")
    EndSelect
WEnd

#include <Constants.au3>
#include <GUIConstants.au3>
Opt("GUIOnEventMode", 1)

GUICreate("Example Two")
GUISetOnEvent($GUI_EVENT_CLOSE, "SpecialEvents")

$Button1 = GUICtrlCreateButton ("Launch Regedit",  10, 10, 100, 30)
GUICtrlSetOnEvent(-1, "RegeditButtonclicked")


GUISetState()

; Just idle around
While 1
    Sleep(10)
Wend


Func RegeditButtonclicked()
    $answer = MsgBox($MB_YESNO, "Confirm", "Do you want to run regedit?")
    If $answer = $IDYES Then Run("regedit.exe")
EndFunc

Func SpecialEvents()
    If @GUI_CTRLID = $GUI_EVENT_CLOSE Then Exit
EndFunc

Edited March 6, 2006 by CyberSlug

[BigDod]

Has no-one noticed that this is in the wrong forum. This is the V2 Support forum.

[cppman]

hahaha, they accidently clicked the wrong link, "7 links down".....