Jump to content

Problem With Showing Right Msg


Chobby
 Share

Recommended Posts

Hey. i'm working on a little script ... Just forget the use, as its for a game :think:

Its just, i want it to show 1 thing when 2 variables (from combo's) has been chosen and 'Preview'-button has been clicked.. But it always shows the same msg, no matter WHAT the variables are :S

Can you help me? Heres the code:

; Note .. A lot of code has been left out, as it has no use in this :)
; For example most of the Previews of all of the maps and gametypes
#include <GUIConstants.au3>
#include <Misc.au3>

GUICreate("Ca Server Commands - By Chobby", 440, 320, 100, 100)             
GUISetState (@SW_SHOW)                                                          
#NoTrayIcon

GUICtrlCreateGroup("Choose Map:", 20, 45, 160, 45)                          

GUICtrlCreateCombo("Choose default map", 30, 60, 140, 20)
$GUIMAP = GUICtrlSetData(-1, "  FFA_Bespin|  FFA_Deathstar|  FFA_Imperial|  FFA_NS_Hideout|  FFA_NS_Streets|  FFA_Raven|  FFA_Yavin|  CTF_Bespin|  CTF_Imperial|  CTF_NS_Streets|  CTF_Yavin|  Duel_Bay|  Duel_Jedi|  Duel_Pit|  Duel_Carbon| |Or custom map|  Jedi Council|  Country Academy|  Country Roads|  FFA_Koa|  NabooCity|  CloudCity")
GUICtrlCreateGroup("", -99, -99, 1, 1)                                          
GUICtrlCreateGroup("Choose Gametype:", 190, 45, 120, 45)                    

GUICtrlCreateCombo("Choose gametype", 200, 60, 100, 20)
$GUIGTYPE = GUICtrlSetData(-1, "  FFA|  Holocron|  Jedimaster|  Duel|  TFFA|  CTF")
GUICtrlCreateGroup("", -99, -99, 1, 1)  

$BTNPreview = GUICtrlCreateButton("&Preview", 125, 230, 100, 20)

GUICtrlCreateGroup("", -99, -99, 1, 1)  

While 1
    $msg = GUIGetMsg()
    If $msg = $GUI_EVENT_CLOSE Then
        Exit
    EndIf
    
    If $msg = $BTNPreview Then
    Select
        Case(GUICtrlRead($GUIMAP) = "  FFA_Bespin" = $GUI_ENABLE AND GUICtrlRead($GUIGTYPE) = "  FFA" = $GUI_ENABLE)
            MsgBox(4096, "Map change preview", "Will change the map to FFA in FFA_Bespin")
                    
        Case(GUICtrlRead($GUIMAP) = "  FFA_Bespin" = $GUI_ENABLE AND GUICtrlRead($GUIGTYPE) = "  Holocron" = $GUI_ENABLE)
            MsgBox(4096, "Map change preview", "Will change the map to Holocron in FFA_Bespin")
        ;Code left out, so its not that long..
    EndSelect
    EndIf
    Sleep(25)
WEnd
Link to comment
Share on other sites

you have

GUICtrlCreateCombo("Choose gametype", 200, 60, 100, 20)
$GUIGTYPE = GUICtrlSetData(-1, "  FFA|  Holocron|  Jedimaster|  Duel|  TFFA|  CTF")

it should be

$GUIGTYPE =GUICtrlCreateCombo("Choose gametype", 200, 60, 100, 20)
GUICtrlSetData(-1, "  FFA|  Holocron|  Jedimaster|  Duel|  TFFA|  CTF")

same for $GUIMAP =

8)

Edited by Valuater

NEWHeader1.png

Link to comment
Share on other sites

  • Moderators

This fixes the combo problem. I also optimized your case statements, which will save a lot of coding.

; Note .. A lot of code has been left out, as it has no use in this :)
; For example most of the Previews of all of the maps and gametypes
#include <GUIConstants.au3>
#include <Misc.au3>

#NoTrayIcon

GUICreate("Ca Server Commands - By Chobby", 440, 320, 100, 100)
GUISetState(@SW_SHOW)

GUICtrlCreateGroup("Choose Map:", 20, 45, 160, 45)

