Get output from Run

[iNFERiON]

Hey all, I'm pretty new to AutoIt, but I'm really liking the ease of learning it so far. I am creating a GUI installation script for a program and it's for 90% done. The last thing I want to add is a Progressbar that keeps track of the progress of extraction, so the user can see that something is acutally happening, since this is a long process. I have the progressbar added to my GUI, but what I can't figure out is if and how it's possible to have the progressbar get it's value from an external process. I am running the DOS version of RAR to extract a set of rar files.

Now this is how I call the RAR application:

$extract = RunWait(@TempDir & "\rar.exe x stpdta.001 " & ControlGetText("", "", $path))

Everytime a volume is done extracting the DOS application ($extract) says "Extracting from file2 ... Extracting from file3" and so on... Is there a way I can can "catch" those messages so I can set the progressbar to move on a little bit? This will give the user the idea that something is actually happening.

Edited February 19, 2007 by iNFERiON

[MrCreatoR]

Hi!

Try this example, i think it will help you to understand how it can be done (it's not a perfect example, but it is wery basic help wih things that you trying to do ) :

expandcollapse popup

#include <GuiStatusBar.au3>

$RarPath = @ScriptDir & "\Rar.exe"
$ArchiveName = @ScriptDir & "\Test.rar"
$FilesToAdd = '"C:\My Documents" "C:\Test"'

$Gui = GUICreate("Add files to archive", 500, 200)

$Progress = GUICtrlCreateProgress(40, 45, 430, 20)
$ProgressStatus = _GUICtrlStatusBarCreate($Gui, 0, "")
_GUICtrlStatusBarSetSimple($ProgressStatus)

$RunRarButton = GUICtrlCreateButton("Add files...", 220, 80)

GUISetState()

While 1
    $Msg = GUIGetMsg()
    Switch $Msg
        Case -3
            Exit
        Case $RunRarButton
            $ReadRar = Run($RarPath & ' a "' & $ArchiveName & '" ' & $FilesToAdd, "", @SW_HIDE, 2)
            GUICtrlSetData($RunRarButton, "Abort")
            AddFiles()
    EndSwitch
WEnd

Func AddFiles()
    While 1
        $Msg = GUIGetMsg()
        $ReadRarLine = StdoutRead($ReadRar)
        If @error Or $Msg = $RunRarButton Then ExitLoop
        _GUICtrlStatusBarSetText($ProgressStatus, "Add files process... " & $ReadRarLine, 255)
        GUICtrlSetData($Progress, _StringStripNotNumber($ReadRarLine))
        $LastRead = $ReadRarLine
    WEnd
    If $Msg = $RunRarButton Then
        ProcessClose($ReadRar)
        GUICtrlSetData($Progress, 0)
    EndIf
    GUICtrlSetData($RunRarButton, "Add files...")
    $DoneMsg = "Done!"
    If StringInStr($LastRead, "Warning") Or StringInStr($LastRead, "Error") Then
        If StringInStr($LastRead, "Warning") Then $ErrPos = StringInStr($LastRead, "Warning")
        If StringInStr($LastRead, "Error") Then $ErrPos = StringInStr($LastRead, "Error")
        $DoneMsg = "Done! (" & StringTrimLeft($LastRead, $ErrPos-2) & ")"
    EndIf
    _GUICtrlStatusBarSetText($ProgressStatus, $DoneMsg, 255)
EndFunc


Func _StringStripNotNumber($String)
    If Not IsString($String) Then Return $String
    Local $i, $RetNumber, $AllStringArr = StringSplit($String, "")
    For $i = 1 To $AllStringArr[0]
        If StringRegExp($AllStringArr[$i], '^ *([0-9]+\.{0,1}[0-9]*|0x[0-9]+) *$') Then $RetNumber &= $AllStringArr[$i]
    Next
    Return $RetNumber
EndFunc

Edited February 22, 2007 by MsCreatoR