Find a line in a file

[BrettF]

Say i have a file with the lines:

a

b123

c

d234

e....

and i didnt know what line d234 was on. How would i find it?

[SmOke_N]

_FileReadToArray() + Loop + StringInString()

[BrettF]

Thanks.

[flyingboz]

Say i have a file with the lines:

by parsing the file, looking for the line. (duh)

One method (pseudocode / untested / no error checking) uses FileRead,StringInStr,StringLeft,and StringReplace

$contents = FileRead($filename,filegetsize($filename))
$line = "this is a matching line"
$line_delimiter = @CRLF
$match = StringInStr($contents,$line) 
If Not $match then 
    exit 0
else
  StringReplace(StringLeft($contents,$line),$line_delimiter,"")
  exit @extended
endif

Edited January 15, 2007 by flyingboz

[GEOSoft]

If you are going to #include <array.au3>

Then also take a look at the _Array Search() function

[SmOke_N]

This may make it simple... the _ArrayDisplay2d is just to show you, isn't needed for the function.

Input the file to search, the string to find, and 1 in the $iCase parameter if you want the search case sensitive.

It will return a 2 dimensional array, the [0] will contain the line number found, and the [1] will display the actual line itself.

CODE

expandcollapse popup

$a = _StringReturnLine('somefile.txt', 'some text')
_ArrayDisplay2d($a)

Func _StringReturnLine($hFile, $sFind, $iCase = 0)
    If Not FileExists($hFile) Then Return SetError(1, 0, 0)
    Local $aSplit = StringSplit(StringStripCR(FileRead($hFile)), @LF)
    If @error Then Return SetError(2, 0, 0)
    Local $sHoldLineNum, $sHoldLineStr
    For $iCC = 1 To UBound($aSplit) - 1
        If StringInStr($aSplit[$iCC], $sFind, $iCase) Then
            $sHoldLineNum &= $iCC & Chr(1)
            $sHoldLineStr &= $aSplit[$iCC] & Chr(1)
        EndIf
    Next
    If Not $sHoldLineNum Then Return SetError(3, 0, '')
    $sHoldLineNum = StringSplit(StringTrimRight($sHoldLineNum, 1), Chr(1))
    $sHoldLineStr = StringSplit(StringTrimRight($sHoldLineStr, 1), Chr(1))
    Local $aReturnArray[UBound($sHoldLineNum)][2]
    $aReturnArray[0][0] = UBound($sHoldLineNum) - 1
    For $iCC = 1 To UBound($sHoldLineNum) - 1
        $aReturnArray[$iCC][0] = $sHoldLineNum[$iCC]
        $aReturnArray[$iCC][1] = $sHoldLineStr[$iCC]
    Next
    Return $aReturnArray
EndFunc


Func _ArrayDisplay2D($aArray, $sTitle = 'Array Display 2Dim', $iBase = 1, $sToConsole = 0)
    If Not IsArray($aArray) Then Return SetError(1, 0, 0)
    Local $sHold = 'Dimension 1 Has:  ' & UBound($aArray, 1) -1 & ' Element(s)' & @LF & _
            'Dimension 2 Has:  ' & UBound($aArray, 2) - 1 & ' Element(s)' & @LF & @LF
    For $iCC = $iBase To UBound($aArray, 1) - 1
        For $xCC = 0 To UBound($aArray, 2) - 1
            $sHold &= '[' & $iCC & '][' & $xCC & ']  = ' & $aArray[$iCC][$xCC] & @LF
        Next
    Next
    If $sToConsole Then Return ConsoleWrite(@LF & $sHold)
    Return MsgBox(262144, $sTitle, StringTrimRight($sHold, 1))
EndFunc

[BrettF]

Thanks. I'll see wich one works way works best and which one is the simpilist to read (so i understand it )