Tab within a Tab

[JohnBailey]

I want to do a tab inside of a tab. So, I want one tab that takes the user to one place while allowing for child/sub tabs. How do I do this action? I tried it and it doesn't seem to work

[Valuater]

per help

ONLY one Tab control can be created by window. But a script can creates several windows having a tab in.

so, you can create child windows to do what you want

8)

[Xenobiologist]

Hi,

expandcollapse popup

#include <GUIConstants.au3>

$Main_Gui = GUICreate("My GUI Tab", 500, 500)  ; will create a dialog box that when displayed is centered
$Child_Gui = GUICreate("Child Gui", 480, 460, 15, 35, BitOR($WS_CHILD, $WS_TABSTOP), -1, $Main_Gui)

$child_tab = GUICtrlCreateTab(10, 10, 470, 450)
$c_tab0 = GUICtrlCreateTabItem("c_tab0")
$button = GUICtrlCreateButton("test button", 20, 40, 120, 25)
$c_tab1 = GUICtrlCreateTabItem("c_tab1")
GUICtrlCreateTabItem("")   ; end tabitem definition

GUISwitch($Main_Gui)

GUISetBkColor(0x00E0FFFF)
GUISetFont(9, 300)

$tab = GUICtrlCreateTab(10, 10, 490, 490)

$tab0 = GUICtrlCreateTabItem("tab0")
GUICtrlCreateLabel("label0", 30, 80, 50, 20)
$tab0OK = GUICtrlCreateButton("OK0", 20, 50, 50, 20)
$tab0input = GUICtrlCreateInput("default", 80, 50, 70, 20)

$tab1 = GUICtrlCreateTabItem("tab----1")
GUICtrlCreateLabel("label1", 30, 80, 50, 20)
$tab1combo = GUICtrlCreateCombo("", 20, 50, 60, 120)
GUICtrlSetData(-1, "Trids|CyberSlug|Larry|Jon|Tylo", "Jon") ; default Jon
$tab1OK = GUICtrlCreateButton("OK1", 80, 50, 50, 20)

$tab2 = GUICtrlCreateTabItem("tab2")
GUICtrlSetState(-1, $GUI_SHOW)   ; will be display first
GUICtrlCreateLabel("label2", 30, 80, 50, 20)
$tab2OK = GUICtrlCreateButton("OK2", 140, 50, 50)

$tab3 = GUICtrlCreateTabItem("tab3")

GUICtrlCreateTabItem("")   ; end tabitem definition


GUISetState()

; Run the GUI until the dialog is closed
While 1
    $msg = GUIGetMsg()
    Select
        Case $msg = $GUI_EVENT_CLOSE
            ExitLoop
        Case $msg = $tab
            If GUICtrlRead($tab) = 3 Then
                GUISetState(@SW_SHOW, $Child_Gui)
            Else
                GUISetState(@SW_HIDE, $Child_Gui)
            EndIf
    EndSelect
   
WEnd

So long,

Mega

P.S.: See Tab 3

[Valuater]

Nice one, Mega!!

8)

[Xenobiologist]

Nice one, Mega!!

8)

Hi,

Thanks! Did that a while ago for somebody in the German Forum.

So long,

Mega

[JohnBailey]

th.meger AWESOME! Thank you! I was disappoint that I could do what you did! I'm going to look through the script and figure out how you did everything. I really appreciate it! Learning time --->>