$GUIMAP = GUICtrlCreateCombo("Choose default map", 30, 60, 140, 20)
GUICtrlSetData(-1, "  FFA_Bespin|  FFA_Deathstar|  FFA_Imperial|  FFA_NS_Hideout|  FFA_NS_Streets|  FFA_Raven|  FFA_Yavin|  CTF_Bespin|  CTF_Imperial|  CTF_NS_Streets|  CTF_Yavin|  Duel_Bay|  Duel_Jedi|  Duel_Pit|  Duel_Carbon| |Or custom map|  Jedi Council|  Country Academy|  Country Roads|  FFA_Koa|  NabooCity|  CloudCity")
GUICtrlCreateGroup("", -99, -99, 1, 1)
GUICtrlCreateGroup("Choose Gametype:", 190, 45, 120, 45)

$GUIGTYPE = GUICtrlCreateCombo("Choose gametype", 200, 60, 100, 20)
GUICtrlSetData(-1, "  FFA|  Holocron|  Jedimaster|  Duel|  TFFA|  CTF")
GUICtrlCreateGroup("", -99, -99, 1, 1)

$BTNPreview = GUICtrlCreateButton("&Preview", 125, 230, 100, 20)

GUICtrlCreateGroup("", -99, -99, 1, 1)

While 1
    $msg = GUIGetMsg()
    Select
        Case $msg = $GUI_EVENT_CLOSE
            Exit
        Case $msg = $BTNPreview
            If GUICtrlRead($GUIGTYPE) <> "Choose gametype" And _
                    GUICtrlRead($GUIMAP) <> "Choose default map" Then
                MsgBox(4096, "Map change preview", "Will change the map to" & _
                        GUICtrlRead($GUIGTYPE) & " in" & GUICtrlRead($GUIMAP))
            Else
                ContinueLoop
            EndIf
        ;Code left out, so its not that long..
    EndSelect
WEnd
Link to comment
Share on other sites

actually, i would use stringsplit()

example

$info = StringSplit( " FFA_Bespin| FFA_Deathstar| FFA_Imperial| FFA_NS_Hideout| FFA_NS_Streets| FFA_Raven| FFA_Yavin| CTF_Bespin| CTF_Imperial| CTF_NS_Streets| CTF_Yavin| Duel_Bay| Duel_Jedi| Duel_Pit| Duel_Carbon| |Or custom map| Jedi Council| Country Academy| Country Roads| FFA_Koa| NabooCity| CloudCity", "|")

after creating the combo use

for $x = 1 to $info[0]

guictrlsetdata( $GUIMAP, $info[$x], 1)

next

and then use that same for/next loop to match the guictrlread

$GUIMAP_info = guictrlread($GUIMAP)

for $x = 1 to $info[0]

if $info[$x] = $GUIMAP_info then

$GUIMAP_info = $$info[$x]

rxitloop

endif

next

use that same routine for

$GUIGTYPE =

thats what i would do....... written on the fly.. not tested

8)

Edited by Valuater

NEWHeader1.png

Link to comment
Share on other sites

Sorry, i didn't understand much of it ...

Well, heres my whole script, but its not working .. I'm fucking up the While and WEnds :(

Can you help me, again? :think:

; Script Start
#include <GUIConstants.au3>
#include <Misc.au3>


GUICreate("Ca Server Commands - By Chobby", 440, 320, 100, 100)             ;Create the GUI
GUISetState (@SW_SHOW)                                                      ;Show the GUI
#NoTrayIcon

$filemenu = GUICtrlCreateMenu("Files")
$fileupdates = GUICtrlCreateMenuitem("Updates",$filemenu)
$seperator2 = GUICtrlCreateMenuitem("",$filemenu)
$fileexit = GUICtrlCreateMenuitem("Exit",$filemenu)

$linkmenu = GUICtrlCreateMenu("Links")
$link1 = GUICtrlCreateMenuitem("Clan Apathy Forum",$linkmenu)
$seperator1 = GUICtrlCreateMenuitem("", $linkmenu)
$link2 = GUICtrlCreateMenuitem("AutoIt HP",$linkmenu)
$link3 = GUICtrlCreateMenuitem("AutoIt Forum",$linkmenu)

