IE.au3 LinkClick

[Zaxon]

I'm not sure if DaleHohm has considered this before or not:

I was writing a utility which made use of the fabulous ie.au3 library. I needed to click a link based on URL.

As it stands now, you need to manually iterate each link using _IELinkGetCollection, and then switch to _IELinkClickByIndex to make the click. It's an involved process, when comparised to _IELinkClickByText which does it all in one command.

It would be good if link clicks could be generalized. So throw away _IELinkClickByText, and replace it with:

_IELinkClickByType (or whatever you want to call it).

It could have the form:

_IELinkClickByType( ByRef $o_object, $s_linkString, $s_mode = "text" , [$f_wait = 1]] )

$s_linkString = the string to match

$s_mode = "text", "URL", etc.

I've bastardized the format of some already existing _IE commands, here. The concept being that you can cause a link click as easily base on URL (or any other relevant criteria) as you can now on text.

[big_daddy]

What would be the point of clicking a link by url? Why not just navigate to it.

[Zaxon]

What would be the point of clicking a link by url? Why not just navigate to it.

Easy. I have a tv site which I parse. On the TV guide page, it has links to individual page descriptions about episodes. Now, all description links contain a certain substring within a javascript URL. The link changes for every episode. However, there is always a substring that contains a unique string that I know about.

So, I need to be able to say, click on the link that contains "blah blah" in its URL.

And in case you're thinking that you can just calculating the URL, the site has referer blockers, so you HAVE to click to its pages from the main TV guide page. You can't go straight to its description pages.

[big_daddy]

Something like this?

#include <IE.au3>

$sURL = "www.google.com"
$oIE = _IECreate($sURL)

_IEClickLinkByURL($oIE, "services")

Func _IEClickLinkByURL(ByRef $o_object, $s_linkURL, $i_index = 0, $f_wait = 1)
    If Not IsObj($o_object) Then
        __IEErrorNotify ("Error", "_IELinkClickByURL", "$_IEStatus_InvalidDataType")
        SetError($_IEStatus_InvalidDataType, 1)
        Return 0
    EndIf
    
    Local $found = 0, $link, $linkURL, $links = $o_object.document.links
    $i_index = Number($i_index)
    For $link In $links
        $linkURL = $link.href
        If StringInStr($linkURL, $s_linkURL) Then
            If ($found = $i_index) Then
                $link.click
                If $f_wait Then
                    _IELoadWait($o_object)
                    SetError(@error)
                    Return -1
                EndIf
                SetError($_IEStatus_Success)
                Return -1
            EndIf
            $found = $found + 1
        EndIf
    Next
    __IEErrorNotify ("Warning", "_IELinkClickByURL", "$_IEStatus_NoMatch")
    SetError($_IEStatus_NoMatch) ; Could be caused by parameter 2, 3 or both
    Return 0
EndFunc   ;==>_IEClickLinkByURL

[DaleHohm]

I'll admit I've thought about this. There are a couple of functions that could be redesigned to make them more generic like this. In the end I based my decision on watching the usage pattern (based on questions in the forum and examples posted) and decided that the way those functions were designed today met the need and were easy to use -- I've gotten almost no questions about _IELinkClickByText and it is used in a large percentagte of scripts written with IE.au3.

As you mention, the functionality is readily available now by iterating through the links collection.

Thanks, but for now I choose to leave it as it is.

Dale