Disable GUI, but have an ability to drag it.

[MrCreatoR]

Hi all,

Is there a way to actualy disable the gui, and in the same time have ability to drag it?

i mean, disable like this:

GuiSetState(@SW_DISABLE, $GuiHwnd)

But in that case, i can not drag the gui by a title, i know that this is possible with some styles, and then set a label to dragable and then disable each control... or somthing like that... and also i know that it can be done if you cover whole gui with some disabled label, but its not it, i need somthing original, somthing that will allow to drag a GUI while it's disabled.

Is this possible?

Thanks for any help.

[BrettF]

Hi all,

Is there a way to actualy disable the gui, and in the same time have ability to drag it?

i mean, disable like this:

GuiSetState(@SW_DISABLE, $GuiHwnd)

But in that case, i can not drag the gui by a title, i know that this is possible with some styles, and then set a label to dragable and then disable each control... or somthing like that... and also i know that it can be done if you cover whole gui with some disabled label, but its not it, i need somthing original, somthing that will allow to drag a GUI while it's disabled.

Is this possible?

Thanks for any help.

Maybe, just maybe, disable all of the controls, and then leave the window open to be dragged? Not sure if that'll work though

[smashly]

Maybe, just maybe, disable all of the controls, and then leave the window open to be dragged? Not sure if that'll work though

That's a nice idea , but if you disabling a widows gui that has default styles set , then you can't disable the title bar min,max and close controls afik. (maybe can be done via dll call.. idk for sure though)

Most the other controls you can disable though , eg: menus and butttons and such.

I've asked and researched the same question before , but never really found a straight out answer to do it.

Good luck.

[MrCreatoR]

Maybe now someone has found a solution for that one?

[Generator]

I have some ideas, maybe it will work or not.

Have a check to check if MousePos() and WinActive(), if the MousePos is at Titlebar and the GUI is active, i believe you stil can make it active even the windows is disabled, and then use Larry's mouse hook, if it drags then just use WinMove() to go along with it.

Hope that helped.

[martin]

I have some ideas, maybe it will work or not.

Have a check to check if MousePos() and WinActive(), if the MousePos is at Titlebar and the GUI is active, i believe you stil can make it active even the windows is disabled, and then use Larry's mouse hook, if it drags then just use WinMove() to go along with it.

Hope that helped.

And if you do it the way Generator suggests then WIndowFromPoint might be useful because you need to be sure the window you're trying to drag is really 'seen' by the cursor.

[MrCreatoR]

Thanks for the idea Generator, but the problem is, that while the gui should be disabled, there many stuff executed, so it will not help - while copying for example, the script is waiting, and therefore i can not drag the gui manual (using WinMove() ).

Maybe if there a way to do it using GuiRegistrMsg() - then it might help...

[martin]

Thanks for the idea Generator, but the problem is, that while the gui should be disabled, there many stuff executed, so it will not help - while copying for example, the script is waiting, and therefore i can not drag the gui manual (using WinMove() ).

Maybe if there a way to do it using GuiRegistrMsg() - then it might help...

In that case I think you need to run another script which is just used to move the disabled one like this (not tested)

#include <GuiConstants.au3>
#Include <Misc.au3>

$GuiHwnd = WinGetHandle("Title of your disabled Gui")

 While 1
    
    If _IsPressed("01") Then
           $mp = MouseGetPos()
           $hwnd = DLLCall("user32.dll", "hwnd", "WindowFromPoint", "int", $mp[0], "int", $mp[1])
       If $hwnd[0] = $GuiHwnd Then
            $wp = WinGetPos("test")
            While _IsPressed("01")
              $np = MouseGetPos()
              WinMove("test","",$wp[0] - $mp[0] + $np[0],$wp[1] - $mp[1] + $np[1])
            WEnd
         EndIf
     EndIf
     
WEnd

[MrCreatoR]

Ok, i think that i has found a solution, but there is one problem that i mentioned here (there is traces of the "Controls Gui")...

#include <GuiConstants.au3>

$HostGui = GuiCreate("Test", 400, 300)
$MainGui = GuiCreate("", 400, 300, -1, -1, $WS_POPUP, BitOR($WS_EX_TRANSPARENT, $WS_EX_MDICHILD), $HostGui)

$DisableGUI_Button = GUICtrlCreateButton("Disable GUI", 20, 60)
$CheckBoxCtrl = GUICtrlCreateCheckbox("Test CheckBox", 20, 120)
$LabelCtrl = GUICtrlCreateLabel("Some label", 20, 180, 400)

GUISetState(@SW_SHOW, $HostGui)
GUISetState(@SW_SHOW, $MainGui)

While 1
    $Msg = GUIGetMsg()
    Switch $Msg
        Case -3
            Exit
        Case $DisableGUI_Button
            GUISetState(@SW_DISABLE, $MainGui)
            GUICtrlSetData($LabelCtrl, "Now try to drag the window ;)")
    EndSwitch
WEnd

[martin]

