ALT and shortcut key to select tab

[jonny1234]

Hi,

As you will know, if you put a button on a form and put a & in its caption, then you can click the button by pressing ALT and whichever character had the & before it in the button's caption.

I would like to do the same for tabs in a tab control. Is it possible?

Here is a simple GUI with a three-tabbed tab control, but underlining a character in the caption for each tab doesn't click that tab like it does for buttons as described above.

#include <GUIConstants.au3>

Opt("GUIOnEventMode", 1)
$Form1 = GUICreate("Test", 329, 189, 193, 123)
GUISetOnEvent($GUI_EVENT_CLOSE, "AForm1Close")
$Tab1 = GUICtrlCreateTab(12, 10, 303, 165)
$TabSheet1 = GUICtrlCreateTabItem("&One")
$TabSheet2 = GUICtrlCreateTabItem("&Two")
$TabSheet3 = GUICtrlCreateTabItem("T&hree")
GUICtrlCreateTabItem("")
GUISetState(@SW_SHOW)

While 1
    Sleep(100)
WEnd
        
Func AForm1Close()
    GUIDelete($Form1)
    Exit
EndFunc

Please can you help.

Thanks,

Jonny

[paullab]

Have you thought about using hotkeys?

Edited March 12, 2007 by paullab

[therks]

Okay so this is kind of an old thread but I found it while searching for something else and just had to answer it.

I've done this several times in scripts I've written and always thought it worked well. Give a script like this a try:

#include <GUIConstants.au3>

$gui = GUICreate('', 200, 200)
$bt_Tab1 = GUICtrlCreateButton('&h', -99, -99, 0, 0)
$bt_Tab2 = GUICtrlCreateButton('&w', -99, -99, 0, 0)

GUICtrlCreateLabel('Tab example:', 0, 0, 100, 15)
GUICtrlCreateTab(10, 20, 180, 150)
$tbi_Tab1 = GUICtrlCreateTabItem('&Hello')
     GUICtrlCreateLabel('Label', 50, 80, 50, 15)
$tbi_Tab2 = GUICtrlCreateTabItem('&World')
     GUICtrlCreateButton('Button', 50, 90, 50, 20)
GUICtrlCreateTabItem('')

GUICtrlCreateLabel('Tadaa!', 50, 185, 50, 15)

GUISetState()

While 1
     $gm = GUIGetMsg()
     Switch $gm
          Case $bt_Tab1
               GUICtrlSetState($tbi_Tab1, $GUI_SHOW)
          Case $bt_Tab2
               GUICtrlSetState($tbi_Tab2, $GUI_SHOW)
          Case $GUI_EVENT_CLOSE
               ExitLoop
     EndSwitch
WEnd