checkbox

[Gif]

what is the return script for checkbox?

if $tick = False then 
                        _IECreate("http://www.google.com", 0, 1 , 0, 0)
                    Else    
                 _IECreate("http://videos.google.com", 0, 1 , 0, 0)
                     sleep(1000)
                     Exit
       endif

[PsaltyDS]

Do you mean in a GUI or one of those Google web pages?

If you mean to test a checkbox on a GUI:

#include <guiconstants.au3>

$WinTitle = "CheckBox Check"
$WinText = ""

;Create GUI
$hGui = GUICreate($WinTitle, 200, 100)
$CtrlId = GUICtrlCreateCheckbox("This is my checkbox", 10, 10, 180, 30)
$Check = GUICtrlCreateButton("Check", 33, 50, 50, 30)
$Quit = GUICtrlCreateButton("Quit", 117, 50, 50, 30)
GUISetState()

While 1
    Switch GUIGetMsg()
        Case $GUI_EVENT_CLOSE
            Exit
        Case $Quit
            Exit
        Case $Check
            ; Method one
            If BitAND(GUICtrlRead($CtrlId), $GUI_CHECKED) Then
                MsgBox(64, "Method One", "It's checked!")
            Else
                MsgBox(64, "Method One", "It is not checked.")
            EndIf

            ; ...or method two
            If ControlCommand($WinTitle, $WinText, $CtrlId, "IsChecked") Then
                MsgBox(64, "Method Two", "It's checked!")
            Else
                MsgBox(64, "Method Two", "It is not checked.")
            EndIf
    EndSwitch
WEnd

If you mean on a web page, look at the IE.au3 functions.

Edit: More complete demo... with GuiCtrlRead() fixed... :">

Edited May 10, 2007 by PsaltyDS

[Gif]

Ok !!!

[Gif]

Ok !!!