Ok, i think that i has found a solution, but there is one problem that i mentioned here (there is traces of the "Controls Gui")...

#include <GuiConstants.au3>

$HostGui = GuiCreate("Test", 400, 300)
$MainGui = GuiCreate("", 400, 300, -1, -1, $WS_POPUP, BitOR($WS_EX_TRANSPARENT, $WS_EX_MDICHILD), $HostGui)

$DisableGUI_Button = GUICtrlCreateButton("Disable GUI", 20, 60)
$CheckBoxCtrl = GUICtrlCreateCheckbox("Test CheckBox", 20, 120)
$LabelCtrl = GUICtrlCreateLabel("Some label", 20, 180, 400)

GUISetState(@SW_SHOW, $HostGui)
GUISetState(@SW_SHOW, $MainGui)

While 1
    $Msg = GUIGetMsg()
    Switch $Msg
        Case -3
            Exit
        Case $DisableGUI_Button
            GUISetState(@SW_DISABLE, $MainGui)
            GUICtrlSetData($LabelCtrl, "Now try to drag the window ;)")
    EndSwitch
WEnd

That's very neat. I'm sure I was just about to think of that myself.

[smashly]

Another crude solution to dragging a disabled window, could be tweaked a bit to get the desired result..

#include <GUIConstants.au3>

Opt("MouseCoordMode", 1)

$Gui = GuiCreate("Drag Disabled Window", 300, 100)
GUISetState(@SW_SHOW, $Gui)
GUISetState(@SW_DISABLE, $Gui)

While 1
    $msg = GUIGetMsg()
    Select
        Case $msg = $GUI_EVENT_CLOSE
            Exit
    EndSelect
    WindowClicked()
WEnd

Func WindowClicked()
    $GGCI = GUIGetCursorInfo($Gui)
    $MGP = MouseGetPos()
    $WGP = WinGetPos($GUI, "")
    If $GGCI[2] = 1 And $MGP[0] >= $WGP[0] And $MGP[0] <= ($WGP[0] + $WGP[2]) _
                    And $MGP[1] >= $WGP[1] And $MGP[1] <= ($WGP[1] + $WGP[3]) Then 
        WinMove($Gui, "", $MGP[0] - 150, $MGP[1] - 50)
    EndIf   
EndFunc

Cheers

Edited August 8, 2007 by smashly

[MrCreatoR]

Another crude solution to dragging a disabled window

Thanks, in that case i think it better to do it like this:

#include <GUIConstants.au3>
Opt("GuiOnEventMode", 1)

$Gui = GuiCreate("Drag Disabled Window", 300, 100)
GUISetState(@SW_SHOW, $Gui)
GUISetState(@SW_DISABLE, $Gui)

GUISetOnEvent($GUI_EVENT_PRIMARYDOWN, "DragGui")
GUISetOnEvent($GUI_EVENT_CLOSE, "Quit")

While 1
    Sleep(10)
WEnd

Func Quit()
    Exit
EndFunc

Func DragGui()
    Local $MousePos = MouseGetPos()
    Local $hWndPos = WinGetPos($Gui)
    Local $WinPos[2], $GuiCurInfo[5]
    
    $WinPos[0] = $MousePos[0]-$hWndPos[0]
    $WinPos[1] = $MousePos[1]-$hWndPos[1]
    
    $GuiCurInfo = GUIGetCursorInfo($Gui)
    While $GuiCurInfo[2] = 1
        $MousePos = MouseGetPos()
        $GuiCurInfo = GUIGetCursorInfo($Gui)
        WinMove($Gui, '', $MousePos[0]-$WinPos[0], $MousePos[1]-$WinPos[1])
    WEnd
EndFunc

But in fact, i wanted to title be NOT disabled, as in my previous solution(?) - But the problem in that solution, that the background is always (almoust) leave traces of transparent gui when draging .

Edited August 8, 2007 by MsCreatoR

[martin]

But the problem in that solution, that the background is always (almoust) leave traces of transparent gui when draging .

If you do this there are no traces.

#include <GUIConstants.au3>


$HostGui = GuiCreate("Test", 400, 300)
$MainGui = GuiCreate("", 400, 300, 0, 0,$WS_POPUP)
DllCall("user32.dll", "int", "SetParent", "hwnd", WinGetHandle($MainGui), "hwnd", WinGetHandle($HostGui))
$DisableGUI_Button = GUICtrlCreateButton("Disable GUI", 20, 60)
$CheckBoxCtrl = GUICtrlCreateCheckbox("Test CheckBox", 20, 120)
$LabelCtrl = GUICtrlCreateLabel("Some label", 20, 180, 400)

GUISetState(@SW_SHOW, $HostGui)
GUISetState(@SW_SHOW, $MainGui)

While 1
    $Msg = GUIGetMsg()
    Switch $Msg
        Case -3
            Exit
        Case $DisableGUI_Button
            GUISetState(@SW_DISABLE, $MainGui)
            GUICtrlSetData($LabelCtrl, "Now try to drag the window wink.gif")
    EndSwitch
