GUi minimize to tray

[billthecreator]

how would you minimize the gui but not have it show up on the bottom but in the tray as an icon??

[SmOke_N]

http://www.autoitscript.com/forum/index.ph...st&p=310179

[Valuater]

http://www.autoitscript.com/forum/index.ph...ighlite=to+tray

8)

8)

[smashly]

Hi,

Don't know if it helps...

I did an on event mode 1 example of min to tray, tray to gui.

(since the other example is in on event mode 0)

expandcollapse popup

#include <GuiConstants.au3>
#Include <Constants.au3>

Opt("TrayMenuMode",1)
Opt("TrayOnEventMode",1)
Opt("GUIOnEventMode", 1)

;----- Gui ----
$Main = GuiCreate("Minimize To Tray", 300, 200, -1, -1) 
GUISetOnEvent($GUI_EVENT_MINIMIZE, 'GuiEvent')
GUISetOnEvent($GUI_EVENT_CLOSE, 'GuiEvent')
GUISetState(@SW_SHOW, $Main)

;------ Tray Menu ----
$Show = TrayCreateItem("Show Gui")
TrayItemSetOnEvent(-1, 'TrayEvent')
TrayCreateItem("")
$Exit = TrayCreateItem("Exit")
TrayItemSetOnEvent(-1, 'TrayEvent')
TraySetState(2)

While 1
    Sleep(10)
WEnd

Func GuiEvent()
    Select
        Case @GUI_CtrlId = $GUI_EVENT_MINIMIZE
            GUISetState(@SW_HIDE, $Main)
            TraySetState(1)     
        Case @GUI_CtrlId = $GUI_EVENT_CLOSE 
            Exit
    EndSelect       
EndFunc


Func TrayEvent()
    Select
        Case @TRAY_ID = $Show 
                GUISetState(@SW_SHOW, $Main)
                GUISetState(@SW_RESTORE, $Main)             
                TraySetState(2)         
        Case @TRAY_ID = $Exit
                Exit
    EndSelect       
EndFunc

Cheers

Edited June 13, 2007 by smashly

[Zedna]

Another example is my NET SEND GUI