Smtp Mailer That Supports Html And Attachments.

TheDcoder · January 14, 2021

@Jos Definitely not, the priorities for this project have been shifted and the email aspect is not in the focus right now, but I might get to work on it soon.

Jos · January 14, 2021

Different words ... same conclusion .... but this time it wasn't just directly to you and meant more as a general statement as nobody using it and seen the request bothered to test/respond.... which is fine and it simply means that version won't make it to the first page.

TheDcoder · January 14, 2021

@Jos I imagine there aren't many people who use SMTP directly from the application, so unless someone volunteers their time to test, it is going to take a while. Luckily I am still actively working on the project so I should be able to test soon.

I would've tested it separately but I don't want to use my Google account for testing, so need to wait for my client so I can use their servers.

mLipok · January 14, 2021

18 minutes ago, TheDcoder said:

unless someone volunteers their time to test, it is going to take a while

Test what ?

Zedna · January 14, 2021

5 hours ago, mLipok said:

Test what ?

I doubt if explicit forcing of UTF-8 will not break non english national characters

because I almost everywhere use Windows 1250 code page for my native Czech language,

UTF is more problematic in my experience.

Sorry I dont have time for testing of this latest (forced UTF-8) change these days ...

TheDcoder · January 15, 2021

@mLipok The UTF-8 changes, currently the UDF has problems with non-Latin characters.

@Zedna UTF-8 should be less problematic compared to all other encodings because it is pretty much universally adopted and is backward compatible with ASCII, perhaps you are having problems because Windows 1250 is not compatible with it? :think:

mLipok · January 16, 2021

On 12/30/2020 at 10:31 AM, Jos said:

Just add the 2 lines to the original UDF:

If StringInStr($as_Body, "<") And StringInStr($as_Body, ">") Then
        $objEmail.HTMLBody = $as_Body
        $objEmail.HTMLBodyPart.CharSet = "UTF-8"
    Else
        $objEmail.Textbody = $as_Body & @CRLF
        $objEmail.TextBodyPart.CharSet = "UTF-8"
    EndIf

Jos

It was discussed here in this topic, almost 6 years ago.

On 2/4/2015 at 11:37 AM, Allow2010 said:

currently i use

If $xusehtml Or StringInStr(StringStripWS($as_Body, 8), "<html>") Or StringInStr(StringStripWS($as_Body,8), "<!DOCTYPEhtml>") Then
            $objEmail.HTMLBody = $as_Body
            $objEmail.HTMLBodyPart.CharSet = "UTF-8"
            $objEmail.HTMLBodyPart.ContentTransferEncoding = "quoted-printable"
        Else
            $objEmail.Textbody = $as_Body & @CRLF
            $objEmail.TextBodyPart.CharSet = "UTF-8"
            $objEmail.TextBodyPart.ContentTransferEncoding = "quoted-printable"
        EndIf

and i added $xusehtml to the function definition so i can force html mode if needed, or it will be used if html is detected...

What about "quoted-printable" ?
I think should be used , at least I use them all the time (6 years till now).

mLipok · January 16, 2021

Please also check this:

Jos · January 16, 2021

Looks promising, but I have no idea what the result of all of this combined will be so will need confirmation that everything will remain working!
As nobody have yet confirmed the previous UTF8 change proposal will keep working in all cases and only seen opinions that it might fail, I am not doing anything for the moment until either a confirmation or issues are provided in a script form.

Zedna · January 16, 2021

If $xusehtml Or StringInStr(StringStripWS($as_Body, 8), "<html>") Or StringInStr(StringStripWS($as_Body,8), "<!DOCTYPEhtml>") Then
            $objEmail.HTMLBody = $as_Body
            $objEmail.HTMLBodyPart.CharSet = "UTF-8"
            $objEmail.HTMLBodyPart.ContentTransferEncoding = "quoted-printable"
        Else
            $objEmail.Textbody = $as_Body & @CRLF
            $objEmail.TextBodyPart.CharSet = "UTF-8"
            $objEmail.TextBodyPart.ContentTransferEncoding = "quoted-printable"
        EndIf

