Is there a way to use website inside gui

[kcd-clan]

Is there some way to inergrade a website into gui

Well is their one aready done.

[Xenobiologist]

Hi,

check helpfile for _IECreateEmbedded

So long,

Mega

[ChrisL]

Is there some way to inergrade a website into gui

Well is their one aready done.

This used to be in the help file somewhere can't see it though at the minute so I picked it out of a script I have

expandcollapse popup

$o_ComError = ObjEvent("AutoIt.Error","Object_Error")
$oIE = ObjCreate("Shell.Explorer.2")

#include <GUIConstants.au3>
; Create a simple GUI for our output
GUICreate ( "Autoit", 800, 600,(@DesktopWidth-800)/2, (@DesktopHeight-600)/2 , $WS_OVERLAPPEDWINDOW + $WS_VISIBLE + $WS_CLIPSIBLINGS)
$GUIActiveX         = GUICtrlCreateObj      ( $oIE,      5, 40 , 790 , 360 )
$GUI_Button_Back    = GuiCtrlCreateButton   ("Back",     10, 420, 100,  30)
$GUI_Button_Forward = GuiCtrlCreateButton   ("Forward", 120, 420, 100,  30)
$GUI_Button_Home    = GuiCtrlCreateButton   ("Home",    230, 420, 100,  30)
$GUI_Button_Stop    = GuiCtrlCreateButton   ("Stop",    330, 420, 100,  30)


GuiCtrlSetFont (-1,14)
GUISetState ()    ;Show GUI

$oIE.navigate("http://www.AutoitScript.com")


While 1
    $msg = GUIGetMsg()
    
    Select
        Case $msg = $GUI_EVENT_CLOSE
            ExitLoop
        Case $msg = $GUI_Button_Home
            $oIE.navigate("http://www.AutoitScript.com")
        Case $msg = $GUI_Button_Back
            $oIE.GoBack
        Case $msg = $GUI_Button_Forward
            $oIE.GoForward
        Case $msg = $GUI_Button_Stop
            $oIE.Stop
        
        Case Else 
        ;
    EndSelect
    
Wend

GUIDelete ()
Exit

Func Object_Error() 
   msgbox(64, "Error", "Sorry can not process request")
   SetError(1); something to check for when this function returns 
Endfunc