Replace text in a file

[Docfxit]

Hi,

I'd like to find out how to replace text in a file only if it's within double quotes. An example would be:

This is text in the file. "This is where I need CRLF replaced by some text" CRLF

I'd like to replace the CRLF because it's between double quotes. I don't want to replace the CRLF at the end.

Thank you,

Docfxit

[poisonkiller]

Open help file and look for FileRead, _StringBetween, StringInStr, StringReplace and FileWrite.

[SmOke_N]

I could of sworn I saw this very subject 1 or 2 days ago?... was there an answer on that one?

[DW1]

are there several lines like that? or something like this?

"This is where I need CRLF replaced by some text" CRLF " more stufff here in another set of quotes CRLF and has more stuff to replace" CRLF "etc."

If the above example is how your file looks then you may need to go one character at a time since all of the "CRLF"s are inbetween quotes.

[MisterBates]

Any chance you could post a section of the file?

[MrCreatoR]

See in help file this function _ReplaceStringInFile().

Or you can use my version on this func:

$Ret = ReplaceText("C:\test.txt", "Old Text", "New Text")
ConsoleWrite($Ret & @LF & @extended)

Func ReplaceText($FileName, $OldText, $NewText) 
    If Not FileExists($FileName) Then Return SetError(1, 0, -1)
    If $OldText = "" Then Return SetError(2, 0, 0)
    
    Local $hFile = FileOpen($FileName, 0)
    Local $VarToWrite = FileRead($hFile)
    FileClose($hFile)
    If Not StringInStr($VarToWrite, $OldText) Then Return SetError(3, 0, 0)
    
    Local $ReplStr = StringReplace($VarToWrite, $OldText, $NewText)
    Local $Extended = @extended
    
    Local $hFileW = FileOpen($FileName, 2)
    FileWrite($hFileW, $ReplStr)
    FileClose($hFileW)
    Return SetError(0, $Extended, 1)
EndFunc

[Docfxit]

Open help file and look for FileRead, _StringBetween, StringInStr, StringReplace and FileWrite.

Thanks for the reply. The way I see it I can't use any of these except FileRead and FileWrite because I need to replace the CRLF if there is double quotes around it.

Thank you,

Docfxit

[Docfxit]

I could of sworn I saw this very subject 1 or 2 days ago?... was there an answer on that one?

Kinda. The one you probably saw needs this as an answer. This is much simpler and to the point. No one was answering the other one.

Thank you,

Docfxit

[Docfxit]

are there several lines like that? or something like this?

"This is where I need CRLF replaced by some text" CRLF " more stufff here in another set of quotes CRLF and has more stuff to replace" CRLF "etc."

If the above example is how your file looks then you may need to go one character at a time since all of the "CRLF"s are inbetween quotes.

Yes I haven't found anything that would find something in between quotes.

The problem is when the record is read in it will have the first quote. Because it's a CRLF AutoIt will have to read in the next record (which is really part of the first record.) until it finds the next quote.

Thank you,

Docfxit

[Docfxit]

Any chance you could post a section of the file?

Sure. This is one record but it reads in as three records because of the CRLF's

LastName,FirstName,"Address1

Address2",City,State,ZipCode,Country,,,,,,,,,,,,,Home,,Work,,Cell1,,Fax,,Email1,,Email2,,,,,,"Divorced

Died"

Thanks for looking at it.

Docfxit

[Docfxit]

See in help file this function _ReplaceStringInFile().

Or you can use my version on this func:

Sample function removed because of a board error

The problem the way I see it is I can't use this because I don't know if the CRLF that I need to replace is between double quotes or if it marks the end of the record.

Thank you,

Docfxit

Edited June 20, 2007 by docfxit

[MisterBates]

Sure. This is one record but it reads in as three records because of the CRLF's

LastName,FirstName,"Address1

Address2",City,State,ZipCode,Country,,,,,,,,,,,,,Home,,Work,,Cell1,,Fax,,Email1,,Email2,,,,,,"Divorced

Died"

Thanks for looking at it.

Docfxit

What comes after this one record - is it a blank line? If so, one solution may be to use FileRead to read two lines. If second line is not a blank line, append second to first and read next. Keep going until a blank line is encountered. At that point, process the accumulated records (all appended into a single string), then start over (read next two lines etc. etc.)

Edit: If next record is not a blank record, then you could use StringRegExp to check if the record ends with an unterminated double-quoted string, and assume that if it does, the rest is in the next record:

$fResult = StringRegExp($sString, '^[^"]*?(?:["][^"]*?["][^"]*?)*?["][^"]*?$', 0); $fResult is TRUE if unterminated string in line

the following should only give console output on an unterminated double-quoted string (last test) - it works on my machine