WEnd

[MrCreatoR]

Thanks!!! it's perfect now!

[MrCreatoR]

It seems that there is just one more litle(?) problem - before i disable the Gui, i can not press any button on title bar (close/minimize etc) - the child gui is always has the focus - how to prevent this behaviour?

[ResNullius]

It seems that there is just one more litle(?) problem - before i disable the Gui, i can not press any button on title bar (close/minimize etc) - the child gui is always has the focus - how to prevent this behaviour?

Moving the SetParent call to after the Gui SetState commands works for me:

#include <GUIConstants.au3>


$HostGui = GuiCreate("Test", 400, 300)
$MainGui = GuiCreate("", 400, 300, 0, 0,$WS_POPUP)

$DisableGUI_Button = GUICtrlCreateButton("Disable GUI", 20, 60)
$CheckBoxCtrl = GUICtrlCreateCheckbox("Test CheckBox", 20, 120)
$LabelCtrl = GUICtrlCreateLabel("Some label", 20, 180, 400)

GUISetState(@SW_SHOW, $HostGui)
GUISetState(@SW_SHOW, $MainGui)

DllCall("user32.dll", "int", "SetParent", "hwnd", WinGetHandle($MainGui), "hwnd", WinGetHandle($HostGui))

While 1
    $Msg = GUIGetMsg()
    Switch $Msg
        Case -3
            Exit
        Case $DisableGUI_Button
            GUISetState(@SW_DISABLE, $MainGui)
            GUICtrlSetData($LabelCtrl, "Now try to drag the window wink.gif")
    EndSwitch
WEnd

[martin]

Moving the SetParent call to after the Gui SetState commands works for me:

#include <GUIConstants.au3>
$HostGui = GuiCreate("Test", 400, 300)
$MainGui = GuiCreate("", 400, 300, 0, 0,$WS_POPUP)

$DisableGUI_Button = GUICtrlCreateButton("Disable GUI", 20, 60)
$CheckBoxCtrl = GUICtrlCreateCheckbox("Test CheckBox", 20, 120)
$LabelCtrl = GUICtrlCreateLabel("Some label", 20, 180, 400)

GUISetState(@SW_SHOW, $HostGui)
GUISetState(@SW_SHOW, $MainGui)

DllCall("user32.dll", "int", "SetParent", "hwnd", WinGetHandle($MainGui), "hwnd", WinGetHandle($HostGui))

While 1
    $Msg = GUIGetMsg()
    Switch $Msg
        Case -3
            Exit
        Case $DisableGUI_Button
            GUISetState(@SW_DISABLE, $MainGui)
            GUICtrlSetData($LabelCtrl, "Now try to drag the window wink.gif")
    EndSwitch
WEnd

That works, but the Gui still looks disabled when it doesn't have focus and it looks wrong to me.

This approach also works, but MsCreatoR you might not like the time used by the AdLibEnable

expandcollapse popup

#include <GUIConstants.au3>
#Include <Misc.au3>

$HostGui = GuiCreate("Test", 400, 300)

$DisableGUI_Button = GUICtrlCreateButton("Disable GUI", 20, 60)
$CheckBoxCtrl = GUICtrlCreateCheckbox("Test CheckBox", 20, 120)
$LabelCtrl = GUICtrlCreateLabel("Some label", 20, 180, 400)

AdlibEnable("MoveMe",200)
GUISetState(@SW_SHOW, $HostGui)
$disabled = False

While 1
    $Msg = GUIGetMsg()
    Switch $Msg
        Case -3
            Exit
        Case $DisableGUI_Button
            $disabled = True
            GUISetState(@SW_DISABLE, $HostGui)
            GUICtrlSetData($LabelCtrl, "Now try to drag the window")
    EndSwitch
WEnd



Func MoveMe()
    If Not $disabled Then Return
    if _IsPressed("01") Then
        $mp = MouseGetPos()
        $hwnd = DLLCall("user32.dll", "hwnd", "WindowFromPoint", "int", $mp[0], "int", $mp[1])
        If $hwnd[0] = $HostGui Then
            $wp = WinGetPos("Test")
            While _IsPressed("01")
                $np = MouseGetPos()
                WinMove("Test","",$wp[0] - $mp[0] + $np[0],$wp[1] - $mp[1] + $np[1])
            WEnd
        EndIf
    EndIf
EndFunc

[MrCreatoR]

Moving the SetParent call to after the Gui SetState commands works

Thanks, but not after all states, like this is better:

GUISetState(@SW_SHOW, $HostGui)
DllCall("user32.dll", "int", "SetParent", "hwnd", $MainGui, "hwnd", $HostGui)
GUISetState(@SW_SHOW, $MainGui)

That way nothing is jumping up

Thanks a lot!

but MsCreatoR you might not like the time used by the AdLibEnable

And also the _IsPressed()

But thanks anyway, all that works, but besides moving the window, in my script there many stuff executed, so it must be as much simple as it can be.

Thank to all, the problem is solved i think!