Comparing Numbers?

[huldu]

I was sitting here wondering, how do you compare multiple numbers with each others to see which is the biggest?

The idea is fairly simple, like: If $a > $b Then. But how does it look when you have multiple numbers?. For example...

$a = 10
$b = 4
$c = 65
$d = 43
$e = 19

Years ago we went thru this in school, but cant remember how it was done! I just remember the code was "fairly" simple when done right . I just cant do it right, thats the problem

First i would guess $a would be compared to existing numbers, $b->$e to see if its bigger then those... but just cant figure it out. Was hoping someone knew how it was done

[Thatsgreat2345]

eh whatever

Edited April 29, 2006 by thatsgreat2345

[SmOke_N]

I made a udf to do this:

http://www.autoitscript.com/forum/index.ph...ndpost&p=151083

Here is an example:

$a = 10
$b = 4
$c = 65
$d = 43
$e = 19
$avArray = StringSplit($a & ',' & $b & ',' & $c & ',' & $d & ',' & $e, ',')

ArraySortNum($avArray)
MsgBox(0, 'Example', 'Largest Number There Was: ' & $avArray[1] & @CR & 'Smallest Number There Was: ' & $avArray[5])

Func ArraySortNum(ByRef $nArray, $Ascending = 0, $Start = 1)
    For $i = $Start To UBound($nArray) - 2
        Local $SE = $i
        If $Ascending = 0 Then
            For $x = $i To UBound($nArray) - 1
                If Number($nArray[$SE]) < Number($nArray[$x]) Then $SE = $x
            Next
        Else
            For $x = $i To UBound($nArray) - 1
                If Number($nArray[$SE]) > Number($nArray[$x]) Then $SE = $x
            Next
        EndIf
        Local $HLD = $nArray[$i]
        $nArray[$i] = $nArray[$SE]
        $nArray[$SE] = $HLD
    Next
EndFunc

Edited April 29, 2006 by SmOke_N

[RazerM]

i just wrote something quickly (you beat me to it smoke)

Also remember that the For..Next statement($j) only goes up to 100 and won't work with larger numbers

MsgBox(0, @error, _Biggest("10,4,65,43,19"))

Func _Biggest($s_num)
    Dim $biggest[2]
    $biggest[0] = 0
    $i_num = StringSplit($s_num, ",")
    For $i = 1 To $i_num[0]
        For $j = 1 To 100
            If $i_num[$i] > $j And $j > $biggest[0] Then
                $biggest[0] = $j
                $biggest[1] = $i_num[$i]
            EndIf
        Next
    Next
    Return $biggest[1]
EndFunc

Edited April 29, 2006 by RazerM

[huldu]

The code smoke had was wonderful, just what i was looking for, thanks!

I ran into a new problem however

Im using Random to generate the numbers atm and i noticed that sometimes same number poped up. Is there a way to stop same numbers from appearing?. I kinda thought it started to get quite complicated atm, sorry about it.

I made this but cant get it to work properly atm

expandcollapse popup

While $loop = 0

    $a = Random(1,35,1)
    $b = Random(1,35,1)
    $c = Random(1,35,1)
    $d = Random(1,35,1)
    $e = Random(1,35,1)
    
    If $a = $b or $c or $d or $e Then 
        ToolTip("Error: " & $a & " : " & $b & " : " & $c & " : " & $d & " : " & $e, 0,0)
        Sleep(200)
        $loop = 0
    EndIf
    
    If $b = $a or $c or $d or $e Then
        ToolTip("Error: " & $a & " : " & $b & " : " & $c & " : " & $d & " : " & $e, 0,0)
        Sleep(200)
        $loop = 0
    EndIf

    If $c = $a or $b or $d or $e Then
        ToolTip("Error: " & $a & " : " & $b & " : " & $c & " : " & $d & " : " & $e, 0,0)
        Sleep(200)
        $loop = 0
    EndIf
    
    If $d = $a or $b or $c or $e Then
        ToolTip("Error: " & $a & " : " & $b & " : " & $c & " : " & $d & " : " & $e, 0,0)
        Sleep(200)
        $loop = 0
    EndIf
    If $e = $a or $b or $c or $d Then
        ToolTip("Error: " & $a & " : " & $b & " : " & $c & " : " & $d & " : " & $e, 0,0)
        Sleep(200)
        $loop = 0
    ElseIf
        $loop = 1
    EndIf
    
WEnd

I added the tooltip and sleep, just to see if the numbers really appeared more then once. The problem is most of the time they dont, and the script wont continue thru the loop.

Edited April 29, 2006 by huldu

[CyberSlug]

This is wrong

If $a = $b or $c or $d or $e Then

You must say

If $a = $b Or $$a = $c or $a = $d or $a = $e

$a = Random(1, 35, 1)

Do
  $b = Random(1, 35, 1)
Until $b <> $a

Do
  $c = Random(1, 35, 1) 
Until $c <> $a And $c <> $b 

Do
  $d = Random(1, 35, 1)
Until $d <> $c And $d <> $b And $d <> $a

MsgBox(0,"Numbers", $a & "," & $b & ", " & $c & ", " & $d)

It would be a lot easier to use arrays instead of separate variables....

; Initialize array of integers 1 to 35
Dim $numberSet[35]
For $i = 0 To 34
    $numberSet[$i] = $i + 1
Next

; Read elements randomly and put into new array
; Each time we decrease the index range...
Dim $resultSet[35]
For $i = 34 to 0 step -1
    $randIndex = Random(0, $i, 1)
    $resultSet[$i] = $numberSet[$randIndex]
    
; replace used number with highest unsed one
    $numberSet[$randIndex] = $numberSet[$i]
Next

; $resultSet and Output will contain all numbers 1 to 35 in random order (each occurs once)
$output = ""
For $i = 0 to 34
    $output = $output & $resultSet[$i] & ", "
Next
$output = StringTrimRight($output, 2)
MsgBox(4096,"", $output)