$sUnterminatedDQ = '^[^"]*?(?:["][^"]*?["][^"]*?)*?["][^"]*?$'
$sString = 'no double-quoted string in the line'
$fResult = StringRegExp($sString, $sUnterminatedDQ, 0)
if @error or $fResult Then ConsoleWrite('@@ Debug(' & @ScriptLineNumber & ') : $fResult = ' & $fResult & @crlf & '>Error code: ' & @error & ', Extended: ' & @extended & @crlf);### Debug Console
$sString = 'double-quoted "string" in the line'
$fResult = StringRegExp($sString, $sUnterminatedDQ, 0)
if @error or $fResult Then ConsoleWrite('@@ Debug(' & @ScriptLineNumber & ') : $fResult = ' & $fResult & @crlf & '>Error code: ' & @error & ', Extended: ' & @extended & @crlf);### Debug Console
$sString = '"double-quoted string" at start'
$fResult = StringRegExp($sString, $sUnterminatedDQ, 0)
if @error or $fResult Then ConsoleWrite('@@ Debug(' & @ScriptLineNumber & ') : $fResult = ' & $fResult & @crlf & '>Error code: ' & @error & ', Extended: ' & @extended & @crlf);### Debug Console
$sString = 'double-quoted string "at the end"'
$fResult = StringRegExp($sString, $sUnterminatedDQ, 0)
if @error or $fResult Then ConsoleWrite('@@ Debug(' & @ScriptLineNumber & ') : $fResult = ' & $fResult & @crlf & '>Error code: ' & @error & ', Extended: ' & @extended & @crlf);### Debug Console
$sString = 'multiple "double-quoted" strings "in the" line'
$fResult = StringRegExp($sString, $sUnterminatedDQ, 0)
if @error or $fResult Then ConsoleWrite('@@ Debug(' & @ScriptLineNumber & ') : $fResult = ' & $fResult & @crlf & '>Error code: ' & @error & ', Extended: ' & @extended & @crlf);### Debug Console
$sString = 'unterminated "double-quoted string in the line'
$fResult = StringRegExp($sString, $sUnterminatedDQ, 0)
if @error or $fResult Then ConsoleWrite('@@ Debug(' & @ScriptLineNumber & ') : $fResult = ' & $fResult & @crlf & '>Error code: ' & @error & ', Extended: ' & @extended & @crlf);### Debug Console

The pattern works as follows:

^[^"]*? - matches anything up to the first double-quote

(?: - starts a group (the '?:' tells StringregExp not to remember the matching text

["] - matches an opening double quote

[^"]*? - matches anything between the double quotes

["] - matches a closing double quote

[^"]*? - matches any characters up to the next double quote

)*? - finishes the group, and tells RegExp to look for zero or more of these groups (DQ string followed by other chars)

["] - matches an unmatched double quote

[^"]*?$ - matches remaining characters up to the end of the line

All of the stuff up to the "unmatched double quote" is necessary to handle correctly matched double quotes in the line ...

Edited June 21, 2007 by MisterBates

[Docfxit]

What comes after this one record - is it a blank line? If so, one solution may be to use FileRead to read two lines. If second line is not a blank line, append second to first and read next. Keep going until a blank line is encountered. At that point, process the accumulated records (all appended into a single string), then start over (read next two lines etc. etc.)

I don't have a blank line.

Edit: If next record is not a blank record, then you could use StringRegExp to check if the record ends with an unterminated double-quoted string, and assume that if it does, the rest is in the next record:

$fResult = StringRegExp($sString, '^[^"]*?(?:["][^"]*?["][^"]*?)*?["][^"]*?$', 0); $fResult is TRUE if unterminated string in line

This is really supper. You are really great for putting this together for me. It works perfectly. I had no idea this could be done in one line like this. I was ready to create a few loops to solve it.

Thank you very very much,

Docfxit

[MisterBates]

This is really supper. You are really great for putting this together for me. It works perfectly. I had no idea this could be done in one line like this. I was ready to create a few loops to solve it.

Thanks - always good to get feedback (and thanks)

To be honest, I wasn't sure it could be done with RegExps, and struggled for a while with CRLF inside double quotes vs. outside double quotes (where there might not be a closing double quote). But once you posted data showing that a single line could be split over 2-3 lines in the file, that made it much easier to visualise.

Edit: BTW, if you're working with CSV files, you might want to split the input (once you've reconstructed the record) into its fields. The Following RegExp (courtesy Jim Weirich) does just that. You need to use StringRegExp with flag=3 as follows:

$sPattern = '([^",]*|"(?:[^"]|"")*")(?:,|\Z)'
$sTestRecord = ',,,"""",,,"hello",356.3,,,"some more string data"'
$asFields = StringRegExp($sTestRecord, $sPattern, 3)

One curiosity while testing - if the input record ends with a double-quoted field, the array returned by StringRegExp contains one extra field at the end (can't figure out why).

Parsing the CSV records this way takes account of null fields, of commas inside double quotes, and of pairs of double quotes inside double quotes. It also enables you to know when you've fully reconstructed a record, even if @crlf occurs in a non-Double-Quoted field, simply by testing that the number of fields is high enough.

See you in the forums!

Edited June 23, 2007 by MisterBates