A cmd-line tool made for Auto It

[Der_Andi]

Hi,

just a little gimmick

Enter non-UDF Autoit-commands into the input and see for yourself.

A variable already exists, so enter only that part of line, that would be behind the equals sign.

Example:

Enter: Asc("a")

Output: 97

It's only basic. Feel free to improve it.

Special control commands:

#exit --> ...

#cls --> clear screen

expandcollapse popup

#include <GuiConstants.au3>
#include <Process.au3>
#include <GuiEdit.au3>
Opt("GuiOnEventMode", 1)

GuiCreate("AutoIt CMD", 760, 460, -1, -1, -1, $WS_EX_TOOLWINDOW)
GUISetOnEvent($GUI_EVENT_CLOSE, "_quit")
GUISetBkColor(0x020060)
GUISetFont(9, 400, 0, "Tahoma")
$edit = GuiCtrlCreateEdit("AutoIt CMDbox" & @crlf & @CRLF, 10, 10, 740, 410, $ES_MULTILINE + $ES_READONLY + $ES_AUTOVSCROLL + $WS_VSCROLL)
GUICtrlSetBkColor(-1, 0x020060)
GUICtrlSetColor(-1, 0xFFFFFF)
GUICtrlCreateLabel("=", 10, 430, 10, 20, $SS_CENTERIMAGE)
GUICtrlSetColor(-1, 0xFFFFFF)
$input = GuiCtrlCreateInput("", 20, 430, 730, 20)
GUICtrlSetBkColor(-1, 0x020060)
GUICtrlSetColor(-1, 0xFFFFFF)
GUICtrlSetState(-1, $gui_focus)
$button = GUICtrlCreateButton("", 1, 1, 1, 1, $bs_defpushbutton)
GUICtrlSetState(-1, $gui_hide)
GUICtrlSetOnEvent(-1, "_cmd")

WinSetTrans("AutoIt CMDbox", "", 230)
GuiSetState()
While 1
    Sleep(1000)
WEnd

Func _cmd()
    $line = GUICtrlRead($input)
    If StringLen($line) > 0 Then
        If $line = "#exit" Then Exit
        If $line = "#cls" Then GUICtrlSetData($edit, "")
                
        GUICtrlSetData($edit, GUICtrlRead($edit) & GUICtrlRead($input))
        GUICtrlSetData($input, "")
        $file = FileOpen(@TempDir & "\autoit_cmd_temp.txt", 2)
        FileWriteLine($file, "#NoTrayIcon")
        FileWriteLine($file, '$log = FileOpen(@tempdir & "\autoit_cmd_log.txt", 2)')
        FileWriteLine($file, "$ret = " & $line)
        FileWriteLine($file, "If @error = 0 Then FileWriteLine($log, $ret)")
        FileWriteLine($file, "FileClose($log)")
        FileClose($file)
        FileMove(@TempDir & "\autoit_cmd_temp.txt", @TempDir & "\autoit_cmd_temp.au3", 1)
        _RunDOS(@TempDir & "\autoit_cmd_temp.au3")
        $result = FileReadLine(@tempdir & "\autoit_cmd_log.txt", 1)
        GUICtrlSetData($edit, GUICtrlRead($edit) & @CRLF & "--> " & $result & @CRLF & @CRLF)
        _GUICtrlEditLineScroll($edit, 0, _GUICtrlEditGetLineCount($edit))
    EndIf
EndFunc

Func _quit()
    Exit
EndFunc

[NELyon]

This shows promise, but instead of RunDOS(), look at the command /Au3ExecuteLine because this automatically assumes that the default option for using au3 files is "Run" and not "Edit"

[RazerM]

This shows promise, but instead of RunDOS(), look at the command /Au3ExecuteLine because this automatically assumes that the default option for using au3 files is "Run" and not "Edit"

I had the same problem, replace the _cmd func with this:

Func _cmd()
 $line = GUICtrlRead($input)
 If StringLen($line) > 0 Then
  If $line = "#exit" Then Exit
  If $line = "#cls" Then GUICtrlSetData($edit, "")

  GUICtrlSetData($edit, GUICtrlRead($edit) & GUICtrlRead($input))
  GUICtrlSetData($input, "")
  $file = FileOpen(@TempDir & "\autoit_cmd_temp.txt", 2)
  FileWriteLine($file, "#NoTrayIcon")
  FileWriteLine($file, '$log = FileOpen(@tempdir & "\autoit_cmd_log.txt", 2)')
  FileWriteLine($file, "$ret = " & $line)
  FileWriteLine($file, "If @error = 0 Then FileWriteLine($log, $ret)")
  FileWriteLine($file, "FileClose($log)")
  FileClose($file)
  FileMove(@TempDir & "\autoit_cmd_temp.txt", @TempDir & "\autoit_cmd_temp.au3", 1)
  $InstallDir = RegRead("HKEY_LOCAL_MACHINE\SOFTWARE\AutoIt v3\AutoIt", "InstallDir")
  RunWait($InstallDir & '\AutoIt3.exe "' & @TempDir & '\autoit_cmd_temp.au3"')
  $result = FileReadLine(@TempDir & "\autoit_cmd_log.txt", 1)
  GUICtrlSetData($edit, GUICtrlRead($edit) & @CRLF & "--> " & $result & @CRLF & @CRLF)
  _GUICtrlEditLineScroll($edit, 0, _GUICtrlEditGetLineCount($edit))
 EndIf
EndFunc   ;==>_cmd

Edited December 17, 2006 by RazerM