how do you delete unneeded text from a GUI

[PerryRaptor]

So I've got 34 GUIctrlCreateLabel() lines in a function and when the function is called again the old label data isn't deleted.

I need some sort of Label Eraser

[SmOke_N]

If you are creating one in the same spot, why not use GUICtrlDelete... or my preference...

GUICtrlSetData($label1, '')
GUICtrlSetData($label1, 'New Text')

[PerryRaptor]

hmmm...I didn't use GUICtrlSetData()

may be I should

Is a function like: _GUIEraser( left, top, width, height ) possible?

[MrCreatoR]

a function like: _GUIEraser( left, top, width, height ) possible?

Somthing like this:

GUICreate("Erase GUI", 300, 300)

GUICtrlCreateLabel("test1", 20, 20)
GUICtrlCreateLabel("test2", 40, 40)
GUICtrlCreateLabel("test3", 60, 60)
GUICtrlCreateLabel("test4", 80, 80)

GUICtrlCreateLabel("test5", 100, 100)
GUICtrlCreateLabel("test6", 120, 120)
GUICtrlCreateLabel("test7", 140, 140)
GUICtrlCreateLabel("test8", 160, 160)
GUICtrlCreateLabel("test9", 180, 180)
GUICtrlCreateLabel("test10", 200, 200)

$Button = GUICtrlCreateButton("Erase all", 150, 260)

GUISetState()

While 1
    $Msg = GUIGetMsg()
    Switch $Msg
        Case -3
            Exit
        Case $Button
            _GUIErase(10)
    EndSwitch
WEnd

Func _GUIErase($ControlsNumber)
    For $i = 1 To $ControlsNumber + 2
        GUICtrlDelete($i)
    Next
EndFunc

Edited February 26, 2007 by MsCreatoR

[PerryRaptor]

that works, but it also kills the gui

[SmOke_N]

that works, but it also kills the gui

Because he started at 1...

You chould just give your control a variable name or made them an array.

Dim $aLabel[11]
$Main = GUICreate("Erase GUI", 300, 300)

$aLabel[1] = GUICtrlCreateLabel("test1", 20, 20)
$aLabel[2] = GUICtrlCreateLabel("test2", 40, 40)
$aLabel[3] = GUICtrlCreateLabel("test3", 60, 60)
$aLabel[4] = GUICtrlCreateLabel("test4", 80, 80)
$aLabel[5] = GUICtrlCreateLabel("test5", 100, 100)
$aLabel[6] = GUICtrlCreateLabel("test6", 120, 120)
$aLabel[7] = GUICtrlCreateLabel("test7", 140, 140)
$aLabel[8] = GUICtrlCreateLabel("test8", 160, 160)
$aLabel[9] = GUICtrlCreateLabel("test9", 180, 180)
$aLabel[10] = GUICtrlCreateLabel("test10", 200, 200)

$Button = GUICtrlCreateButton("Erase all", 150, 260)

GUISetState()

While 1
    $Msg = GUIGetMsg()
    Switch $Msg
        Case -3
            Exit
        Case $Button
            For $iCC = 1 To UBound($aLabel) - 1
                GUICtrlDelete($aLabel[$iCC]);Replace $iCC with the number you want to delete
            Next
    EndSwitch
WEnd

Because the GUI has a control id too (1)

[PerryRaptor]

@Sm0ke N

the array fixed it