I use this

$objEmail = ObjCreate ("CDO.Message")
$objEmail.BodyPart.ContentTransferEncoding = "8bit"
$objEmail.BodyPart.CharSet = "windows-1250"

As far as I know there is probably implicit 7bit ContentTransferEncoding which is OK for English chars (without diacritic chars).

So this way I force transfer_encoding 8bit + charset=windows-1250 for Czech language with diacritic chars (ěščřžýáíé)

I use this setting all the time (15 years intensively) without any problems.

EDIT:

If StringInStr($e_Text,"</html>",1) Then
    $objEmail.HTMLBody = $e_Text
Else
    $objEmail.Textbody = $e_Text
EndIf

This way I set text of email, typically to TexBody,

so I don't use: $objEmail.TextBodyPart.CharSet = "windows-1250"

but "more global": $objEmail.BodyPart.CharSet = "windows-1250"

and the same analogy to "Global/non Global" CharSet also with: ContentTransferEncoding

Edited January 16, 2021 by Zedna

mLipok · January 16, 2021

4 hours ago, Jos said:

As nobody have yet confirmed the previous UTF8 change proposal will keep working in all cases and only seen opinions that it might fail, I am not doing anything for the moment until either a confirmation or issues are provided in a script form.

as I said:

12 hours ago, mLipok said:

I use them all the time (6 years till now).

So I do not see any issue as so far.

TheDcoder · February 10, 2021

@Jos I finally got the chance to test your UTF-8 changes, and they worked perfectly! I am pretty satisfied with the result, I tested both the name and body with Unicode text

I do have one suggestion though, it will be better to rename the base64 encoding function to __INetSmtpMailCom_Base64Encode in order to avoid conflicts.

supersonic · February 26, 2021

@Jos Thank you for keeping this UDF maintained and improved! I've been using it for over 10 years - with well over 100,000+ emails sent.

I like to confirm that on my side the UTF-8 changes work like a treat.

Are there any conceivable circumstances where UTF-8 handling should be disabled?

Jos · February 26, 2021

19 minutes ago, supersonic said:

Are there any conceivable circumstances where UTF-8 handling should be disabled?

I would expect not but looking at all the posts here with all the different settings used with UTF & Codepages, I have no clue what so ever if there is one setting that solves all possibilities and have no idea how this all can be tested, so am not going to worry about it and leave things as they are until there is a safe conclusion we can make for changes.

TheDcoder · February 26, 2021

6 hours ago, Jos said:

...leave things as they are...

Maybe the OP can be updated to mention this experimental UTF-8 code?

supersonic · March 15, 2021

Regarding the last posts about UTF-8, there are three sections (or more?) that affect this very thing:

1 - Body (overall?):

$objEmail.BodyPart.ContentTransferEncoding = "8bit"
$objEmail.BodyPart.CharSet = "windows-1250"

2 - Body (by type):

If StringInStr($as_Body, "<") And StringInStr($as_Body, ">") Then
    $objEmail.HTMLBody = $as_Body
    $objEmail.HTMLBodyPart.CharSet = "UTF-8"
Else
    $objEmail.Textbody = $as_Body & @CRLF
    $objEmail.TextBodyPart.CharSet = "UTF-8"
EndIf

3 - Sender name:

$s_FromName = "Jos ąćę" ; Name from who the email was sent.
$s_Fromname = "=?utf-8?B?" & _Base64Encode(BinaryToString(StringToBinary($s_FromName,4),1)) & '?='

Is anyone out there who knows about possible interactions? Or is it unproblematic to use all these settings at the same time - a lot helps a lot?

Regarding 1 and 2: Are these settings redundant? Or complementary?

I could not provoke any incompatibilities - maybe I just got lucky or tested wrong.

Somebody any clue?

Edited March 16, 2021 by supersonic

MaxWilko · May 18, 2021

