2x Splashscreen

[DaLiMan]

I know it's not possible to have 2 Splash-screens opened at once in the same script.

But I was wondering if someone already has a nice workaround for this by for example creating a second script for the second Splash and then starting and exiting this script by the first one?

Or does anyone have a nice idea of putting this together?

[CyberSlug]

You could also use the beta versions of AutoIt that include GUI support. Create a GUI window for one of the splash screens.....

Might post an implementation if I get time...

[DaLiMan]

Nice idea, didn't think of that.

But how to get the GUI to be always on top and not disturbing the rest of the process?

[DaLiMan]

Found a little option like this:

Code1

IniWrite("P:\Splash.ini", "Splash", "Running", "Y")

SplashTextOn("Title", "Message goes here.", -1, -1, -1, -1, 4, "", 24)
Run("P:\Test\TestScripts\Splash2.exe")
Sleep(3000)

IniWrite("P:\Splash.ini", "Splash", "Running", "N")
SplashOff()

Code2

Dim $Run = "Y"

While $Run = "Y"
$Run = IniRead("P:\Splash.ini", "Splash", "Running", "")
SplashImageOn("SpIm", "C:\Solar.bmp", "50", "50", "10", "10")
Wend

Not very nice, but useable.

[ezzetabi]

What about using a external compiled Autoit script that only shows Splashscreens?

You file install them as many time you need.

[DaLiMan]

Sorry, second code should be:

Code2

Dim $Run = "Y"
SplashImageOn("SpIm", "C:\Solar.bmp", "82", "76", "100", "-1")

While $Run = "Y"
   $Run = IniRead("P:\Splash.ini", "Splash", "Running", "Y")
Wend

Exit

Otherwise it's flashing all the time.... :">

[pekster]

What about using a external compiled Autoit script that only shows Splashscreens?

You file install them as many time you need.

<{POST_SNAPBACK}>

It might be eaisier to use command line options so you don't need to bother with installed files, cleanup, etc.

Just have the script call itself (a 2nd instance) with special paramaters so that it displays a specific splash screen instead of the "main" body of the script.

[DaLiMan]

Just have the script call itself (a 2nd instance) with special paramaters so that it displays a specific splash screen instead of the "main" body of the script.

Sounds nice, but it's a bit to complicated for me because I haven't got a clue of how to accomplish that.

I guess I'm not that good a coder.

[pekster]

Sounds nice, but it's a bit to complicated for me because I haven't got a clue of how to accomplish that.

I guess I'm not that good a coder.

<{POST_SNAPBACK}>

I was thinking something like this:

If $CmdLine[0] = 3 AND $CmdLine[1] = "Splashscreen" Then
 ;do our 2nd instance of the splashscreen, pause for 2 secs, then exit
  SplashTextOn($CmdLine[2], $CmdLine[3], 200, 200)
  Sleep(2000)
  Exit
EndIf
;otherwise, run the "main" script

SplashTextOn("Information", "Press alt-q to quit" & @LF & _
 "Press alt-1 for the first message" & @LF & _
 "Press alt-2 for the second message")
HotKeySet("!q", "quit")
HotKeySet("!1", "first")
HotKeySet("!2", "second")
While 1
  Sleep(100)
WEnd

Func quit()
  Exit
EndFunc

Func first()
  Run(@ScriptFullPath & ' Splashscreen "First message" ' & _
  '"This is the first message"')
EndFunc

Func second()
  Run(@ScriptFullPath & ' Splashscreen "Second message" ' & _
  '"This is the second message"')
EndFunc

I believe you need to compile this code before it will work.

[ezzetabi]

It might be eaisier to use command line options so you don't need to bother with installed files, cleanup, etc.

Just have the script call itself (a 2nd instance) with special paramaters so that it displays a specific splash screen instead of the "main" body of the script.

<{POST_SNAPBACK}>

Very nice idea... And also easy to script. Very good!

Edit: Scrolled the page... And read:

Sounds nice, but it's a bit to complicated for me because I haven't got a clue of how to accomplish that.

I guess I'm not that good a coder.

Well. Thats why the forum is there, no?