Help with Checking & Arrays

[acidfear]

I'm stuck on a problem :/

I'm writing a program that writes to the registry.

I have checkboxes for each type of reg key there is (string, binary,dword etc..)

I am stuck on how to check every checkbox for the checked one. I would assume using arrays would work, but I haven't been able to figure it out.

Here the array code I used.

$check1 - $check2 etc... are the gui checkbox labels

for $x  = 1 to 5  step 1
              if $check($x) = $gui_checked then
                       $valid = $check($x)
              else
                     etc...
              endif
next

When i try to use $valid as the key type in regwrite, it doesn't seem to work. Could it be because in the array $check($x) isn't being read as $check1 etc..?

Thanks in adv.

Edited February 6, 2007 by acidfear

[Xenobiologist]

Hi,

maybe you forgot GuiCtrlRead(variable) = $gui_Checked ...

So long,

Mega

[McGod]

All the checkbox's are in an array, and the button will loop the array to check the stats.

Note: GUICtrlRead ( $checkboxes[$i], 1 ) just grabs the name.

#include <GUIConstants.au3>
Dim $checkboxes[4]

#Region ### START Koda GUI section ### Form=
$Form1 = GUICreate("Checkbox Check", 315, 310, 193, 115)
$Checkboxes[0] = GUICtrlCreateCheckbox("ACheckbox1", 104, 72, 97, 17)
$Checkboxes[1] = GUICtrlCreateCheckbox("ACheckbox2", 104, 104, 97, 17)
$Checkboxes[2] = GUICtrlCreateCheckbox("ACheckbox3", 104, 136, 97, 17)
$Checkboxes[3] = GUICtrlCreateCheckbox("ACheckbox4", 104, 168, 97, 17)
$Button1 = GUICtrlCreateButton("Check states", 104, 192, 105, 25, 0)
GUISetState(@SW_SHOW)
#EndRegion ### END Koda GUI section ###

While 1
    $nMsg = GUIGetMsg()
    Switch $nMsg
        Case $GUI_EVENT_CLOSE
            Exit
        Case $Button1
            For $i = 0 To UBound ( $checkboxes ) - 1 Step 1
                If GUICtrlRead ( $checkboxes[$i] ) = $GUI_CHECKED Then
                    MsgBox ( 1, GUICtrlRead ( $checkboxes[$i], 1 ), "This checkbox is checked." )
                Else
                    MsgBox ( 1, GUICtrlRead ( $checkboxes[$i], 1 ), "This checkbox is not checked." )
                EndIf
            Next
    EndSwitch
WEnd

[BrettF]

IF BitAnd(GUICtrlRead($Item),$GUI_CHECKED) = $GUI_CHECKED Then

Edit: I think that works...

Edited February 6, 2007 by bert

[acidfear]

Awesome! I forgot about the method chip gave. Works just the way I had in mind.

Thanks all for the help!!