window always on bottom

[theguy0000]

I know there is a way to make windows Always on Top, but How could I make a GUI always on bottom?

So that it's like it's part of the desktop, and it could never end up above another window, it is only shown when that section of the desktop is visible.

Sorry If the answer is obvious, but I searched the help file to no avail...

[Xenobiologist]

Hi,

you mean something like bginfo.exe does?

So long,

Mega

[theguy0000]

Hi,

you mean something like bginfo.exe does?

So long,

Mega

uhh may be asking something obvious here, but could I have a little more info on that..?

[SmOke_N]

Hmmm, I'm 99% sure I did a proof of Concept a long time ago with AnyGUI.au3 ... Can't remember what forum it was in though or for whom I did it.

Edit:

Found it... Is something like what you are looking for?

expandcollapse popup

#include <GUIConstants.au3>
;Functions used from AnyGUI v2.6 by Quaizywabbit


$DeskTop = ControlGetHandle('Program Manager', 'FolderView', 'SysListView321')
$C1 = _TargetaddCombo('', @DesktopWidth - 155, 65, 135, 20, Default, Default, $DeskTop)
GUICtrlSetData($C1[0], "It|is|possible|to|create|that|type|of|GUI")
GUISetState()
$B1 = _TargetaddButton("Example 1", @DesktopWidth - 80, 100, 60, 30, -1, -1, $DeskTop)
GUISetState()
$B2 = _TargetaddButton("Example 2", @DesktopWidth - 150, 100, 60, 30, -1, -1, $DeskTop)
GUISetState()

While WinExists($DeskTop)
    $msg = GUIGetMsg(1)
    Select
        Case $msg[0] = $B1[0]
            MsgBox(0, 'Example', 'This is just an example')
        Case $msg[0] = $B2[0]
            If MsgBox(4, 'Exit?', 'Would you like to exit?') = 6 Then Exit
    EndSelect
    Sleep(5)
WEnd

Func _TargetaddChild($text, $PosX, $PosY, $SizeX, $SizeY, $LocTargethWnd = 0);
    If not ($LocTargethWnd = 0) Then $TargethWnd = $LocTargethWnd
    Local $a = GUICreate($text, $SizeX, $SizeY, $PosX, $PosY, $WS_CHILD, -1, $TargethWnd)
    If $a = 0 Then SetError(1)
    Return $a
EndFunc   ;==>_TargetaddChild

Func _TargetaddCombo($text, $PosX, $PosY, $SizeX, $SizeY, $style = -1, $exstyle = -1, $LocTargethWnd = 0)
    If not ($LocTargethWnd = 0) Then $TargethWnd = $LocTargethWnd
    Local $a[3]
    $a[2] = _TargetaddChild($text, $PosX, $PosY, $SizeX, $SizeY, $TargethWnd)
    $a[0] = GUICtrlCreateCombo($text, 0, 0, $SizeX, $SizeY, $style, $exstyle)
    $a[1] = ControlGetHandle($a[2], "", $a[0])
    If $a[2] = 0 Or $a[0] = 0 Or $a[1] = "" Then
        SetError(1)
        Return 0
    Else
        Return $a
    EndIf
EndFunc   ;==>_TargetaddCombo

Func _TargetaddButton($text, $PosX, $PosY, $SizeX, $SizeY, $style = -1, $exstyle = -1, $LocTargethWnd = 0)
    If not ($LocTargethWnd = 0) Then $TargethWnd = $LocTargethWnd
    Local $a[3]
    $a[2] = _TargetaddChild($text, $PosX, $PosY, $SizeX, $SizeY, $TargethWnd)
    $a[0] = GUICtrlCreateButton($text, 0, 0, $SizeX, $SizeY, $style, $exstyle)
    $a[1] = ControlGetHandle($a[2], "", $a[0])
    If $a[2] = 0 Or $a[0] = 0 Or $a[1] = "" Then
        SetError(1)
        Return 0
    Else
        Return $a
    EndIf
EndFunc   ;==>_TargetaddButton

