IE.au3, possible to know if a button was clicked on a embedded page?

[Will66]

Using IE.au3 to embed and load a local html file from my hard drive in a gui using _IECreateEmbedded ().

I have setup some buttons in the html file that perform various functions.

Is it possible to return to autoit script if a button was clicked and which button?

basically i guess, how can i listen for events.

Edited February 11, 2007 by Will66

[DaleHohm]

Yes, using the AutoIt ObjEvent function. There is nothing in IE.au3 to help you with this specifically, but you do need object references to the button and IE.au3 ca help with that.

Here is a template to get you started:

$oEvent1 = ObjEvent( $oButton1, "Button1_")

Func Button1_onclick()

;do what you want to in here...

EndFunc

Dale

[Will66]

Ok, that gives me some clues thanx. I'm looking at the ObjEvent helpfile but it doesn't show anything useful outside the _IE standard functions.

html "test.html":

<input type="button" name="clicker" value="click me">

autoit:

#include <GUIConstants.au3>
#include <IE.au3>
$Editor=@ScriptDir & "\test.html"

_IEErrorHandlerRegister ()
$oIE = _IECreateEmbedded ()
GUICreate("Embedded Web control Test", 640, 580, (@DesktopWidth - 640) / 2, (@DesktopHeight - 580) / 2, $WS_OVERLAPPEDWINDOW + $WS_VISIBLE + $WS_CLIPSIBLINGS)
$GUIActiveX = GUICtrlCreateObj($oIE, 10, 40, 300, 470)
GUISetState()
$event = _IENavigate ($oIE, $Editor)
While 1
    $msg = GUIGetMsg()
    Select
        Case $msg = $GUI_EVENT_CLOSE
            ExitLoop
        ;Case $event > 0
            ;MsgBox(0,"",$event)
    EndSelect
WEnd

GUIDelete()

Exit

[Will66]

Got it!

Thankyou for your help, i'd never have found it. Cheers.

#include <GUIConstants.au3>
#include <IE.au3>
$Editor=@ScriptDir & "\test.html"

_IEErrorHandlerRegister ()
$oIE = _IECreateEmbedded ()
GUICreate("Embedded Web control Test", 640, 580, (@DesktopWidth - 640) / 2, (@DesktopHeight - 580) / 2, $WS_OVERLAPPEDWINDOW + $WS_VISIBLE + $WS_CLIPSIBLINGS)
$GUIActiveX = GUICtrlCreateObj($oIE, 10, 40, 300, 470)
GUISetState()
$event = _IENavigate ($oIE, $Editor)

$oButton1 = _IEGetObjByName ($oIE, "clicker")


$oEvent1 = ObjEvent( $oButton1, "Button1_")
;$SinkObject=ObjEvent($oIE,"IEEvent_","DWebBrowserEvents2") 
While 1
    $msg = GUIGetMsg()
    Select
        Case $msg = $GUI_EVENT_CLOSE
            ExitLoop
        ;Case $SinkObject
            ;MsgBox(0,"",$SinkObject)
    EndSelect
WEnd

GUIDelete()

Exit



Func Button1_onclick()
MsgBox(0,"","test")
EndFunc