*Updated* Mouse coordinates

[XxSunxX]

Allo. Can anyone help me with a script that tells me my mouse coordinates. I would like something that as I move my mouse it shows my current mouse coordinates. I would like it to be either two ways.

- A box appears at my mouse cursor and as I move my cursor text in the box has something like x=? y=?

- Text in a GUI changes as I move my cursor telling me my coordinates.

I would like choice two the most.

Could someone please help me out?

Thanks.

[/dev/null]

Here is something to get you started.

; This will create a tooltip in the upper left of the screen

HotKeySet("{ESC}","TheEnd")

While 1
    $pos = MouseGetPos()
    ToolTip("x = " & $pos[0] & " y = " & $pos[1], $pos[0]+5, $pos[1]+5)
    Sleep(100)  ; Sleep to give tooltip time to display
WEnd
    
Func TheEnd()
    Exit
EndFunc

[4gotn1]

dam my comp went dumb and dev beat me to it but here's what i did

Dim $Mouse
HotKeySet("{F5}", "_Terminate")

While 1
    $Mouse = MouseGetPos()
    TrayTip("", "X: "& $Mouse[0] & "  Y: "& $Mouse[1], 0)
    ;or you could do
    ;ToolTip("X: "& $Mouse[0] &"  Y: "& $Mouse[1], $Mouse[0] + 10, $Mouse[1] + 10)
    Sleep(20)
WEnd

Func _Terminate()
    Exit
EndFunc ;==> _Terminate()

[XxSunxX]

#include <GUIConstants.au3>

#Region ### START Koda GUI section ### Form=
$Form1 = GUICreate("MCF Requested Version", 148, 50, 469, 469, -1, BitOR($WS_EX_TOOLWINDOW,$WS_EX_WINDOWEDGE))
GUISetBkColor(0x335EA8)
$Button1 = GUICtrlCreateButton("Start", 0, 0, 147, 25, 0)
$Button2 = GUICtrlCreateButton("Stop", 0, 24, 147, 25, 0)
GUISetState(@SW_SHOW)
#EndRegion ### END Koda GUI section ###

While 1
    $nMsg = GUIGetMsg()
    Switch $nMsg
        Case $GUI_EVENT_CLOSE
        Case $Button2
        Exit
        Case $Button1
        While 1
    $pos = MouseGetPos()
    ToolTip("x = " & $pos[0] & " y = " & $pos[1], $pos[0]+5, $pos[1]+5)
WEnd
    Case $Button2
        Exit
Func TheEnd()
    Exit
EndFunc
            Exit

    EndSwitch
WEnd

When I click start it does what I want, but when I click stop it doesnt stop. Help please.

[/dev/null]

When I click start it does what I want, but when I click stop it doesnt stop. Help please.

You are sure you don't get syntax errors when you run that script????

Try this:

#include <GUIConstants.au3>

#Region ### START Koda GUI section ### Form=
$Form1 = GUICreate("MCF Requested Version", 148, 50, 469, 469, -1, BitOR($WS_EX_TOOLWINDOW, $WS_EX_WINDOWEDGE))
GUISetBkColor(0x335EA8)
$Button1 = GUICtrlCreateButton("Start", 0, 0, 147, 25, 0)
$Button2 = GUICtrlCreateButton("Stop", 0, 24, 147, 25, 0)
GUISetState(@SW_SHOW)
#EndRegion ### END Koda GUI section ###

While 1
    $nMsg = GUIGetMsg()
    Switch $nMsg
        Case $GUI_EVENT_CLOSE
            Exit
        Case $Button2
            AdlibDisable()
            ToolTip("")
            
        Case $Button1
            AdlibEnable("_ShowMousePos",150)
    EndSwitch
WEnd

Func _ShowMousePos()
    $pos = MouseGetPos()
    ToolTip("x = " & $pos[0] & " y = " & $pos[1], $pos[0] + 5, $pos[1] + 5)
EndFunc