Edited October 8, 2006 by SmOke_N

[theguy0000]

Hmmm, I'm 99% sure I did a proof of Concept a long time ago with AnyGUI.au3 ... Can't remember what forum it was in though or for whom I did it.

Edit:

Found it... Is something like what you are looking for?

{KLIP!}

ya, that's great! thanks!

[theguy0000]

wait, no, how can I read a gui ctrl?

[SmOke_N]

I gave an example, look at how $B1 or $B2 are being noticed they are pressed.

[SmOke_N]

expandcollapse popup

#include <GUIConstants.au3>
;Functions used from AnyGUI v2.6 by Quaizywabbit


$DeskTop = ControlGetHandle('Program Manager', 'FolderView', 'SysListView321')
$C1 = _TargetaddCombo('', @DesktopWidth - 155, 65, 135, 20, Default, Default, $DeskTop)
GUICtrlSetData($C1[0], "It|is|possible|to|create|that|type|of|GUI")
GUISetState()
$B1 = _TargetaddButton("Example 1", @DesktopWidth - 80, 100, 60, 30, -1, -1, $DeskTop)
GUISetState()
$B2 = _TargetaddButton("Example 2", @DesktopWidth - 150, 100, 60, 30, -1, -1, $DeskTop)
GUISetState()

While WinExists($DeskTop)
    $msg = GUIGetMsg(1)
    Select
        Case $msg[0] = $B1[0]
            MsgBox(0, 'Example', 'This is just an example')
        Case $msg[0] = $B2[0]
            If GUICtrlRead($C1[0]) <> '' Then MsgBox(64, 'Info', GUICtrlRead($C1[0]))
            If MsgBox(4, 'Exit?', 'Would you like to exit?') = 6 Then Exit
    EndSelect
    Sleep(5)
WEnd

Func _TargetaddChild($text, $PosX, $PosY, $SizeX, $SizeY, $LocTargethWnd = 0);
    If not ($LocTargethWnd = 0) Then $TargethWnd = $LocTargethWnd
    Local $a = GUICreate($text, $SizeX, $SizeY, $PosX, $PosY, $WS_CHILD, -1, $TargethWnd)
    If $a = 0 Then SetError(1)
    Return $a
EndFunc   ;==>_TargetaddChild

Func _TargetaddCombo($text, $PosX, $PosY, $SizeX, $SizeY, $style = -1, $exstyle = -1, $LocTargethWnd = 0)
    If not ($LocTargethWnd = 0) Then $TargethWnd = $LocTargethWnd
    Local $a[3]
    $a[2] = _TargetaddChild($text, $PosX, $PosY, $SizeX, $SizeY, $TargethWnd)
    $a[0] = GUICtrlCreateCombo($text, 0, 0, $SizeX, $SizeY, $style, $exstyle)
    $a[1] = ControlGetHandle($a[2], "", $a[0])
    If $a[2] = 0 Or $a[0] = 0 Or $a[1] = "" Then
        SetError(1)
        Return 0
    Else
        Return $a
    EndIf
EndFunc   ;==>_TargetaddCombo

Func _TargetaddButton($text, $PosX, $PosY, $SizeX, $SizeY, $style = -1, $exstyle = -1, $LocTargethWnd = 0)
    If not ($LocTargethWnd = 0) Then $TargethWnd = $LocTargethWnd
    Local $a[3]
    $a[2] = _TargetaddChild($text, $PosX, $PosY, $SizeX, $SizeY, $TargethWnd)
    $a[0] = GUICtrlCreateButton($text, 0, 0, $SizeX, $SizeY, $style, $exstyle)
    $a[1] = ControlGetHandle($a[2], "", $a[0])
    If $a[2] = 0 Or $a[0] = 0 Or $a[1] = "" Then
        SetError(1)
        Return 0
    Else
        Return $a
    EndIf
EndFunc   ;==>_TargetaddButton

Look at $B2 and GUICtrlRead()

[theguy0000]

I gave an example, look at how $B1 or $B2 are being noticed they are pressed.

oh, ok :">

thanks