;
;##################################
; Include
;##################################
#Include<file.au3>
;##################################
; Variables
;##################################
$SmtpServer = "smtp-mail.outlook.com"              ; address for the smtp-server to use - REQUIRED
$FromName = "AutoCaliBot"                      ; name from who the email was sent
$FromAddress = "ri------autocali@outlook.com" ; address from where the mail should come
$ToAddress = "au------collect@outlook.com"   ; destination address of the email - REQUIRED
$Subject = "Calibration Report"                   ; subject from the email - can be anything you want it to be
$Body = "Test"                              ; the messagebody from the mail - can be left blank but then you get a blank mail
$AttachFiles = "01089.csv"                       ; the file(s) you want to attach seperated with a ; (Semicolon) - leave blank if not needed
$CcAddress = ""                           ; address for cc - leave blank if not needed
$BccAddress = ""     ; address for bcc - leave blank if not needed
$Importance = "Normal"                  ; Send message priority: "High", "Normal", "Low"
$Username = "ri------autocali@outlook.com"                    ; username for the account used from where the mail gets sent - REQUIRED
$Password = "mypass"                  ; password for the account used from where the mail gets sent - REQUIRED
$IPPort = 587                            ; port used for sending the mail
$ssl = 0                                ; enables/disables secure socket layer sending - put to 1 if using httpS
$tls = 0                                ; enables/disables TLS when required
;$IPPort=465                          ; GMAIL port used for sending the mail
;$ssl=1                               ; GMAILenables/disables secure socket layer sending - put to 1 if using httpS

;##################################
; Script
;##################################
Global $oMyRet[2]
Global $oMyError = ObjEvent("AutoIt.Error", "MyErrFunc")
$rc = _INetSmtpMailCom($SmtpServer, $FromName, $FromAddress, $ToAddress, $Subject, $Body, $AttachFiles, $CcAddress, $BccAddress, $Importance, $Username, $Password, $IPPort, $ssl, $tls)
If @error Then
    MsgBox(0, "Error sending message", "Error code:" & @error & "  Description:" & $rc)
EndIf
;
; The UDF
Func _INetSmtpMailCom($s_SmtpServer, $s_FromName, $s_FromAddress, $s_ToAddress, $s_Subject = "", $as_Body = "", $s_AttachFiles = "", $s_CcAddress = "", $s_BccAddress = "", $s_Importance="Normal", $s_Username = "", $s_Password = "", $IPPort = 25, $ssl = 0, $tls = 0)
    Local $objEmail = ObjCreate("CDO.Message")
    $objEmail.From = '"' & $s_FromName & '" <' & $s_FromAddress & '>'
    $objEmail.To = $s_ToAddress
    Local $i_Error = 0
    Local $i_Error_desciption = ""
    If $s_CcAddress <> "" Then $objEmail.Cc = $s_CcAddress
    If $s_BccAddress <> "" Then $objEmail.Bcc = $s_BccAddress
    $objEmail.Subject = $s_Subject
    If StringInStr($as_Body, "<") And StringInStr($as_Body, ">") Then
        $objEmail.HTMLBody = $as_Body
    Else
        $objEmail.Textbody = $as_Body & @CRLF
    EndIf
    If $s_AttachFiles <> "" Then
        Local $S_Files2Attach = StringSplit($s_AttachFiles, ";")
        For $x = 1 To $S_Files2Attach[0]
            $S_Files2Attach[$x] = _PathFull($S_Files2Attach[$x])
