Stdout does not give results

[ptrex]

Maybe it's my lack of experience with stdout(), but I have several problems with it.

Let' start with this one :

#include <Constants.au3>

ReadInfo()

Func ReadInfo()
local $info
$info = Run("wmic csproduct","",@SW_HIDE,2); WMIC is the MS Commandline WMI solution

While 1
    $line = StdoutRead($Info)
    
    ConsoleWrite($line)
    If @error Then ExitLoop
Wend

EndFunc

No result is given

PS : The wmic runs only on XP and later.

Any hint

Thanks

ptrex

[ptrex]

@all

Just to let you know "wmic csproduct" is standard available in XP.

Just open CMD and run this command "wmic csproduct"

It will give you some output results.

But not in AutoIT so far ?! any idea why ?

[ptrex]

No help from no one.

Can at least someone confirm the same behaviour ?

I this a bug or a limitation of AutoIT or a script error ?

thanks

ptrex

Edited December 15, 2006 by ptrex

[jpm]

No help from no one.

Can at least someone confirm the same behaviour ?

I this a bug or a limitation of AutoIT or a script error ?

thanks

ptrex

I test your script same behavior here.

I try to launch with @comspec /c without any success.

I am as you I don't know why the StdoutRead doc example is working and not yours.

I need Valik or DaveF to jump in this analysis. :">

[ptrex]

I test your script same behavior here.

I try to launch with @comspec /c without any success.

I am as you I don't know why the StdoutRead doc example is working and not yours.

I need Valik or DaveF to jump in this analysis. :">

@Jpm

I have more example that don't work.

Try to use the Windows PowerShell cmdline tool.

The same results.

I am glad you responded !!

regards

ptrex

[jpm]

#include <Constants.au3>

$foo = Run(@ComSpec & " /c wmic csproduct", @SystemDir, @SW_HIDE, $STDERR_CHILD + $STDOUT_CHILD)

While 1
    $line = StdoutRead($foo)
    If @error Then ExitLoop
    MsgBox(0, "STDOUT read:", $line)
Wend

While 1
    $line = StderrRead($foo)
    If @error Then ExitLoop
    MsgBox(0, "STDERR read:", $line)
Wend

MsgBox(0, "Debug", "Exiting...")

That the test I did. Have a look.

The CMD does not end so I you run it from Scite and stop the debugging you will see a msgbox with the first line.

That's remain me a lot of discussion about some application not delivering the dtdout buffer before closing.

I don't remember if some go around as been found.

[ptrex]

Jpm

Thanks so far.

Let me kow if there was a solution found.

This would open up doors.

Because I intended to start using the MS PowerShell.

And this is has big potentials also for AutoIT !!

regards

ptrex

Edited December 15, 2006 by ptrex

[DaveF]

Looks like WMIC expects some kind of input if it's not being run by the shell, I fed it a CRLF and it worked OK for me:

Dim $pid, $ourOutput
     
  ; Open with connections to STDIN and STDOUT
     $pid = Run("wmic.exe csproduct", @SystemDir, @SW_HIDE, 3)
     
     StdinWrite($pid, @CRLF)
  ; Call with no string param to close STDIN
     StdinWrite($pid)
     
     While 1
         $ourOutput &= StdoutRead($pid)
         If @error Then ExitLoop
     WEnd
         
     MsgBox(0, "", $ourOutput)

[The Kandie Man]

Ptrex, when writing a program called MP3 to OGG, i noticed that all the command line encoders wrote to the $STDERR_CHILD stream. They just simply didn't write to the STDOUT stream even though they should have. I think this could very well be your problem.

Edited December 16, 2006 by The Kandie Man

[jpm]

Looks like WMIC expects some kind of input if it's not being run by the shell, I fed it a CRLF and it worked OK for me:

Dim $pid, $ourOutput
     
 ; Open with connections to STDIN and STDOUT
     $pid = Run("wmic.exe csproduct", @SystemDir, @SW_HIDE, 3)
     
     StdinWrite($pid, @CRLF)
 ; Call with no string param to close STDIN
     StdinWrite($pid)
     
     While 1
         $ourOutput &= StdoutRead($pid)
         If @error Then ExitLoop
     WEnd
         
     MsgBox(0, "", $ourOutput)

THanks DaveF,

That's exactly what Valik was mentioning in a discussion with JON. Some applications don't deliver output until they stopped.

I cannot remember if he was looking for a solution for those.

[ptrex]

@DaveF/Jpm

Thanks you guys !!!

This is the solution or workaround.

Now it even works with the MS Powershell.

You' ll be hearing more about this in the Example scripts.

regards

ptrex

Edited December 16, 2006 by ptrex

[jefhal]

Now it even works with the MS Powershell.

ptrex

Hi Ptrex- Can you show an example with PowerShell? Here's the PowerShell line that I'd like to collect inside of AutoIT:

Get-WmiObject win32_SystemEnclosure | select serialnumber

[jefhal]

And it works on a remote computer as well:

Dim $pid, $ourOutput
     
; Open with connections to STDIN and STDOUT
     $pid = Run("c:\windows\system32\WindowsPowerShell\v1.0\powershell.exe Get-WmiObject -computer mycomputer win32_SystemEnclosure | select serialnumber", @SystemDir, @SW_HIDE, 3)
     StdinWrite($pid, @CRLF)
; Call with no string param to close STDIN
     StdinWrite($pid)
     
     While 1
         $ourOutput &= StdoutRead($pid)
         If @error Then ExitLoop
     WEnd
         
     MsgBox(0, "", $ourOutput)

[ptrex]

@Jefhal

This is a working example that needs more refining.

#include <Constants.au3>

$Cmd = '$colItems = get-wmiobject -class "Win32_NetworkClient" -namespace "root\CIMV2" `'&@CR& _
       '-computername "." '&@CR& _
       'foreach ($objItem in $colItems)'&@CR& _
       '{write-host "Caption: " $objItem.Caption'&@CR& _
       'write-host "Description: " $objItem.Description'&@CR& _
       'write-host "Installation Date: " $objItem.InstallDate'&@CR& _
       '}'

; -noexit -noprofile -command help about_automatic_variables"

$PowerShell = Run('PowerShell.exe -command '&$Cmd, "", @SW_HIDE , _
                $STDERR_CHILD + $STDOUT_CHILD + $STDIN_CHILD)

StdinWrite($PowerShell,@CRLF) 
StdinWrite($PowerShell)

While 1
    $line = StdoutRead($PowerShell)
    If @error Then ExitLoop
    ;If $line <> "" Then
    ConsoleWrite($line)
    ;EndIf
Wend

While 1
    $line = StderrRead($PowerShell)
    If @error Then ExitLoop
    ConsoleWrite( "STDERR read: "& $line& @CR)
Wend

If you have something going post some examples in the Example Scripts section.

regards,

ptrex