$helpmenu = GUICtrlCreateMenu("Help")
$helpfile = GUICtrlCreateMenuitem("Help...",$helpmenu)
$helpabout = GUICtrlCreateMenuitem("About",$helpmenu)



GUICtrlCreateLabel("For more information and/or more programs see www.ipshare.5gigs.com! (Soon up) ", 10, 10, 400);Add the main label

GUICtrlCreateGroup("Change Map:", 10, 30, 420, 225)                         ;Add main group
GUICtrlCreateGroup("Choose Map:", 20, 45, 160, 45)                          ;Add map group

$GUIMAP = GUICtrlCreateCombo("Choose default map", 30, 60, 140, 20)
GUICtrlSetData(-1, "  FFA_Bespin|  FFA_Deathstar|  FFA_Imperial|  FFA_NS_Hideout|  FFA_NS_Streets|  FFA_Raven|  FFA_Yavin|  CTF_Bespin|  CTF_Imperial|  CTF_NS_Streets|  CTF_Yavin|  Duel_Bay|  Duel_Jedi|  Duel_Pit|  Duel_Carbon| |Or custom map|  Jedi Council|  Country Academy|  Country Roads|  FFA_Koa|  NabooCity|  CloudCity")

;$mapffa_bespin = GUICtrlCreateRadio("FFA_Bespin", 30, 60, 100, 20)         ;Add options to map group                                       ;Make this option checked
;$mapffa_deathstar = GUICtrlCreateRadio("FFA_Deathstar", 30, 80, 100, 20)   ;Add options to map group
;$mapffa_imperial = GUICtrlCreateRadio("FFA_Imperial", 30, 100, 100, 20)    
;$mapffa_ns_hideout = GUICtrlCreateRadio("FFA_NS_Hideout", 30, 120, 100, 20)
;$mapffa_ns_streets = GUICtrlCreateRadio("FFA_NS_Streets", 30, 140, 100, 20)
;$mapffa_raven = GUICtrlCreateRadio("FFA_Raven", 30, 160, 100, 20)
;$mapffa_yavin = GUICtrlCreateRadio("FFA_Yavin", 30, 180, 100, 20)
;$mapctf_bespin = GUICtrlCreateRadio("CTF_Bespin", 150, 60, 100, 20)
;$mapctf_imperial = GUICtrlCreateRadio("CTF_Imperial", 150, 80, 100, 20)
;$mapctf_ns_streets = GUICtrlCreateRadio("CTF_NS_Streets", 150, 100, 100, 20)
;$mapctf_yavin = GUICtrlCreateRadio("CTF_Yavin", 150, 120, 100, 20)
;$mapduel_bay = GUICtrlCreateRadio("Duel_Bay", 150, 140, 100, 20)
;$mapduel_jedi = GUICtrlCreateRadio("Duel_Jedi", 150, 160, 100, 20)
;$mapduel_pit = GUICtrlCreateRadio("Duel_Pit", 150, 180, 100, 20)
;$mapduel_carbon = GUICtrlCreateRadio("Duel_Carbon", 150, 200, 100, 20)

GUICtrlCreateGroup("", -99, -99, 1, 1)                                      ;Close the map group
GUICtrlCreateGroup("Choose Gametype:", 190, 45, 120, 45)                    ;Create gtype group

$GUIGTYPE = GUICtrlCreateCombo("Choose gametype", 200, 60, 100, 20)
GUICtrlSetData(-1, "  FFA|  Holocron|  Jedimaster|  Duel|  TFFA|  CTF")

;$typeffa = GUICtrlCreateRadio("Free For All", 280, 60, 100, 20)                ;Add options to gtype group                                         ;Make this option checked
;$typeholo = GUICtrlCreateRadio("Holocron", 280, 80, 100, 20)               ;Add options to gtype group
;$typejedi = GUICtrlCreateRadio("Jedimaster", 280, 100, 100, 20)
;$typeduel = GUICtrlCreateRadio("Duel", 280, 120, 100, 20)
;$typetffa = GUICtrlCreateRadio("Team Free For All", 280, 140, 100, 20)
;$typectf = GUICtrlCreateRadio("Capture The Flag", 280, 160, 100, 20)

