Help in advance.

[GEOSoft]

Does anyone know a good loop to get the names of all the DLL and OCX files in the %System% folder and write the filename, modified date and version number of each to a file? It is needed to check if any files have been changed since the app was last run ( similiar to the Windows SFC of the past). The next stage will be comparing the lists but that can wait for a while.

I also need a method to Append the contents of a text file to the clipboard.

[CyberSlug]

Since no one else has posted, here you go

expandcollapse popup

; Append text to clipboard
$textFromFile = "code to get text from file goes here..."
$clipBAK = ClipGet()
ClipPut($clipBAK & @CRLF & $textFromFile)


;Get the names of all the DLL and OCX files in the %System% folder, and
;write the filename, modified date and version number of each to a file
;Generates a tab-separated file with Name, Version, and TimeStamp.

$outputFile = "DllOcxInfo.txt"
$output = FileOpen($outputFile, 1) ;write/append file mode

If $output = -1 Then;see if file opened for writing OK
   MsgBox(0, "Error", "Unable to open file.")
   Exit
EndIf

SplashTextOn("Please wait", "Writing DLL and OCX info to " & $outputFile)

; DLL Files
$fileName = FileFindFirstFile(@SystemDir & "\*.dll") 
$errorFlag = @error
$modTime = prettyPrintTime(@SystemDir & "\" &$fileName)
$version = FileGetVersion(@SystemDir & "\" &$fileName)


While $errorFlag = 0
  ;note that Chr(9) is the tab character
   FileWriteLine($output, _
      $fileName & Chr(9) & $version & Chr(9) & $modTime & @LF)

   $fileName = FileFindNextFile() 
   $errorFlag = @error
   $modTime = prettyPrintTime(@SystemDir & "\" &$fileName)
   $version = FileGetVersion(@SystemDir & "\" &$fileName)
WEnd


; OCX Files
$fileName = FileFindFirstFile(@SystemDir & "\*.ocx") 
$errorFlag = @error
$modTime = prettyPrintTime(@SystemDir & "\" &$fileName)
$version = FileGetVersion(@SystemDir & "\" &$fileName)

While $errorFlag = 0
  ;note that Chr(9) is the tab character
   FileWriteLine($output, _
      $fileName & Chr(9) & $version & Chr(9) & $modTime & @LF)

   $fileName = FileFindNextFile() 
   $errorFlag = @error
   $modTime = prettyPrintTime(@SystemDir & "\" &$fileName)
   $version = FileGetVersion(@SystemDir & "\" &$fileName)
WEnd


FileClose($output)
SplashOff()
MsgBox(0,"","Operation Completed")
Exit


Func prettyPrintTime($fileName)
   $t = FileGetTime($fileName, 0) ;0=modificationTime
   If @error Then Return "TimeStampError"

   $hr = $t[3]
   $min = $t[4]
   $sec = $t[5]

   If $min < 10 Then $min = "0" & $min
   If $sec < 10 Then $sec = "0" & $sec

   $time = ($hr & ":" & $min & ":" & $sec)   ; h:mm:ss (24-hour format)
   $date = $t[1] & "/" & $t[2] & "/" & $t[0] ; m/d/yyyy format
   Return ($time & " " & $date)
EndFunc

[GEOSoft]

Thanks CS. That's a starting point at least. I'll see what I can do with it.

[CyberSlug]

I just realized that my append-clipboard-text response has a bug: If the clipboard is empty or contains a picture, $bak is the number zero! Here's a better solution:

; Note:  Perhaps you don't want to use @CRLF at all
Func ClipAppend($text)
    $bak = ClipGet()
    If @error Then
  ClipPut($text)
    Else
  ClipPut($bak & @CRLF & $text)
    EndIf
EndFunc

[GEOSoft]

Thanks again. I had not gotten around to trying it yet anyway. I still have a lot of other code to do for this project. I should have thought right away to place it in a tempfile first and then append. I must have been brain dead at that moment. I actually have to append the contents of Autoexec.bat, Config.sys,Dosstart.bat and portions of the System.ini files if they exist. It may all be redundent anyway because of the hassles with onclick functions for the buttons in Larry's GUI. I'm begining th think that Delphi is going to be more suitable than a compiled macro.