;~          ConsoleWrite('@@ Debug : $S_Files2Attach[$x] = ' & $S_Files2Attach[$x] & @LF & '>Error code: ' & @error & @LF) ;### Debug Console
            If FileExists($S_Files2Attach[$x]) Then
                ConsoleWrite('+> File attachment added: ' & $S_Files2Attach[$x] & @LF)
                $objEmail.AddAttachment($S_Files2Attach[$x])
            Else
                ConsoleWrite('!> File not found to attach: ' & $S_Files2Attach[$x] & @LF)
                SetError(1)
                Return 0
            EndIf
        Next
    EndIf
    $objEmail.Configuration.Fields.Item ("http://schemas.microsoft.com/cdo/configuration/sendusing") = 2
    $objEmail.Configuration.Fields.Item ("http://schemas.microsoft.com/cdo/configuration/smtpserver") = $s_SmtpServer
    If Number($IPPort) = 0 then $IPPort = 25
    $objEmail.Configuration.Fields.Item ("http://schemas.microsoft.com/cdo/configuration/smtpserverport") = $IPPort
    ;Authenticated SMTP
    If $s_Username <> "" Then
        $objEmail.Configuration.Fields.Item ("http://schemas.microsoft.com/cdo/configuration/smtpauthenticate") = 1
        $objEmail.Configuration.Fields.Item ("http://schemas.microsoft.com/cdo/configuration/sendusername") = $s_Username
        $objEmail.Configuration.Fields.Item ("http://schemas.microsoft.com/cdo/configuration/sendpassword") = $s_Password
    EndIf
    ; Set security params
    If $ssl Then $objEmail.Configuration.Fields.Item ("http://schemas.microsoft.com/cdo/configuration/smtpusessl") = True
    If $tls Then $objEmail.Configuration.Fields.Item ("http://schemas.microsoft.com/cdo/configuration/sendtls") = True
    ;Update settings
    $objEmail.Configuration.Fields.Update
    ; Set Email Importance
    Switch $s_Importance
        Case "High"
            $objEmail.Fields.Item ("urn:schemas:mailheader:Importance") = "High"
        Case "Normal"
            $objEmail.Fields.Item ("urn:schemas:mailheader:Importance") = "Normal"
        Case "Low"
            $objEmail.Fields.Item ("urn:schemas:mailheader:Importance") = "Low"
    EndSwitch
    $objEmail.Fields.Update
    ; Sent the Message
    $objEmail.Send
    If @error Then
        SetError(2)
        Return $oMyRet[1]
    EndIf
    $objEmail=""
EndFunc   ;==>_INetSmtpMailCom
;
;
; Com Error Handler
Func MyErrFunc()
    $HexNumber = Hex($oMyError.number, 😎
    $oMyRet[0] = $HexNumber
    $oMyRet[1] = StringStripWS($oMyError.description, 3)
    ConsoleWrite("### COM Error !  Number: " & $HexNumber & "   ScriptLine: " & $oMyError.scriptline & "   Description:" & $oMyRet[1] & @LF)
    SetError(1); something to check for when this function returns
    Return
EndFunc   ;==>

ScriptLine: 93 Description: The server rejected the sender address. The server response was: 451 5.7.3 STARTTLS is required to send mail [LO4P123CA0226.GBRP123.PROD.OUTLOOK.COM]

Hi all, what am I doing wrong here? Please help ! Thanks for your time!

Edited May 18, 2021 by Jos
added codebox & removed exact emailaddress to avoid spam

Jos · May 18, 2021

You have the wrong ssl setting. This worked for me on my O365 account:

Jos

MaxWilko · May 18, 2021

Jos its all working, this was really helpful, thanks!

wan · August 26, 2022

@Jos Thank You . The email script working perfectly . But I want to ask how I want to include duration of script running time and send it also through email.

Smtp Mailer That Supports Html And Attachments.

Recommended Posts

Link to comment

Share on other sites

Top Posters In This Topic

Top Posters In This Topic

Popular Posts

Jos

Jos

water

Posted Images

Link to comment

Share on other sites

Link to comment

Share on other sites

Link to comment

Share on other sites

Link to comment

Share on other sites

Link to comment

Share on other sites

Link to comment

Share on other sites

Link to comment

Share on other sites

Link to comment

Share on other sites

Link to comment

Share on other sites

Link to comment

Share on other sites

Link to comment

Share on other sites

Link to comment

Share on other sites

Link to comment

Share on other sites

Link to comment

Share on other sites

Link to comment

Share on other sites

Link to comment

Share on other sites

Link to comment

Share on other sites

Link to comment

Share on other sites

Link to comment

Share on other sites

Create an account or sign in to comment

Create an account

Sign in

Recently Browsing 0 members