_INetGetSource with Cookie or any other header

[mary]

Please, if you have an exemple with cookie session autentification using _INetGetSource, let as know. I try this UDF but no succeed

here is my exemple:

#include <INet.au3>

$url="http://www.awebservice.com?"
$Data_to_Post="abc=10&id=12"


$My_valid_cookies_session="Cookie:UserId=aeerehgftreuusffe12ehggf" 

; this cookie is obtened by Live Http Headers (Firefox) ;and it work great with Curl or Wget

$html_source_reponse = _INetGetSource($url & $Data_to_Post, $My_valid_cookies_session)

consolewrite($html_source_reponse )

please what is wrong in my code ? (user agent or any other header item is not necessary ! only Cookie)

thinks a lot

Edited January 28, 2007 by mary

[/dev/null]

Please, if you have an exemple with cookie session autentification using _INetGetSource, let as know. I try this UDF but no succeed

here is my exemple:

$html_source_reponse = _INetGetSource($url & $Data_to_Post, $My_valid_cookies_session)

please what is wrong in my code ? (user agent or any other header item is not necessary ! only Cookie)

thinks a lot

did you read the help file for _INetGetSource?

There is no way to POST data and there is NO second parameter (which you believe to be the Cookie), at least

in my version of the help file....

You need to use the IE Automation commands (_IExyz). See help file samples.....

[mary]

did you read the help file for _INetGetSource?

There is no way to POST data and there is NO second parameter (which you believe to be the Cookie), at least

in my version of the help file....

You need to use the IE Automation commands (_IExyz). See help file samples.....

no, no...look at INET.AU udf, the prototype of _inetgetsource is :

Func _InetGetSource($url, $headers='')

balabla


EndFun

The autor of this func is Wouter (?), so may be he forgot to add some thing in help file

[mary]

Here Wouter code, $s_Header argument is missed in help file !

Func _INetGetSource($s_URL, $s_Header = '')
    Local $h_DLL = DllOpen("wininet.dll"), $ai_IO, $ai_IOU, $ai_ICH, $ai_IRF[5] = [0, 0, '', 0, 1], $s_Buf = ''
    $ai_IO = DllCall($h_DLL, 'int', 'InternetOpen', 'str', "AutoIt v3", 'int', 0, 'str', '', 'str', '', 'int', 0)
    If @error Or $ai_IO[0] = 0 Then
        DllClose($h_DLL)
        SetError(1)
        Return 0
    EndIf
    $ai_IOU = DllCall($h_DLL, 'int', 'InternetOpenUrl', 'int', $ai_IO[0], 'str', $s_URL, 'str', $s_Header, 'int', StringLen($s_Header), 'int', 0x80000000, 'int', 0)
    If @error Or $ai_IOU[0] = 0 Then
        DllCall($h_DLL, 'int', 'InternetCloseHandle', 'int', $ai_IO[0])
        DllClose($h_DLL)
        SetError(1)
        Return 0
    EndIf
    Local $v_Struct = DllStructCreate ('udword')
    While $ai_IRF[4] <> 0
        $s_Buf &= StringMid($ai_IRF[2], 1, $ai_IRF[4])
        $ai_IRF = DllCall($h_DLL, 'int', 'InternetReadFile', 'int', $ai_IOU[0], 'str', "", 'int', 256, 'ptr', DllStructGetPtr ($v_Struct, 1))
        $ai_IRF[4] = DllStructGetData ($v_Struct, 1)
    WEnd
    DllStructDelete ($v_Struct)
    DllCall($h_DLL, 'int', 'InternetCloseHandle', 'int', $ai_IOU[0])
    DllCall($h_DLL, 'int', 'InternetCloseHandle', 'int', $ai_IO[0])
    DllClose($h_DLL)
    Return StringTrimRight($s_Buf, 1)
EndFunc;==>_INetGetSource

Edited January 30, 2007 by mary

[AzKay]

Try this.

