Help converting VBS to autoit

[copyleft]

Can anybody convert this visual basic script to autoit. (It basically deletes files older than 10 days from the indicated directory). Shortening the routine would also be greatly appreciated.

expandcollapse popup

'work in this folder
path = "G:\Image"

'delete files/folders older than 10 days
killdate = date() - 10

set fso = createobject("scripting.filesystemobject")

arFiles = array()
count = -1

SelectFiles path, killdate

dcount = 0
for each file in arFiles
  s = s & file.name & vbcrlf
  on error resume next
  file.delete true
  if err.number = 0 then dcount = dcount + 1
  err.clear
  on error goto 0
next

DeleteEmptyFolders path,false

'msgbox count+1 & " files found, " & dcount & " deleted."

sub SelectFiles(sPath, vKillDate)

  set folder = fso.getfolder(sPath)
  set files = folder.files

  for each file in files
    dtlastmodified = null
    on error resume Next
    dtlastmodified = file.datelastmodified
    on error goto 0
    if not isnull(dtlastmodified) Then
      if dtlastmodified < vKillDate then
        count = count + 1
        redim preserve arFiles(count)
        set arFiles(count) = file
      end if
    end if
  next

  for each fldr in folder.subfolders
    SelectFiles fldr.path, vKillDate
  next

end sub

sub DeleteEmptyFolders(sPath,bDeleteThisFolder)

  set folder = fso.getfolder(sPath)

  for each fldr in folder.subfolders
    DeleteEmptyFolders fldr.path,true
  next

  if (folder.files.count = 0) and _
     (folder.subfolders.count) = 0 and _
     bDeleteThisFolder then
    folder.delete
    exit sub
  end if

end sub

[Richard Robertson]

Older than 10 days? By that I assume you mean creation date?

[randallc]

Hi

Tyr the linked file;

Deleting old files

or modify JDEB's findfiles;

JDEB stuffor use other files in "recursive" link in my sig

Best, randall

Edited August 20, 2006 by randallc

[DaleHohm]

To get you started:

• Change set fso = createobject("scripting.filesystemobject") to $fso = ObjCreate("scripting.filesystemobject")
• start all of your variables with a '$' and don't use 'set'
• the rest of the syntax will be pretty similar

Give it a try, post your results and specific questions.

Dale

[JSThePatriot]

Also look for a VBScript to AutoIt Converter. There is one in the Scripts and Scraps section. I never seem to have the link handy either.

JS

[vim]

Also look for a VBScript to AutoIt Converter. There is one in the Scripts and Scraps section. I never seem to have the link handy either.

JS

Here it is:

http://www.autoitscript.com/forum/index.ph...ost&p=83650

[copyleft]

I tried the VBS converter. Didn't work for me. Will try the other suggestions. Thanks all.

Edited August 21, 2006 by copyleft