GUICtrlCreateGroup("", -99, -99, 1, 1)                                      ;Close the gtype group

$BTNPreview = GUICtrlCreateButton("&Preview", 125, 230, 100, 20)            ;Create preview button
GUICtrlSetTip(-1, "Show the options")                                       ;Tooltip for preview button
$BTNSend = GUICtrlCreateButton("&Send", 20, 230, 100, 20)                   ;Create send button
GUICtrlSetTip(-1, "Switch Map")                                             ;Tooltip for send button
GUICtrlSetState(-1,$GUI_DEFBUTTON)                                          ;Default button
$BTNExit = GUICtrlCreateButton("&Exit", 230, 230, 100, 20)                  ;Create exit button
GUICtrlSetTip(-1, "Exit the program")                                       ;Tooltip for exit button

GUICtrlCreateLabel("You should have JK2 running, and then open the console. After that you switch to this window with <ALT> + <TAB>. Select your options, and hit Send!", 10, 260, 400, 40)
GUICtrlCreateLabel("Version 1", 10, 300, 350)

GUICtrlCreateGroup("", -99, -99, 1, 1)                                      ;Close main group
AutoItSetOption("SendKeyDelay", 1)
; - - - Define actions beneath - - -

While 1
    $msg = GUIGetMsg()
    If $msg = $GUI_EVENT_CLOSE Then
        Exit
    EndIf
    Select
        Case $msg = $fileupdates
            MsgBox(64, "Updates..", "Updates since BETA Version 0.2 are:"& @CRLF & @CRLF & " - Added duel_carbon map" & @CRLF & " - Added the menues and menu items" & @CRLF & " - And added most of the parts in the menyitems" & @CRLF & " - Added #NoTrayIcon (= No tray icon :P)")
        Case $msg = $link1
            $IE1 = _IECreate()
            _IENavigate($IE1, "Http://clanapathy.13.forumer.com")
        Case $msg = $link2
            $IE2 = _IECreate()
            _IENavigate($IE2, "Http://www.autoitscript.com")
        Case $msg = $link3
            $IE3 = _IECreate()
            _IENavigate($IE3, "http://www.autoitscript.com/forum/index.php")
        Case $msg = $fileexit
            Exit
        Case $msg = $helpfile
            MsgBox(16, "Helpfile", "NOTE:" & @LF & "The helpfile is not avaliable yet.. If not in the next version, then it will be added in one of the following ones.. Please be patient :)" & @LF & @LF & "Thanks, Chobby..")
        Case $msg = $helpabout
            MsgBox(64, "About...", "I wrote this little program in AutoIt, 100% (Look in links).. The purpose of it is to help mainly new admins remember the admincommands like changing map (which is the first feature of this program, as well).. When more features are being added, it might be more useful for older admins as well :)" & @LF & @LF & "I would like, mainly to give credit to AutoIt and the creators behind that scripting-language.. Secondly, the persons who has been helping me with various stuff about the scripting and testing, should have my credit.. Besides those persons, I would like to thank the people that has been testing this program, and the people that are using it.. Also, I would like to thank (and give some focus) to the whole Clan Apathy clan :)" & @CRLF & @CRLF & "Created by <Ca>CHOBBY," & @CRLF & "MSN: Chobby_san@hotmail.com")
    EndSelect
    If  $msg = $BTNSend Then
    If GUICtrlRead($GUIGTYPE <> "Choose gametype" And _
                    GUICtrlRead($GUIMAP) <> "Choose default map" Then
                WinActivate("Jedi Knight Outcast: Jedi Knight 2 MP")
                WinWaitActive("Jedi Knight Outcast: Jedi Knight 2 MP", "", 10)
                Opt("SendKeyDelay", 1)
                Send("/" & GUICtrlRead($GUIGTYPE) & GUICtrlRead($GUIMAP))
            Else
                ContinueLoop
            EndIf
While 1
    If $msg = $BTNPreview Then
    If GUICtrlRead($GUIGTYPE) <> "Choose gametype" And _
                    GUICtrlRead($GUIMAP) <> "Choose default map" Then
                MsgBox(4096, "Map change preview", "Will change the map to" & _
                        GUICtrlRead($GUIGTYPE) & " in" & GUICtrlRead($GUIMAP))
            Else
                ContinueLoop
            EndIf
    EndIf
    Sleep(25)
WEnd

;===============================================================================
;
; Function Name:    _IECreate()
; Description:    Create an Internet Explorer Browser Window
; Parameter(s):  $f_visible         - 1 sets visible (default), 0 sets invisible
; Requirement(s):   AutoIt3 Beta with COM support (post 3.1.1)
; Return Value(s):  On Success - Returns an object variable pointing to a new InternetExplorer.Application object
;                  On Failure - 0  and sets @ERROR = 1
; Author(s):        Dale Hohm
;
;===============================================================================
;
Func _IECreate($f_visible = 1)
    $o_object = ObjCreate("InternetExplorer.Application")
    If IsObj($o_object) Then
        $o_object.visible = $f_visible
        SetError(0)
        Return $o_object
    Else
        SetError(1)
        Return 0
    EndIf
EndFunc  ;==>_IECreate
;===============================================================================
;
; Function Name:    _IENavigate()
; Description:      Directs an existing browser window to navigate to the specified URL
; Parameter(s):     $o_object       - InternetExplorer.Application, Window or Frame object
;                   $s_Url          - url to navigate to (e.g. "http://www.autoitscript.com")
;                   $f_wait         - 1 = wait for page load to complete before returning
;                                   - 0 = return immediately
; Requirement(s):   AutoIt3 Beta with COM support (post 3.1.1)
; Return Value(s):  On Success - Returns -1 (the Navigate method actually has no return value - all we know is that we tried)
;                  On Failure - 0  and sets @ERROR = 1
; Author(s):        Dale Hohm
;
;===============================================================================
;
Func _IENavigate($o_object, $s_url, $f_wait = 1)
    If IsObj($o_object) Then
        $o_object.navigate ($s_url)
        If ($f_wait = 1) Then _IELoadWait($o_object)
        SetError(0)
        Return -1
    Else
        SetError(1)
        Return 0
    EndIf
EndFunc  ;==>_IENavigate
Link to comment
Share on other sites

  • Moderators

Try this:

#NoTrayIcon
; Script Start
#include <GUIConstants.au3>
#include <Misc.au3>
#include <IE.au3>

Opt("SendKeyDelay", 1)

GUICreate("Ca Server Commands - By Chobby", 440, 320, 100, 100)            ;Create the GUI
$filemenu = GUICtrlCreateMenu("Files")
$fileupdates = GUICtrlCreateMenuitem("Updates", $filemenu)
$seperator2 = GUICtrlCreateMenuitem("", $filemenu)
$fileexit = GUICtrlCreateMenuitem("Exit", $filemenu)

$linkmenu = GUICtrlCreateMenu("Links")
$link1 = GUICtrlCreateMenuitem("Clan Apathy Forum", $linkmenu)
$seperator1 = GUICtrlCreateMenuitem("", $linkmenu)
$link2 = GUICtrlCreateMenuitem("AutoIt HP", $linkmenu)
$link3 = GUICtrlCreateMenuitem("AutoIt Forum", $linkmenu)

$helpmenu = GUICtrlCreateMenu("Help")
$helpfile = GUICtrlCreateMenuitem("Help...", $helpmenu)
$helpabout = GUICtrlCreateMenuitem("About", $helpmenu)

GUICtrlCreateLabel("For more information and/or more programs see www.ipshare.5gigs.com! (Soon up) ", 10, 10, 400);Add the main label

GUICtrlCreateGroup("Change Map:", 10, 30, 420, 225)                        ;Add main group
GUICtrlCreateGroup("Choose Map:", 20, 45, 160, 45)                         ;Add map group

$GUIMAP = GUICtrlCreateCombo("Choose default map", 30, 60, 140, 20)
GUICtrlSetData(-1, "  FFA_Bespin|  FFA_Deathstar|  FFA_Imperial|  FFA_NS_Hideout|  FFA_NS_Streets|  FFA_Raven|  FFA_Yavin|  CTF_Bespin|  CTF_Imperial|  CTF_NS_Streets|  CTF_Yavin|  Duel_Bay|  Duel_Jedi|  Duel_Pit|  Duel_Carbon| |Or custom map|  Jedi Council|  Country Academy|  Country Roads|  FFA_Koa|  NabooCity|  CloudCity")

;$mapffa_bespin = GUICtrlCreateRadio("FFA_Bespin", 30, 60, 100, 20)        ;Add options to map group                                       ;Make this option checked
;$mapffa_deathstar = GUICtrlCreateRadio("FFA_Deathstar", 30, 80, 100, 20)   ;Add options to map group
;$mapffa_imperial = GUICtrlCreateRadio("FFA_Imperial", 30, 100, 100, 20)
;$mapffa_ns_hideout = GUICtrlCreateRadio("FFA_NS_Hideout", 30, 120, 100, 20)
;$mapffa_ns_streets = GUICtrlCreateRadio("FFA_NS_Streets", 30, 140, 100, 20)
;$mapffa_raven = GUICtrlCreateRadio("FFA_Raven", 30, 160, 100, 20)
;$mapffa_yavin = GUICtrlCreateRadio("FFA_Yavin", 30, 180, 100, 20)
;$mapctf_bespin = GUICtrlCreateRadio("CTF_Bespin", 150, 60, 100, 20)
;$mapctf_imperial = GUICtrlCreateRadio("CTF_Imperial", 150, 80, 100, 20)
;$mapctf_ns_streets = GUICtrlCreateRadio("CTF_NS_Streets", 150, 100, 100, 20)
;$mapctf_yavin = GUICtrlCreateRadio("CTF_Yavin", 150, 120, 100, 20)
;$mapduel_bay = GUICtrlCreateRadio("Duel_Bay", 150, 140, 100, 20)
;$mapduel_jedi = GUICtrlCreateRadio("Duel_Jedi", 150, 160, 100, 20)
;$mapduel_pit = GUICtrlCreateRadio("Duel_Pit", 150, 180, 100, 20)
;$mapduel_carbon = GUICtrlCreateRadio("Duel_Carbon", 150, 200, 100, 20)

GUICtrlCreateGroup("", -99, -99, 1, 1)                                     ;Close the map group
GUICtrlCreateGroup("Choose Gametype:", 190, 45, 120, 45)                   ;Create gtype group

$GUIGTYPE = GUICtrlCreateCombo("Choose gametype", 200, 60, 100, 20)
GUICtrlSetData(-1, "  FFA|  Holocron|  Jedimaster|  Duel|  TFFA|  CTF")

;$typeffa = GUICtrlCreateRadio("Free For All", 280, 60, 100, 20)               ;Add options to gtype group                                         ;Make this option checked
;$typeholo = GUICtrlCreateRadio("Holocron", 280, 80, 100, 20)              ;Add options to gtype group
;$typejedi = GUICtrlCreateRadio("Jedimaster", 280, 100, 100, 20)
;$typeduel = GUICtrlCreateRadio("Duel", 280, 120, 100, 20)
;$typetffa = GUICtrlCreateRadio("Team Free For All", 280, 140, 100, 20)
;$typectf = GUICtrlCreateRadio("Capture The Flag", 280, 160, 100, 20)

GUICtrlCreateGroup("", -99, -99, 1, 1)                                     ;Close the gtype group

$BTNPreview = GUICtrlCreateButton("&Preview", 125, 230, 100, 20)           ;Create preview button
GUICtrlSetTip(-1, "Show the options")                                      ;Tooltip for preview button
$BTNSend = GUICtrlCreateButton("&Send", 20, 230, 100, 20)                  ;Create send button
GUICtrlSetTip(-1, "Switch Map")                                            ;Tooltip for send button
GUICtrlSetState(-1, $GUI_DEFBUTTON)                                        ;Default button
$BTNExit = GUICtrlCreateButton("&Exit", 230, 230, 100, 20)                 ;Create exit button
GUICtrlSetTip(-1, "Exit the program")                                      ;Tooltip for exit button

GUICtrlCreateLabel("You should have JK2 running, and then open the console. After that you switch to this window with <ALT> + <TAB>. Select your options, and hit Send!", 10, 260, 400, 40)
GUICtrlCreateLabel("Version 1", 10, 300, 350)

GUICtrlCreateGroup("", -99, -99, 1, 1)                                     ;Close main group
GUISetState(@SW_SHOW)
; - - - Define actions beneath - - -

While 1
    $msg = GUIGetMsg()
    Select
        Case $msg = $GUI_EVENT_CLOSE Or $msg = $BTNExit Or $msg = $fileexit
            Exit
        Case $msg = $fileupdates
            MsgBox(64, "Updates..", "Updates since BETA Version 0.2 are:" & @CRLF & @CRLF & " - Added duel_carbon map" & _
                    @CRLF & " - Added the menues and menu items" & @CRLF & " - And added most of the parts in the menyitems" & _
                    @CRLF & " - Added #NoTrayIcon (= No tray icon :P)")
        Case $msg = $link1
            $IE1 = _IECreate ()
            _IENavigate ($IE1, "Http://clanapathy.13.forumer.com", 0)
            $IE1 = 0
        Case $msg = $link2
            $IE2 = _IECreate ()
            _IENavigate ($IE2, "Http://www.autoitscript.com", 0)
            $IE2 = 0
        Case $msg = $link3
            $IE3 = _IECreate ()
            _IENavigate ($IE3, "http://www.autoitscript.com/forum/index.php", 0)
            $IE3 = 0
        Case $msg = $helpfile
            MsgBox(16, "Helpfile", "NOTE:" & @LF & "The helpfile is not avaliable yet.. If not in the next version, then it will be added in one of the following ones.. Please be patient :)" & @LF & @LF & "Thanks, Chobby..")
        Case $msg = $helpabout
            MsgBox(64, "About...", "I wrote this little program in AutoIt, 100% (Look in links).. The purpose of it is to help mainly new admins remember the admincommands like changing map (which is the first feature of this program, as well).. When more features are being added, it might be more useful for older admins as well :)" & _
                    @LF & @LF & "I would like, mainly to give credit to AutoIt and the creators behind that scripting-language.. Secondly, the persons who has been helping me with various stuff about the scripting and testing, should have my credit.. Besides those persons, I would like to thank the people that has been testing this program, and the people that are using it.. Also, I would like to thank (and give some focus) to the whole Clan Apathy clan :)" & _
                    @CRLF & @CRLF & "Created by <Ca>CHOBBY," & @CRLF & "MSN: Chobby_san@hotmail.com")
        Case $msg = $BTNSend
            If GUICtrlRead($GUIGTYPE) <> "Choose gametype" And _
                    GUICtrlRead($GUIMAP) <> "Choose default map" Then
                If WinExists("Jedi Knight Outcast: Jedi Knight 2 MP") Then
                    WinActivate("Jedi Knight Outcast: Jedi Knight 2 MP")
                    WinWaitActive("Jedi Knight Outcast: Jedi Knight 2 MP", "", 10)
                    Send("/" & GUICtrlRead($GUIGTYPE) & GUICtrlRead($GUIMAP))
                Else
                    MsgBox(48, "Error", "You don't have the game open."); you could start your game here
                EndIf
            Else
                ContinueLoop
            EndIf
        Case $msg = $BTNPreview
            If GUICtrlRead($GUIGTYPE) <> "Choose gametype" And _
                    GUICtrlRead($GUIMAP) <> "Choose default map" Then
                MsgBox(4096, "Map change preview", "Will change the map to" & _
                        GUICtrlRead($GUIGTYPE) & " in" & GUICtrlRead($GUIMAP))
            Else
                MsgBox(48, "Error", "You must select the options first.")
            EndIf
    EndSelect
WEnd
Link to comment
Share on other sites

Create an account or sign in to comment

You need to be a member in order to leave a comment

Create an account

Sign up for a new account in our community. It's easy!

Register a new account

Sign in

Already have an account? Sign in here.

Sign In Now
 Share

  • Recently Browsing   0 members

    • No registered users viewing this page.
×
×
  • Create New...