$oHTTP = ObjCreate("winhttp.winhttprequest.5.1")
$oHTTP.Open("POST", "http://www.awebservice.com?", true)
$oHTTP.SetRequestHeader("Cookie:", "UserId=aeerehgftreuusffe12ehggf")
$oHTTP.SetRequestHeader("Content-Length", StringLen("abc=10&id=12"))
$oHTTP.Send("abc=10&id=12")
ConsoleWrite($oHTTP.ResponseText & @CRLF)

[mary]

Try this.

$oHTTP = ObjCreate("winhttp.winhttprequest.5.1")
$oHTTP.Open("POST", "http://www.awebservice.com?", true)
$oHTTP.SetRequestHeader("Cookie:", "UserId=aeerehgftreuusffe12ehggf")
$oHTTP.SetRequestHeader("Content-Length", StringLen("abc=10&id=12"))
$oHTTP.Send("abc=10&id=12")
ConsoleWrite($oHTTP.ResponseText & @CRLF)

thinks, I know that way. But my goal is to use dllcall without com issues. so my question is how to do same think with Wouter code (_inetGetsource) ?

[AzKay]

Good luck. My way still wins ;3

[mary]

Good luck. My way still wins ;3

no dout but dllcall solution (_inetgetsource) is more rapid and no COM error

[DaleHohm]

You may know this, but it is easy to trap COM errors. Here is how I handle it in IE.au3:

$oIEErrorHandler = ObjEvent("AutoIt.Error", "__IEInternalErrorHandler")

Func __IEInternalErrorHandler()
    $IEComErrorScriptline = $oIEErrorHandler.scriptline
    $IEComErrorNumber = $oIEErrorHandler.number
    $IEComErrorNumberHex = Hex($oIEErrorHandler.number, 8)
    $IEComErrorDescription = StringStripWS($oIEErrorHandler.description, 2)
    $IEComErrorWinDescription = StringStripWS($oIEErrorHandler.WinDescription, 2)
    $IEComErrorSource = $oIEErrorHandler.Source
    $IEComErrorHelpFile = $oIEErrorHandler.HelpFile
    $IEComErrorHelpContext = $oIEErrorHandler.HelpContext
    $IEComErrorLastDllError = $oIEErrorHandler.LastDllError
    $IEComErrorOutput = ""
    $IEComErrorOutput &= "--> COM Error Encountered in " & @ScriptName & @CR
    $IEComErrorOutput &= "----> $IEComErrorScriptline = " & $IEComErrorScriptline & @CR
    $IEComErrorOutput &= "----> $IEComErrorNumberHex = " & $IEComErrorNumberHex & @CR
    $IEComErrorOutput &= "----> $IEComErrorNumber = " & $IEComErrorNumber & @CR
    $IEComErrorOutput &= "----> $IEComErrorWinDescription = " & $IEComErrorWinDescription & @CR
    $IEComErrorOutput &= "----> $IEComErrorDescription = " & $IEComErrorDescription & @CR
    $IEComErrorOutput &= "----> $IEComErrorSource = " & $IEComErrorSource & @CR
    $IEComErrorOutput &= "----> $IEComErrorHelpFile = " & $IEComErrorHelpFile & @CR
    $IEComErrorOutput &= "----> $IEComErrorHelpContext = " & $IEComErrorHelpContext & @CR
    $IEComErrorOutput &= "----> $IEComErrorLastDllError = " & $IEComErrorLastDllError & @CR
    If $_IEErrorNotify Or $__IEAU3Debug Then ConsoleWrite($IEComErrorOutput & @CR)
    SetError($_IEStatus_ComError)
    Return
EndFunc   ;==>__IEInternalErrorHandler

[mary]

Right Dale ! your code is clean and handle well com error.

As I told, my question only technical (about using DllCall Like W0uter _InetGetSource ).

I asked about DllCall because it is more rapid to send a Get HTTP Request (millisecondes is very very important for the goal of my project !!! )

Thinks for all