Recent File List in Menu

[GEOSoft]

I want to create a recent file list in a menu. I have one now but It's limited to the last 2 files.

With the existing function;

Selecting the second item in the Menu will reverse the two items and write the new order to an INI file.

A new File will remove the second Item, move the first tho second and then add the new file at the beginning

This all works fine.

What I want is to be able to have more than the two files in the list.

If a new file is opened then that file gets placed first and the rest shift down one and if the last is over the limit then remove it. No problem there.

If a previously opened file is selected then that item has to move to the the top of the list and the files the previously preceeded it in the list have to shift down as far as where the file used to be in the list. That shouldn't take much work.

Now it gets tougher.

I want to do this without having a lot of empty spaces in the menu in the event that the list is not full.

I have to add a menu item for each new file up to the maximum file limit (set in the INI)

Because of another function that dynamically creates controls I can't dynamically create these ones. When the other function is called it deletes any dynamically created controls and refreshes its own list. (perhaps I could also recrete the MenuItems at that point but that would be a clumsy workaround)

As far as I know MenuItems can be disabled but not hidden (which would be the way to go) so I'm looking for ideas.

[MrCreatoR]

GEOSoft

Hi, i don't quite understand what yo trying to do - you want to create a list with recent files, but what are these recent files? like from windows's recent files?

And it will be much more efective to help you if you post some code (what you are have so far, and where you cab't do something).

[GEOSoft]

GEOSoft

Hi, i don't quite understand what yo trying to do - you want to create a list with recent files, but what are these recent files? like from windows's recent files?

And it will be much more efective to help you if you post some code (what you are have so far, and where you cab't do something).

They could be files of several types but for the sake of discussion we'll say they are all au3 files.

I just need to Have a Menu called Recent Files and then separate menuItems for each file opened in the order that they were last opened starting with the most recent.. The number of files is variable depending on the user settings in the INI file although I'm setting a maximum of 10. It's easy to do using 10 Menu items and then GUICtrlSetData for each item but if there are 10 menuitems and only 3 file have been opened then you will end up with 7 menuitems with a blank string. That creates a menu with 3 items and a large empty space below. I'm trying to avoid that. GUICtrlSetState($I, $GUI_Hide) would would be good but I don't think that works on a menuitem.

To see what I want just take a look at the File menu of any MS Office product (and thousands of other apps).

Edited February 19, 2007 by GEOSoft

[Valuater]

Credits - Holger

expandcollapse popup

#include <GUIConstants.au3>

GUICreate("My GUI menu", 300, 200)

Global $defaultstatus = "Ready"
Global $status
Dim $count      = 0
Dim $lastindex    = 0
Dim $maxrecentfiles = 5 ; max 5 recent files
Dim $recentfiles[$maxrecentfiles][2]

$filemenu = GUICtrlCreateMenu("&File")
$fileitem = GUICtrlCreateMenuitem("Open", $filemenu)
GUICtrlSetState(-1, $GUI_DEFBUTTON)
$helpmenu = GUICtrlCreateMenu("?")
$saveitem = GUICtrlCreateMenuitem("Save", $filemenu)
GUICtrlSetState(-1, $GUI_DISABLE)
$infoitem = GUICtrlCreateMenuitem("Info", $helpmenu)
$exititem = GUICtrlCreateMenuitem("Exit", $filemenu)
$recentfilesmenu = GUICtrlCreateMenu ("Recent Files", $filemenu, 1)

$separator1  = GUICtrlCreateMenuitem("",$filemenu, 2)    ; create a separator line

$viewmenu      = GUICtrlCreateMenu("View", -1, 1)  ; is created before "?" menu
$viewstatusitem = GUICtrlCreateMenuitem("Statusbar", $viewmenu)
GUICtrlSetState(-1,$GUI_CHECKED)

$okbutton      = GUICtrlCreateButton("OK", 50, 130, 70, 20)
GUICtrlSetState(-1,$GUI_FOCUS)
$cancelbutton   = GUICtrlCreateButton("Cancel", 180, 130, 70, 20)

$statuslabel    = GUICtrlCreateLabel($defaultstatus, 0, 165, 300, 16, BitOr($SS_SIMPLE, $SS_SUNKEN))

GUISetState ()
While 1
    $msg = GUIGetMsg()
   
    Switch $msg
        Case $fileitem
            $file = FileOpenDialog("Choose file...", @TempDir, "All (*.*)")
            If @error = 0 Then
                $found = 0
                For $i = 0 To $maxrecentfiles - 1
                    If $file = $recentfiles[$i][1] Then
                        $found = 1
                        ExitLoop
                    EndIf
                Next
               
                If Not $found Then
                    $item = GUICtrlCreateMenuitem ($file, $recentfilesmenu, 0)
                   
                    If $count > $maxrecentfiles - 1 Then
                        GUICtrlDelete($recentfiles[$lastindex][0])
                    EndIf
                   
                    $recentfiles[$lastindex][0] = $item
                    $recentfiles[$lastindex][1] = $file
                   
                    $lastindex = $lastindex + 1
                    If $lastindex = $maxrecentfiles Then $lastindex = 0
                   
                    $count = $count + 1
                EndIf
            EndIf

        Case $viewstatusitem
            If BitAnd(GUICtrlRead($viewstatusitem), $GUI_CHECKED) = $GUI_CHECKED Then
                GUICtrlSetState($viewstatusitem, $GUI_UNCHECKED)
                GUICtrlSetState($statuslabel, $GUI_HIDE)
            Else
                GUICtrlSetState($viewstatusitem, $GUI_CHECKED)
                GUICtrlSetState($statuslabel, $GUI_SHOW)
            EndIf
   
        Case $GUI_EVENT_CLOSE, $cancelbutton, $exititem
            ExitLoop
           
        Case $infoitem
            Msgbox(0, "Info", "Only a test...")
           
        Case Else
            For $i = 0 To $maxrecentfiles - 1
                If $msg > 0 And $msg = $recentfiles[$i][0] Then
                    $file = $recentfiles[$i][1] ; now you have the file that was clicked
                    Msgbox(0, "Open File", $file)
                    ExitLoop
                EndIf               
            Next
    EndSwitch
WEnd

GUIDelete()

Exit

8)

[GEOSoft]

Credits - Holger

8)

That looks promising. I'll play with it a bit. Thanks @Valuater

I think my other option was to go ahead and create them dynamicly. and then delete and re-create them as necessary. And without testing I'm not positive that they would have to be re-created when I called my other function because of the way I refresh those dynamic controls.