List users from Active Directory

[nobby]

Hi,

Pardon my ignorance:

I am trying to get a list of all users in a Domain (ADS). I only require the LoginName to be returned, no other information.

I have tried to make sense of some scripts I found on the forum, but I am having some difficulties in isolating the parts I need.

Any help would be most appreciated.

[Jos]

Untested but should be close:

Local $objCommand = ObjCreate("ADODB.Command")
Local $objConnection = ObjCreate("ADODB.Connection")
$objConnection.Provider = "ADsDSOObject"
$objConnection.Open ("Active Directory Provider")
$objCommand.ActiveConnection = $objConnection
Local $strBase = "<GC://dc=MyDom,dc=Inc>"
Local $strFilter = "(&(objectCategory=person)(objectClass=user)(sAMAccountName=*))"
Local $strAttributes = "cn,sAMAccountName,displayName,sn,distinguishedName"
Local $strQuery = $strBase & ";" & $strFilter & ";" & $strAttributes & ";subtree"
$objCommand.CommandText = $strQuery
$objCommand.Properties ("Page Size") = 100
$objCommand.Properties ("Timeout") = 30
$objCommand.Properties ("Cache Results") = False
$ADS_SCOPE_SUBTREE = 2
$objCommand.Properties ("searchscope") = $ADS_SCOPE_SUBTREE
Local $objRecordSet = $objCommand.Execute
While Not $objRecordSet.EOF
;~      $strName = $objRecordSet.Fields ("sAMAccountName").Value
;~      $strCN = $objRecordSet.Fields ("cn").value
;~      $strdisplayName = $objRecordSet.Fields ("displayName").value
;~      $strSN = $objRecordSet.Fields ("SN").value
;~      $strdistinguishedName = $objRecordSet.Fields ("distinguishedName").value
    FileWriteLine("Users.txt",$objRecordSet.Fields ("sAMAccountName").Value)
    $objRecordSet.MoveNext
WEnd
$objConnection.Close
$objConnection = ""
$objCommand = ""
$objRecordSet = ""

Edited June 19, 2006 by JdeB

[jftuga]

I tested the script and it works great! Nice work.

-John

[KilRoy]

you can also do a dsquery command with the -o samid option.

dsquery -o samid

Same basic ends, different means.

KilRoy

[nobby]

Thank you very much for your help.

[arcker]

jdeb method is the fastest way

i've used it so much in my script

it's an ADO search, the same as the search engine of the tool provided by AD

now, you can do a lot more with ado, or dsquery (but i prefer ADO)

list groups, users, OrganisationalUnit....users of a group

[ptrex]

@nobby

An other way of retrieving the data is using the MS LOGPARSER.

See second post : Look for Active Directory

Enjoy !!